x11-drivers/xf86-input-wacom: Version bump to 1.2.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

x11-drivers/xf86-input-wacom/Manifest

@@ -1 +1,2 @@
 DIST xf86-input-wacom-1.1.0.tar.bz2 645948 BLAKE2B fccc81f49777b10527072bf4b30cb1a510e35d61f30fca96a68d05df55acc91f6c8dc44b2fad5d2b2f3f000646d85b2052841cbc8f933db51b668b1eb3e49dbe SHA512 d4ca8d5ea5e328c6e6b4bdb3d0ca23dee0bdb960e79f4422483d456330f9c88ea7579da4fba192fd250b23d7db1b7f40ad8ef0127f334c580030858edcbb9f4d
+DIST xf86-input-wacom-1.2.0.tar.bz2 647874 BLAKE2B c59e605bacb2694c2e322faba9b030112ffb57f916c816cbcb9a946fa063713c0590e1ea29273f73a84f4360b5bc5241c9768d7e61d77dfc9fb0af72b1a6f1cc SHA512 34817b87318d1fcf885e6427436a54d748a1c910026e6af0a22fafb461b227ca566cf06846f1f57c0d66412d5a3b20c95f014a71f8ef394ea8ca360a5f902318

x11-drivers/xf86-input-wacom/xf86-input-wacom-1.2.0.ebuild

@@ -0,0 +1,81 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-info systemd udev xorg-3 meson
+
+DESCRIPTION="Driver for Wacom tablets and drawing devices"
+HOMEPAGE="https://linuxwacom.github.io/"
+LICENSE="GPL-2"
+SRC_URI="https://github.com/linuxwacom/${PN}/releases/download/${P}/${P}.tar.bz2"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/libwacom-2:=
+	>=x11-base/xorg-server-1.13:=
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXinerama
+	virtual/libudev:="
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+
+pkg_pretend() {
+	linux-info_pkg_setup
+
+	if kernel_is lt 3 17; then
+		if ! linux_config_exists \
+				|| ! linux_chkconfig_present TABLET_USB_WACOM \
+				|| ! linux_chkconfig_present INPUT_EVDEV; then
+			echo
+			ewarn "If you use a USB Wacom tablet, you need to enable support in your kernel"
+			ewarn "  Device Drivers --->"
+			ewarn "    Input device support --->"
+			ewarn "      <*>   Event interface"
+			ewarn "      [*]   Tablets  --->"
+			ewarn "        <*>   Wacom Intuos/Graphire tablet support (USB)"
+			echo
+		fi
+	else
+		if ! linux_config_exists \
+				|| ! linux_chkconfig_present HID_WACOM; then
+			echo
+			ewarn "If you use a USB Wacom tablet, you need to enable support in your kernel"
+			ewarn "  Device Drivers --->"
+			ewarn "    HID support  --->"
+			ewarn "      Special HID drivers  --->"
+			ewarn "        <*> Wacom Intuos/Graphire tablet support (USB)"
+			echo
+		fi
+	fi
+}
+
+pkg_setup() {
+	linux-info_pkg_setup
+}
+
+src_configure() {
+	xorg-3_flags_setup
+
+	local emesonargs=(
+		-Dsystemd-unit-dir="$(systemd_get_systemunitdir)"
+		-Dudev-rules-dir="$(get_udevdir)/rules.d"
+		$(meson_feature test unittests)
+		-Dwacom-gobject=disabled
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}