gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-06 00:48:18 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/aesara: Bump to 2.3.6

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2022-01-20 09:11:55 +01:00
parent 4c605f3134
commit 0a4ea08334
2 changed files with 69 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/aesara/Manifest
View File

@@ -1,3 +1,4 @@
DIST aesara-rel-2.3.3.tar.gz 8179684 BLAKE2B ef738190e4169d43bb2323ee9425a1fc6d96a808d439940ead30b487b99fddaff073e3e05a720bcdb1eaed6fa903179be5df975747ac92e2b81256dbca886bea SHA512 f725cd84a598ea94f9cb22de768d004e96a0236fc4b93a9882a57494ce006fa657b1668b52b60d465816bb78c106a8d08a2a30eef2f5f9a55c437e28c94ee458
DIST aesara-rel-2.3.4.tar.gz 8179596 BLAKE2B 972e05a64da709e171be63d7c077f8b7b00fa3fefb5c0908db0770d6f41afb0960c3659c81a51db37c6ce77ccfef9153de1a47dcf44aa65e9a641c53a74de81e SHA512 1e926a2f9100bf44cf02a6b4ff9563835da64ae62afa0cd43046cfd5b5bbba7f9270ef755a5e9a2a9397626a0e8f9e654df075ec5b5e0629d60c52bfc1d61119
DIST aesara-rel-2.3.5.tar.gz 8186163 BLAKE2B 04d3c020d7eb68a5d88ba98156fcc5899e019ba747864a4b679074298fddccd6a6fc531c32304f0b5c7a4cc947a864e588a54399e85d30e97972fe8fd9cd9c97 SHA512 97bebb811ef79959106581a5b4021be5d63bb3aaecdf8b8d045de0a8587e795f4d564f19f50c62d65e42bad6c07b0aa81bd0b295f2fbd23fcd58e7347f811439
DIST aesara-rel-2.3.6.tar.gz 8188713 BLAKE2B a8c9309fdd11e265f73651f1b5e6abac099b12a9cd266200c895f6b235d40eb6a9fa1eb19b9fd8db1c7b0577d1aab8ad4e75093782dd0f6bb9b3b068d4215329 SHA512 ebd55a6738730219d8609d34f2671a381a384c1457860c1bf8f989273456feabe08fa8d5630014c19f40f65b3b220919410649cfba4bea8f3379d939e22474b9

68
dev-python/aesara/aesara-2.3.6.ebuild Normal file
View File

@@ -0,0 +1,68 @@
# Copyright 2021-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..10} )
inherit distutils-r1 multiprocessing optfeature
MY_P=aesara-rel-${PV}
DESCRIPTION="Library for operating on mathematical expressions with multi-dimensional arrays"
HOMEPAGE="https://github.com/aesara-devs/aesara"
SRC_URI="https://github.com/aesara-devs/aesara/archive/rel-${PV}.tar.gz -> ${MY_P}.tar.gz"
S="${WORKDIR}/${MY_P}"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
RDEPEND="
dev-python/cons[${PYTHON_USEDEP}]
dev-python/etuples[${PYTHON_USEDEP}]
dev-python/logical-unification[${PYTHON_USEDEP}]
dev-python/minikanren[${PYTHON_USEDEP}]
dev-python/filelock[${PYTHON_USEDEP}]
>=dev-python/numpy-1.17.0[${PYTHON_USEDEP}]
dev-python/six[${PYTHON_USEDEP}]
dev-python/scipy[${PYTHON_USEDEP}]"
BDEPEND="
test? (
dev-python/pytest-xdist[${PYTHON_USEDEP}]
)"
distutils_enable_sphinx doc 'dev-python/sphinx_rtd_theme'
distutils_enable_tests pytest
python_test() {
local EPYTEST_DESELECT=(
# speed tests are unreliable
tests/scan/test_basic.py::test_speed
tests/scan/test_basic.py::test_speed_rnn
tests/scan/test_basic.py::test_speed_batchrnn
tests/link/test_vm.py::test_speed
tests/link/test_vm.py::test_speed_lazy
tests/tensor/test_gc.py::test_merge_opt_runtime
# rounding problem?
# https://github.com/aesara-devs/aesara/issues/477
tests/tensor/test_math_scipy.py::TestGammaUBroadcast::test_good
tests/tensor/test_math_scipy.py::TestGammaUInplaceBroadcast::test_good
)
local EPYTEST_IGNORE=(
# we do not package numba
tests/link/test_numba.py
)
epytest -n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
}
python_compile() {
distutils-r1_python_compile
rm "${BUILD_DIR}/install$(python_get_sitedir)/bin/__init__.py" || die
}
pkg_postinst() {
optfeature "GPU code generation/execution on NVIDIA gpus" dev-util/nvidia-cuda-toolkit dev-util/nvidia-cuda-sdk
optfeature "GPU/CPU code generation on CUDA and OpenCL devices" dev-libs/libgpuarray dev-python/pycuda
}