gui-libs/wlroots: 0.14.0 bump

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

gui-libs/wlroots/Manifest

@@ -1 +1,2 @@
 DIST wlroots-0.13.0.tar.gz 503575 BLAKE2B bfcd40ea5cf9f85157b9a44a4a49f0fef1c82c2199ee428316b578e8d53cc39276b42d0a2c4b6b94d1a1f49df5d312539cdf4d053ea2472e0de93254e39dc015 SHA512 1c942a6b8a628383e2b68cd9096d3525021347c5c363a8239a3b4fb0d5736ffcd3e2c1333fdd7d95ecf214dd04bf01062b4f1b4fbbcd88d1d086a55261ca0c82
+DIST wlroots-0.14.0.tar.gz 505461 BLAKE2B d2fa28f64014ef9d840838cb5938af23f6f6b211b62dc352d0d5bb824ccaa7d7a85531e1eca14feeb06d31d59955ff9a913e40a73cad21ed1ebfe76ada39d558 SHA512 83f001133cb4b11a72bb9532b7321655428826662848f67de8e3220a33d9dff4d37c859602bdc319929949d387d014a257b0347039a6649944d7b084c76bb611

gui-libs/wlroots/wlroots-0.14.0.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson
+
+DESCRIPTION="Pluggable, composable, unopinionated modules for building a Wayland compositor"
+HOMEPAGE="https://github.com/swaywm/wlroots"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
+	inherit git-r3
+	SLOT="0/9999"
+else
+	SRC_URI="https://github.com/swaywm/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+	SLOT="0/14"
+fi
+
+LICENSE="MIT"
+IUSE="x11-backend X"
+
+DEPEND="
+	>=dev-libs/libinput-1.14.0:0=
+	>=dev-libs/wayland-1.19.0
+	>=dev-libs/wayland-protocols-1.17.0
+	media-libs/mesa[egl,gles2,gbm]
+	sys-auth/seatd:=
+	virtual/libudev
+	x11-libs/libdrm
+	x11-libs/libxkbcommon
+	x11-libs/pixman
+	x11-backend? ( x11-libs/libxcb:0= )
+	X? (
+		x11-base/xorg-server[wayland]
+		x11-libs/libxcb:0=
+		x11-libs/xcb-util-image
+		x11-libs/xcb-util-wm
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.17
+	>=dev-util/meson-0.56.0
+	virtual/pkgconfig
+"
+
+src_configure() {
+	# xcb-util-errors is not on Gentoo Repository (and upstream seems inactive?)
+	local emesonargs=(
+		"-Dxcb-errors=disabled"
+		"-Dexamples=false"
+		"-Dwerror=false"
+		"-Drenderers=gles2"
+		-Dxwayland=$(usex X enabled disabled)
+		-Dx11-backend=$(usex x11-backend enabled disabled)
+	)
+
+	meson_src_configure
+}
+
+pkg_postinst() {
+	elog "You must be in the input group to allow your compositor"
+	elog "to access input devices via libinput."
+}