mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-23 16:49:10 -07:00
sys-apps/portage: version bump to 2.3.51
#666554 - HardlinkQuarantineRepoStorage: exclude distfiles and packages #667008 - delete *.ecompress for empty PORTAGE_COMPRESS #667072 - ecompress: Detect and report colliding (un)compressed files #667604 - move install-qa-check.d/08gentoo-paths to gentoo repo Signed-off-by: Zac Medico <zmedico@gentoo.org> Package-Manager: Portage-2.3.51, Repoman-2.3.11
This commit is contained in:
Zac Medico
@@ -3,4 +3,5 @@ DIST portage-2.3.40-bug-657436-937d0156aa06-1fc628eead43.patch 4131 BLAKE2B 1b05
|
||||
DIST portage-2.3.40.tar.bz2 995122 BLAKE2B 3bfadee6cf57dace32bb4a365850650e13664202f3b16bf75821ff6226e85da823785ac87875fa82bd5cf1b953d638773819495f73f471c06ffd6926518df1ac SHA512 ded128c1941664fab6bc95f05115ec08900fddaedd1b6f12afa48da024531ee8939134d49759e09995c76a95e41beafdbf5528a5b62d3bf21c826ab1ac0cd1c5
|
||||
DIST portage-2.3.49.tar.bz2 1010414 BLAKE2B be8e0194855eda8e8a617ee4415d702199e10772bab9539ff27cb165b6749090be887b6f48d449f4e7650e618d43be1b0d26ba59597996a9d3d3ecd0caea166a SHA512 d3daee0075eee61c354ad1d4865b1cf433d9afe5ed56101758219694325c7c5ad62a0d9ce41bf2205934b6e073d0eba3ef3f7c8b6633b5a3448e469783c5329a
|
||||
DIST portage-2.3.50.tar.bz2 1012905 BLAKE2B 8eebb6ea412db4d07be64047c8e9995c7d61906ff3c387495f144acd5b7d31e9d8ede3f9e606dc7a28df5b5726a0a6d55e2e0d79c78848213f4835fb1a588f30 SHA512 120514e4e176de9ad27892d547825d4fd51d250266f9de8f2f96d689ff1373adab77b838e9801043f0053111063857e957e83b495d520db8cc7733af28b03b64
|
||||
DIST portage-2.3.51.tar.bz2 1013015 BLAKE2B f7f5e6c9e627db5a9e4bfcc9a6cbebb40fda910d3cc928922870b295c706a9f669d3d812e726b220610efe6b182460811eb9420d6fa5b8756481df64a88fe2b9 SHA512 6c22b97959d4b5be263b9a1de6bb343b1f8300e989f37c7334a9d5d6fb65fe2390958e222bc5379ec95099124fc51a049ecca6e1bfc18f0a6c57e4601342bb94
|
||||
DIST portage-2.3.8.tar.bz2 938062 BLAKE2B 3f7bedf6268131a3b3539d53c8a7bb069b533b3a78e5eec521b6201439c8ee5e66996e798fe295561d0a94bfcd32adf414d4f8b5e7a93035cea09749406e64a3 SHA512 4b4b2de20323799b9b0f7a8812f939aa9a96d2744a0f65ad5287ba49744c491b55169cdb21f2885317a6a7c960d2070775ffd798f247b44eebc677c33c271eb8
|
||||
|
||||
264
sys-apps/portage/portage-2.3.51.ebuild
Normal file
264
sys-apps/portage/portage-2.3.51.ebuild
Normal file
@@ -0,0 +1,264 @@
|
||||
# Copyright 1999-2018 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=5
|
||||
|
||||
PYTHON_COMPAT=(
|
||||
pypy
|
||||
python3_4 python3_5 python3_6 python3_7
|
||||
python2_7
|
||||
)
|
||||
PYTHON_REQ_USE='bzip2(+),threads(+)'
|
||||
|
||||
inherit distutils-r1 systemd
|
||||
|
||||
DESCRIPTION="Portage is the package management and distribution system for Gentoo"
|
||||
HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Portage"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd"
|
||||
SLOT="0"
|
||||
IUSE="build doc epydoc gentoo-dev +ipc +native-extensions +rsync-verify selinux xattr"
|
||||
|
||||
DEPEND="!build? ( $(python_gen_impl_dep 'ssl(+)') )
|
||||
>=app-arch/tar-1.27
|
||||
dev-lang/python-exec:2
|
||||
>=sys-apps/sed-4.0.5 sys-devel/patch
|
||||
doc? ( app-text/xmlto ~app-text/docbook-xml-dtd-4.4 )
|
||||
epydoc? ( >=dev-python/epydoc-2.0[$(python_gen_usedep 'python2*')] )"
|
||||
# Require sandbox-2.2 for bug #288863.
|
||||
# For xattr, we can spawn getfattr and setfattr from sys-apps/attr, but that's
|
||||
# quite slow, so it's not considered in the dependencies as an alternative to
|
||||
# to python-3.3 / pyxattr. Also, xattr support is only tested with Linux, so
|
||||
# for now, don't pull in xattr deps for other kernels.
|
||||
# For whirlpool hash, require python[ssl] (bug #425046).
|
||||
# For compgen, require bash[readline] (bug #445576).
|
||||
# app-portage/gemato goes without PYTHON_USEDEP since we're calling
|
||||
# the executable.
|
||||
RDEPEND="
|
||||
>=app-arch/tar-1.27
|
||||
dev-lang/python-exec:2
|
||||
!build? (
|
||||
>=sys-apps/sed-4.0.5
|
||||
app-shells/bash:0[readline]
|
||||
>=app-admin/eselect-1.2
|
||||
$(python_gen_cond_dep 'dev-python/pyblake2[${PYTHON_USEDEP}]' \
|
||||
python{2_7,3_4,3_5} pypy)
|
||||
rsync-verify? (
|
||||
>=app-portage/gemato-14[${PYTHON_USEDEP}]
|
||||
>=app-crypt/openpgp-keys-gentoo-release-20180706
|
||||
>=app-crypt/gnupg-2.2.4-r2[ssl(-)]
|
||||
)
|
||||
)
|
||||
elibc_FreeBSD? ( sys-freebsd/freebsd-bin )
|
||||
elibc_glibc? ( >=sys-apps/sandbox-2.2 )
|
||||
elibc_musl? ( >=sys-apps/sandbox-2.2 )
|
||||
elibc_uclibc? ( >=sys-apps/sandbox-2.2 )
|
||||
>=app-misc/pax-utils-0.1.17
|
||||
selinux? ( >=sys-libs/libselinux-2.0.94[python,${PYTHON_USEDEP}] )
|
||||
xattr? ( kernel_linux? (
|
||||
>=sys-apps/install-xattr-0.3
|
||||
$(python_gen_cond_dep 'dev-python/pyxattr[${PYTHON_USEDEP}]' \
|
||||
python2_7 pypy)
|
||||
) )
|
||||
!<app-admin/logrotate-3.8.0
|
||||
!<app-portage/repoman-2.3.10"
|
||||
PDEPEND="
|
||||
!build? (
|
||||
>=net-misc/rsync-2.6.4
|
||||
userland_GNU? ( >=sys-apps/coreutils-6.4 )
|
||||
)"
|
||||
# coreutils-6.4 rdep is for date format in emerge-webrsync #164532
|
||||
# NOTE: FEATURES=installsources requires debugedit and rsync
|
||||
|
||||
REQUIRED_USE="epydoc? ( $(python_gen_useflags 'python2*') )"
|
||||
|
||||
SRC_ARCHIVES="https://dev.gentoo.org/~zmedico/portage/archives"
|
||||
|
||||
prefix_src_archives() {
|
||||
local x y
|
||||
for x in ${@}; do
|
||||
for y in ${SRC_ARCHIVES}; do
|
||||
echo ${y}/${x}
|
||||
done
|
||||
done
|
||||
}
|
||||
|
||||
TARBALL_PV=${PV}
|
||||
SRC_URI="mirror://gentoo/${PN}-${TARBALL_PV}.tar.bz2
|
||||
$(prefix_src_archives ${PN}-${TARBALL_PV}.tar.bz2)"
|
||||
|
||||
pkg_setup() {
|
||||
use epydoc && DISTUTILS_ALL_SUBPHASE_IMPLS=( python2.7 )
|
||||
}
|
||||
|
||||
python_prepare_all() {
|
||||
distutils-r1_python_prepare_all
|
||||
|
||||
if use gentoo-dev; then
|
||||
einfo "Disabling --dynamic-deps by default for gentoo-dev..."
|
||||
sed -e 's:\("--dynamic-deps", \)\("y"\):\1"n":' \
|
||||
-i lib/_emerge/create_depgraph_params.py || \
|
||||
die "failed to patch create_depgraph_params.py"
|
||||
|
||||
einfo "Enabling additional FEATURES for gentoo-dev..."
|
||||
echo 'FEATURES="${FEATURES} ipc-sandbox network-sandbox strict-keepdir"' \
|
||||
>> cnf/make.globals || die
|
||||
fi
|
||||
|
||||
if use native-extensions; then
|
||||
printf "[build_ext]\nportage-ext-modules=true\n" >> \
|
||||
setup.cfg || die
|
||||
fi
|
||||
|
||||
if ! use ipc ; then
|
||||
einfo "Disabling ipc..."
|
||||
sed -e "s:_enable_ipc_daemon = True:_enable_ipc_daemon = False:" \
|
||||
-i lib/_emerge/AbstractEbuildProcess.py || \
|
||||
die "failed to patch AbstractEbuildProcess.py"
|
||||
fi
|
||||
|
||||
if use xattr && use kernel_linux ; then
|
||||
einfo "Adding FEATURES=xattr to make.globals ..."
|
||||
echo -e '\nFEATURES="${FEATURES} xattr"' >> cnf/make.globals \
|
||||
|| die "failed to append to make.globals"
|
||||
fi
|
||||
|
||||
if use build || ! use rsync-verify; then
|
||||
sed -e '/^sync-rsync-verify-metamanifest/s|yes|no|' \
|
||||
-i cnf/repos.conf || die "sed failed"
|
||||
fi
|
||||
|
||||
if [[ -n ${EPREFIX} ]] ; then
|
||||
einfo "Setting portage.const.EPREFIX ..."
|
||||
sed -e "s|^\(SANDBOX_BINARY[[:space:]]*=[[:space:]]*\"\)\(/usr/bin/sandbox\"\)|\\1${EPREFIX}\\2|" \
|
||||
-e "s|^\(FAKEROOT_BINARY[[:space:]]*=[[:space:]]*\"\)\(/usr/bin/fakeroot\"\)|\\1${EPREFIX}\\2|" \
|
||||
-e "s|^\(BASH_BINARY[[:space:]]*=[[:space:]]*\"\)\(/bin/bash\"\)|\\1${EPREFIX}\\2|" \
|
||||
-e "s|^\(MOVE_BINARY[[:space:]]*=[[:space:]]*\"\)\(/bin/mv\"\)|\\1${EPREFIX}\\2|" \
|
||||
-e "s|^\(PRELINK_BINARY[[:space:]]*=[[:space:]]*\"\)\(/usr/sbin/prelink\"\)|\\1${EPREFIX}\\2|" \
|
||||
-e "s|^\(EPREFIX[[:space:]]*=[[:space:]]*\"\).*|\\1${EPREFIX}\"|" \
|
||||
-i lib/portage/const.py || \
|
||||
die "Failed to patch portage.const.EPREFIX"
|
||||
|
||||
einfo "Prefixing shebangs ..."
|
||||
while read -r -d $'\0' ; do
|
||||
local shebang=$(head -n1 "$REPLY")
|
||||
if [[ ${shebang} == "#!"* && ! ${shebang} == "#!${EPREFIX}/"* ]] ; then
|
||||
sed -i -e "1s:.*:#!${EPREFIX}${shebang:2}:" "$REPLY" || \
|
||||
die "sed failed"
|
||||
fi
|
||||
done < <(find . -type f -print0)
|
||||
|
||||
einfo "Adjusting make.globals ..."
|
||||
sed -e "s|\(/usr/portage\)|${EPREFIX}\\1|" \
|
||||
-e "s|^\(PORTAGE_TMPDIR=\"\)\(/var/tmp\"\)|\\1${EPREFIX}\\2|" \
|
||||
-i cnf/make.globals || die "sed failed"
|
||||
|
||||
einfo "Adjusting repos.conf ..."
|
||||
sed -e "s|^\(location = \)\(/usr/portage\)|\\1${EPREFIX}\\2|" \
|
||||
-e "s|^\(sync-openpgp-key-path = \)\(.*\)|\\1${EPREFIX}\\2|" \
|
||||
-i cnf/repos.conf || die "sed failed"
|
||||
if use prefix-guest ; then
|
||||
sed -e "s|^\(main-repo = \).*|\\1gentoo_prefix|" \
|
||||
-e "s|^\\[gentoo\\]|[gentoo_prefix]|" \
|
||||
-e "s|^\(sync-uri = \).*|\\1rsync://rsync.prefix.bitzolder.nl/gentoo-portage-prefix|" \
|
||||
-i cnf/repos.conf || die "sed failed"
|
||||
fi
|
||||
|
||||
einfo "Adding FEATURES=force-prefix to make.globals ..."
|
||||
echo -e '\nFEATURES="${FEATURES} force-prefix"' >> cnf/make.globals \
|
||||
|| die "failed to append to make.globals"
|
||||
fi
|
||||
|
||||
cd "${S}/cnf" || die
|
||||
if [ -f "make.conf.example.${ARCH}".diff ]; then
|
||||
patch make.conf.example "make.conf.example.${ARCH}".diff || \
|
||||
die "Failed to patch make.conf.example"
|
||||
else
|
||||
eerror ""
|
||||
eerror "Portage does not have an arch-specific configuration for this arch."
|
||||
eerror "Please notify the arch maintainer about this issue. Using generic."
|
||||
eerror ""
|
||||
fi
|
||||
}
|
||||
|
||||
python_compile_all() {
|
||||
local targets=()
|
||||
use doc && targets+=( docbook )
|
||||
use epydoc && targets+=( epydoc )
|
||||
|
||||
if [[ ${targets[@]} ]]; then
|
||||
esetup.py "${targets[@]}"
|
||||
fi
|
||||
}
|
||||
|
||||
python_test() {
|
||||
esetup.py test
|
||||
}
|
||||
|
||||
python_install() {
|
||||
# Install sbin scripts to bindir for python-exec linking
|
||||
# they will be relocated in pkg_preinst()
|
||||
distutils-r1_python_install \
|
||||
--system-prefix="${EPREFIX}/usr" \
|
||||
--bindir="$(python_get_scriptdir)" \
|
||||
--docdir="${EPREFIX}/usr/share/doc/${PF}" \
|
||||
--htmldir="${EPREFIX}/usr/share/doc/${PF}/html" \
|
||||
--portage-bindir="${EPREFIX}/usr/lib/portage/${EPYTHON}" \
|
||||
--sbindir="$(python_get_scriptdir)" \
|
||||
--sysconfdir="${EPREFIX}/etc" \
|
||||
"${@}"
|
||||
}
|
||||
|
||||
python_install_all() {
|
||||
distutils-r1_python_install_all
|
||||
|
||||
local targets=()
|
||||
use doc && targets+=(
|
||||
install_docbook
|
||||
--htmldir="${EPREFIX}/usr/share/doc/${PF}/html"
|
||||
)
|
||||
use epydoc && targets+=(
|
||||
install_epydoc
|
||||
--htmldir="${EPREFIX}/usr/share/doc/${PF}/html"
|
||||
)
|
||||
|
||||
# install docs
|
||||
if [[ ${targets[@]} ]]; then
|
||||
esetup.py "${targets[@]}"
|
||||
fi
|
||||
|
||||
systemd_dotmpfilesd "${FILESDIR}"/portage-ccache.conf
|
||||
|
||||
# Due to distutils/python-exec limitations
|
||||
# these must be installed to /usr/bin.
|
||||
local sbin_relocations='archive-conf dispatch-conf emaint env-update etc-update fixpackages regenworld'
|
||||
einfo "Moving admin scripts to the correct directory"
|
||||
dodir /usr/sbin
|
||||
for target in ${sbin_relocations}; do
|
||||
einfo "Moving /usr/bin/${target} to /usr/sbin/${target}"
|
||||
mv "${ED}usr/bin/${target}" "${ED}usr/sbin/${target}" || die "sbin scripts move failed!"
|
||||
done
|
||||
}
|
||||
|
||||
pkg_preinst() {
|
||||
# comment out sanity test until it is fixed to work
|
||||
# with the new PORTAGE_PYM_PATH
|
||||
#if [[ $ROOT == / ]] ; then
|
||||
## Run some minimal tests as a sanity check.
|
||||
#local test_runner=$(find "${ED}" -name runTests)
|
||||
#if [[ -n $test_runner && -x $test_runner ]] ; then
|
||||
#einfo "Running preinst sanity tests..."
|
||||
#"$test_runner" || die "preinst sanity tests failed"
|
||||
#fi
|
||||
#fi
|
||||
|
||||
# elog dir must exist to avoid logrotate error for bug #415911.
|
||||
# This code runs in preinst in order to bypass the mapping of
|
||||
# portage:portage to root:root which happens after src_install.
|
||||
keepdir /var/log/portage/elog
|
||||
# This is allowed to fail if the user/group are invalid for prefix users.
|
||||
if chown portage:portage "${ED}"var/log/portage{,/elog} 2>/dev/null ; then
|
||||
chmod g+s,ug+rwx "${ED}"var/log/portage{,/elog}
|
||||
fi
|
||||
}
|
||||
Reference in New Issue
Block a user