gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/pylint: Bump to 2.15.10

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2023-01-10 06:47:43 +01:00
parent e1f40e4b10
commit 0b2e9b0386
2 changed files with 86 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/pylint/Manifest
View File

@@ -1,2 +1,3 @@
DIST pylint-2.15.10.gh.tar.gz 1321574 BLAKE2B 6ba504e0715675e8bf81848132e39e1d9b00078cb5ae2e881212898c6c9cfcbcf554ba3e9c6194173a776689ad311cef8e7420e027261b68c6e3f877c9961f33 SHA512 ce02512705f044be68dc7e2735ad705652307a1deec22ed3c077f29820a79b2d4f2a8ea82ca40a805bab516f7c00f83a22125228461e9e7db4f67f2b4cbf4edc
DIST pylint-2.15.8.gh.tar.gz 1318035 BLAKE2B 39b6a604af8e1b8d54640d9088f9a527ae2ef74535adb0fd655647f972193a955564a2acd0fadde723cf873b0765d362c9cd7dc2d8cc984b8fa0ec0107ce8968 SHA512 c5b59ca220303d66804dd55990e6d62e2cadc2ab7654e47d7ec5e16749b40ad557f43f7b8919c79e48e4b60dc1f92169df7bc312bede279b8f97aee223d9b0bd
DIST pylint-2.15.9.gh.tar.gz 1319840 BLAKE2B 6c48b19698e4692085d010eb857dc036cf67f94f6b82df3427b00a793f410e9b6b6ef7a5e868163752aa37355e8712c4ff48edb9b740f7d254af69370058e8ca SHA512 868d39011a545ffe719bd14dc4f99d59fad2487160900391cc91bec419d1c3857012b950a1bff790cdbdcb4b9120f83faf7c6b8adb1fd033db5edc54fe7816a1

85
dev-python/pylint/pylint-2.15.10.ebuild Normal file
View File

@@ -0,0 +1,85 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..11} )
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1
DESCRIPTION="Python code static checker"
HOMEPAGE="
https://pypi.org/project/pylint/
https://github.com/PyCQA/pylint/
"
SRC_URI="
https://github.com/pycqa/pylint/archive/v${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
IUSE="examples"
# Make sure to check https://github.com/PyCQA/pylint/blob/main/pyproject.toml#L34 on bumps
# Adjust dep bounds!
RDEPEND="
<dev-python/astroid-2.14[${PYTHON_USEDEP}]
>=dev-python/astroid-2.12.13[${PYTHON_USEDEP}]
>=dev-python/dill-0.3.6[${PYTHON_USEDEP}]
>=dev-python/isort-4.2.5[${PYTHON_USEDEP}]
<dev-python/isort-6[${PYTHON_USEDEP}]
>=dev-python/mccabe-0.6[${PYTHON_USEDEP}]
<dev-python/mccabe-0.8[${PYTHON_USEDEP}]
>=dev-python/platformdirs-2.2.0[${PYTHON_USEDEP}]
>=dev-python/tomlkit-0.10.1[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
dev-python/typing-extensions[${PYTHON_USEDEP}]
' 3.8 3.9)
$(python_gen_cond_dep '
>=dev-python/tomli-1.1.0[${PYTHON_USEDEP}]
' 3.8 3.9 3.10)
"
BDEPEND="
test? (
>=dev-python/GitPython-3[${PYTHON_USEDEP}]
dev-python/pytest-timeout[${PYTHON_USEDEP}]
dev-python/typing-extensions[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
python_test() {
rm -rf pylint || die
local EPYTEST_DESELECT=(
# No need to run the benchmarks
tests/benchmark/test_baseline_benchmarks.py
# TODO
'tests/test_functional.py::test_functional[forgotten_debug_statement_py37]'
'tests/test_functional.py::test_functional[dataclass_with_field]'
'tests/test_functional.py::test_functional[no_name_in_module]'
tests/checkers/unittest_typecheck.py::TestTypeChecker::test_nomember_on_c_extension_error_msg
tests/checkers/unittest_typecheck.py::TestTypeChecker::test_nomember_on_c_extension_info_msg
tests/config/pylint_config/test_run_pylint_config.py::test_invocation_of_pylint_config
# apparently fragile, needs unpickleable plugin
tests/test_check_parallel.py::TestCheckParallelFramework::test_linter_with_unpickleable_plugins_is_pickleable
)
epytest
}
python_install_all() {
if use examples ; then
docompress -x "/usr/share/doc/${PF}/examples"
docinto examples
dodoc -r examples/.
fi
distutils-r1_python_install_all
}