mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 22:47:14 -08:00
media-libs/vips: drop 8.15.4
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
This commit is contained in:
@@ -1,3 +1,2 @@
|
||||
DIST vips-8.15.2.tar.xz 18653840 BLAKE2B fa46d58d77ec835cbb7036764bcc40554a72c2d6a854adee31905d04cb189de131340f990b432293935bc8563236816d14fa45c08ba858de6b1be5ee3ea148ec SHA512 f746e4590f0105cb40dbb4ee35fe4b177acbf09d7fc4202f623812018030b9cfdfcbe585742724b35f40ef9b68717ebd015243f3db293086621d9eac3d89a5b2
|
||||
DIST vips-8.15.4.tar.xz 18655032 BLAKE2B ea4bb5af7bf34bda688ea937456ec6c1cff0dfa21e87fd843611cd8b3fb16df8fd1793d8327d40bbf937995466a4cfd417d9fe68f02010e260cf6b68f8c725c5 SHA512 b44fb3d57e356f3f0c4177f8385c0a6e5932ac22af8bd4ef312961d98bec4336bd3fb914a659a51a83a9da8b3bceb1593492a45e433b45a21cc6094aada6f1ac
|
||||
DIST vips-8.15.5.tar.xz 18652672 BLAKE2B bebd8078cb6cedffb4aee98aab17f62538439f81378b4953085ec0cd6e9ce2c6fb17831e77113980bc91c0ed4355d765c2008232b1cf64246467a9cd936e2245 SHA512 d8f87292fa395e108f36769accc64b67ea49aadbea4a6bd97fc457f340c0f78c0365a43ae4b14ac5f154e696a8b2abc100078a8c5ac58aae2dd1b04347fbf4d8
|
||||
|
||||
@@ -1,167 +0,0 @@
|
||||
# Copyright 2023-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
PYTHON_COMPAT=( python3_{10..13} )
|
||||
inherit flag-o-matic meson python-single-r1 toolchain-funcs vala
|
||||
|
||||
DESCRIPTION="VIPS Image Processing Library"
|
||||
HOMEPAGE="https://libvips.github.io/libvips/"
|
||||
SRC_URI="https://github.com/libvips/libvips/releases/download/v${PV}/${P}.tar.xz"
|
||||
|
||||
LICENSE="LGPL-2.1+ MIT"
|
||||
SLOT="0/${PV}"
|
||||
KEYWORDS="~amd64 ~arm64 ~x86"
|
||||
IUSE="
|
||||
archive deprecated doc exif fftw fits fontconfig graphicsmagick
|
||||
gtk-doc heif +highway imagemagick imagequant +introspection +jpeg
|
||||
jpeg2k jpegxl lcms matio openexr orc pango pdf +png python svg
|
||||
test tiff vala webp
|
||||
"
|
||||
REQUIRED_USE="
|
||||
fontconfig? ( pango )
|
||||
graphicsmagick? ( imagemagick )
|
||||
python? ( ${PYTHON_REQUIRED_USE} )
|
||||
test? ( jpeg png webp )
|
||||
vala? ( introspection )
|
||||
"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
RDEPEND="
|
||||
dev-libs/glib:2
|
||||
dev-libs/expat
|
||||
virtual/libintl
|
||||
archive? ( app-arch/libarchive:= )
|
||||
exif? ( media-libs/libexif )
|
||||
fftw? ( sci-libs/fftw:3.0= )
|
||||
fits? ( sci-libs/cfitsio:= )
|
||||
fontconfig? ( media-libs/fontconfig )
|
||||
heif? ( media-libs/libheif:= )
|
||||
highway? ( >=dev-cpp/highway-1.0.5 )
|
||||
!highway? (
|
||||
orc? ( dev-lang/orc )
|
||||
)
|
||||
imagemagick? (
|
||||
graphicsmagick? ( media-gfx/graphicsmagick:= )
|
||||
!graphicsmagick? ( media-gfx/imagemagick:= )
|
||||
)
|
||||
imagequant? ( media-gfx/libimagequant )
|
||||
introspection? ( dev-libs/gobject-introspection )
|
||||
jpeg? ( media-libs/libjpeg-turbo:= )
|
||||
jpeg2k? ( media-libs/openjpeg:= )
|
||||
jpegxl? ( media-libs/libjxl:= )
|
||||
lcms? ( media-libs/lcms:2 )
|
||||
matio? ( sci-libs/matio:= )
|
||||
openexr? ( media-libs/openexr:= )
|
||||
pango? (
|
||||
x11-libs/cairo
|
||||
x11-libs/pango
|
||||
)
|
||||
pdf? (
|
||||
app-text/poppler[cairo]
|
||||
x11-libs/cairo
|
||||
)
|
||||
png? ( media-libs/libpng:= )
|
||||
python? (
|
||||
${PYTHON_DEPS}
|
||||
$(python_gen_cond_dep 'dev-python/pycairo[${PYTHON_USEDEP}]')
|
||||
)
|
||||
svg? (
|
||||
gnome-base/librsvg:2
|
||||
sys-libs/zlib:=
|
||||
x11-libs/cairo
|
||||
)
|
||||
tiff? ( media-libs/tiff:= )
|
||||
webp? ( media-libs/libwebp:= )
|
||||
"
|
||||
DEPEND="
|
||||
${RDEPEND}
|
||||
pango? ( x11-base/xorg-proto )
|
||||
pdf? ( x11-base/xorg-proto )
|
||||
svg? ( x11-base/xorg-proto )
|
||||
test? (
|
||||
tiff? ( media-libs/tiff[jpeg] )
|
||||
)
|
||||
"
|
||||
BDEPEND="
|
||||
dev-util/glib-utils
|
||||
sys-devel/gettext
|
||||
doc? (
|
||||
app-text/doxygen
|
||||
media-gfx/graphviz
|
||||
)
|
||||
gtk-doc? ( dev-util/gtk-doc )
|
||||
python? ( ${PYTHON_DEPS} )
|
||||
vala? ( $(vala_depend) )
|
||||
"
|
||||
|
||||
pkg_setup() {
|
||||
use python && python-single-r1_pkg_setup
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
use vala && vala_setup
|
||||
|
||||
sed -i "s/'vips-doc'/'${PF}'/" cplusplus/meson.build || die
|
||||
|
||||
sed -i "/subdir('fuzz')/d" meson.build || die
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
# workaround for bug in lld (bug #921728)
|
||||
tc-ld-is-lld && filter-lto
|
||||
|
||||
local emesonargs=(
|
||||
$(meson_use deprecated)
|
||||
$(meson_use doc doxygen)
|
||||
-Dexamples=false
|
||||
$(meson_use gtk-doc gtk_doc)
|
||||
$(meson_use vala vapi)
|
||||
-Dcgif=disabled # not packaged, and not used to view gif (only saving)
|
||||
$(meson_feature archive)
|
||||
$(meson_feature exif)
|
||||
$(meson_feature fftw)
|
||||
$(meson_feature fits cfitsio)
|
||||
$(meson_feature fontconfig)
|
||||
$(meson_feature heif)
|
||||
$(meson_feature highway)
|
||||
$(meson_feature imagemagick magick)
|
||||
-Dmagick-package=$(usex graphicsmagick GraphicsMagick MagickCore)
|
||||
$(meson_feature imagequant)
|
||||
$(meson_feature introspection)
|
||||
$(meson_feature jpeg)
|
||||
$(meson_feature jpeg2k openjpeg)
|
||||
$(meson_feature jpegxl jpeg-xl)
|
||||
$(meson_feature lcms)
|
||||
$(meson_feature matio)
|
||||
-Dnifti=disabled # not packaged
|
||||
$(meson_feature openexr)
|
||||
-Dopenslide=disabled # not packaged
|
||||
$(meson_feature orc) # no-op if USE=highway is set
|
||||
$(meson_feature pango pangocairo)
|
||||
-Dpdfium=disabled # not packaged, can use poppler instead
|
||||
$(meson_feature png)
|
||||
$(meson_feature pdf poppler)
|
||||
-Dquantizr=disabled # not packaged, can use imagequant instead
|
||||
-Dspng=disabled # not packaged, can use libpng instead
|
||||
$(meson_feature svg rsvg)
|
||||
$(meson_feature tiff)
|
||||
$(meson_feature webp)
|
||||
$(meson_feature svg zlib) # zlib is currently only used by svgload.c
|
||||
)
|
||||
|
||||
meson_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
meson_src_install
|
||||
|
||||
if use python; then
|
||||
python_fix_shebang "${ED}"/usr/bin/vipsprofile
|
||||
else
|
||||
rm -- "${ED}"/usr/{bin/vipsprofile,share/man/man1/vipsprofile.1} || die
|
||||
fi
|
||||
}
|
||||
Reference in New Issue
Block a user