mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 10:37:22 -08:00
lxqt-base/lxqt-panel: version bump to 0.14.1
Package-Manager: Portage-2.3.62, Repoman-2.3.12 Signed-off-by: Jimi Huotari <chiitoo@gentoo.org> Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST lxqt-panel-0.13.0.tar.xz 273924 BLAKE2B affed55daf1c0a4bf20faeb35278a7d0c7474e514627d24c33469954bcf57ef2c5ee0ac1346918a3edc58f929f07a923e730d0c8ec1d32eeb3d2af41134beced SHA512 f9ea21a24aa8fc0898c756349256a9a84f4e8469743383ce4372f5ab3719170c84ec731d661f7b3355b7501f16fa862ef9d64b7b346e8abd4cbceb547fcb18e3
|
||||
DIST lxqt-panel-0.14.1.tar.xz 439252 BLAKE2B 28172f61cba99450965ca2c1660ca51f268a93ffc32769b270e5c5984b8f3534c3e8736f07334bdec1a1eb408ef35a20bf12de5a445faff161a93efbdacbe51c SHA512 e7cb361a13ac480cda50bc0549d5501f0d4f5bb6c8e257febf81550aaa88c0c55b615762aedb1f03fd654f79efe5aa2590b1dd592f6ae8c7e5a8d08086e0a687
|
||||
|
||||
@@ -0,0 +1,111 @@
|
||||
# Copyright 1999-2019 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
inherit cmake-utils
|
||||
|
||||
DESCRIPTION="LXQt desktop panel and plugins"
|
||||
HOMEPAGE="https://lxqt.org/"
|
||||
|
||||
MY_PV="$(ver_cut 1-2)*"
|
||||
|
||||
if [[ ${PV} = *9999* ]]; then
|
||||
inherit git-r3
|
||||
EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
|
||||
else
|
||||
SRC_URI="https://downloads.lxqt.org/downloads/${PN}/${PV}/${P}.tar.xz"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
|
||||
fi
|
||||
|
||||
LICENSE="LGPL-2.1+"
|
||||
SLOT="0"
|
||||
IUSE="+alsa colorpicker cpuload +desktopswitch +directorymenu dom +kbindicator +mainmenu
|
||||
+mount networkmonitor pulseaudio +quicklaunch sensors +showdesktop
|
||||
+spacer statusnotifier sysstat +taskbar +tray +volume +worldclock"
|
||||
REQUIRED_USE="volume? ( || ( alsa pulseaudio ) )"
|
||||
|
||||
BDEPEND="
|
||||
dev-qt/linguist-tools:5
|
||||
>=dev-util/lxqt-build-tools-0.6.0
|
||||
virtual/pkgconfig
|
||||
"
|
||||
DEPEND="
|
||||
>=dev-libs/libqtxdg-3.3.1
|
||||
dev-qt/qtcore:5
|
||||
dev-qt/qtdbus:5
|
||||
dev-qt/qtgui:5
|
||||
dev-qt/qtsvg:5
|
||||
dev-qt/qtwidgets:5
|
||||
dev-qt/qtx11extras:5
|
||||
dev-qt/qtxml:5
|
||||
kde-frameworks/kwindowsystem:5[X]
|
||||
>=lxde-base/lxmenu-data-0.1.5
|
||||
>=lxde-base/menu-cache-1.1.0
|
||||
=lxqt-base/liblxqt-${MY_PV}
|
||||
=lxqt-base/lxqt-globalkeys-${MY_PV}
|
||||
x11-libs/libX11
|
||||
cpuload? ( sys-libs/libstatgrab )
|
||||
kbindicator? ( x11-libs/libxkbcommon )
|
||||
mount? ( kde-frameworks/solid:5 )
|
||||
networkmonitor? ( sys-libs/libstatgrab )
|
||||
sensors? ( sys-apps/lm_sensors )
|
||||
statusnotifier? ( dev-libs/libdbusmenu-qt[qt5(+)] )
|
||||
sysstat? ( >=lxqt-base/libsysstat-0.4.1 )
|
||||
tray? (
|
||||
x11-libs/libxcb:=
|
||||
x11-libs/libXcomposite
|
||||
x11-libs/libXdamage
|
||||
x11-libs/libXrender
|
||||
x11-libs/xcb-util
|
||||
)
|
||||
volume? (
|
||||
alsa? ( media-libs/alsa-lib )
|
||||
pulseaudio? (
|
||||
media-sound/pavucontrol-qt
|
||||
media-sound/pulseaudio
|
||||
)
|
||||
)
|
||||
"
|
||||
RDEPEND="${DEPEND}
|
||||
!lxqt-base/lxqt-l10n
|
||||
"
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
# Plugins
|
||||
-DCOLORPICKER_PLUGIN=$(usex colorpicker)
|
||||
-DCPULOAD_PLUGIN=$(usex cpuload)
|
||||
-DDESKTOPSWITCH_PLUGIN=$(usex desktopswitch)
|
||||
-DDIRECTORYMENU_PLUGIN=$(usex directorymenu)
|
||||
-DDOM_PLUGIN=$(usex dom)
|
||||
-DKBINDICATOR_PLUGIN=$(usex kbindicator)
|
||||
-DMAINMENU_PLUGIN=$(usex mainmenu)
|
||||
-DMOUNT_PLUGIN=$(usex mount)
|
||||
-DNETWORKMONITOR_PLUGIN=$(usex networkmonitor)
|
||||
-DQUICKLAUNCH_PLUGIN=$(usex quicklaunch)
|
||||
-DSENSORS_PLUGIN=$(usex sensors)
|
||||
-DSHOWDESKTOP_PLUGIN=$(usex showdesktop)
|
||||
-DSPACER_PLUGIN=$(usex spacer)
|
||||
-DSTATUSNOTIFIER_PLUGIN=$(usex statusnotifier)
|
||||
-DSYSSTAT_PLUGIN=$(usex sysstat)
|
||||
-DTASKBAR_PLUGIN=$(usex taskbar)
|
||||
-DTRAY_PLUGIN=$(usex tray)
|
||||
-DVOLUME_PLUGIN=$(usex volume)
|
||||
-DWORLDCLOCK_PLUGIN=$(usex worldclock)
|
||||
)
|
||||
|
||||
if use volume; then
|
||||
mycmakeargs+=(
|
||||
-DVOLUME_USE_ALSA=$(usex alsa)
|
||||
-DVOLUME_USE_PULSEAUDIO=$(usex pulseaudio)
|
||||
)
|
||||
fi
|
||||
|
||||
cmake-utils_src_configure
|
||||
}
|
||||
|
||||
src_install(){
|
||||
cmake-utils_src_install
|
||||
doman panel/man/*.1
|
||||
}
|
||||
Reference in New Issue
Block a user