mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-24 06:48:18 -07:00
app-text/calibre: add 7.11.0
Signed-off-by: Eli Schwartz <eschwartz93@gmail.com> Closes: https://github.com/gentoo/gentoo/pull/36801 Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
This commit is contained in:
Eli Schwartz
committed by
Arthur Zamarin
Arthur Zamarin
parent
bace3d1311
commit
0951031c96
@@ -2,6 +2,8 @@ DIST calibre-5.44.0.tar.xz 41015696 BLAKE2B c7053e728da20fccfa981ed4f56e24a4d5b3
|
||||
DIST calibre-5.44.0.tar.xz.sig 566 BLAKE2B 413b95855d79bdb5b17ca5d760f834006797b4d3e413604f27d351a3392e16d647e772dc063306bf973e1156c34f68cb38152a66164bca849ebed5484e7f6065 SHA512 59957bf35a73f218241bf76cc86994d5af87cea11d3b0800e83f157bf0b2cfcaf4b6c1314562e74a1141d0c167fdb1619cb9a90e93b67f55dd55ceed77045059
|
||||
DIST calibre-7.10.0.tar.xz 44201168 BLAKE2B 9d851ae6cbf0efd16790351720e1e86efb3dc6efc9d7c29b4e471aa99c7ff46969d594e97a2aca13ca096e77e2ae399f6e888c6846da84f7e093493ad32487a6 SHA512 f01d4c57af7f8390c17231ebc6f2fee4b331a8f143337a128119b8585b6e269b5d531a5245c6f418a8ec51ee440f99ce978b0d102f28cc955a2d31911db3b107
|
||||
DIST calibre-7.10.0.tar.xz.sig 566 BLAKE2B ef5aceae5e181e1f1e22e4ef90248e54a77bc35a9da51a152408d11833c35a1e1f131d68c8dbb39303446a6a695694b4aa3b84c16eddd273f79f84bae3a7f073 SHA512 23aa5d044524d23f3bb0cab8cbee1a12f3f147cf1a557703f36eec59e651b63cd6185484515accb4456c3dc3adfb9918eb6b88cd9d205a016232347f1db0ebd1
|
||||
DIST calibre-7.11.0.tar.xz 44329708 BLAKE2B 0c5a1ccafb9c192b7f25998174f2b9ea3571d63a6aeca274d72e7e8e8ed27b433a209d805fd35079f01a72201cb01e741f95d8c83265ea39d3c191bf41dab93f SHA512 93216323d23919ce37f3983304f0d5e88847833c52a00a8a780db1c95860d814298358347848a439ff006827742a7c19171ed4d3e3569cd03296a682200e8160
|
||||
DIST calibre-7.11.0.tar.xz.sig 566 BLAKE2B 2b035fd2a31f5954de229c932c4aca58c0850a3fdfa793932ef81bd84c4612e65ad12138684932714a85e7be68d21cd808f4008d096121d047ae9bf053b893ca SHA512 ffca64e38e5e402c8fc146dff850a67e0644dcf665c5b0d36f9c9ade6702a980f11dcdf73147412c6ee384110fa8a27168fe5c759ba4754005647f8f656a543b
|
||||
DIST calibre-7.7.0.tar.xz 44006620 BLAKE2B f29dcf4c6550c7649dfddcaa4f5390ebf23ae7ef8d8103c9d001c9fcb8ca4a120c7cc8d5c2c36acced6672d78e45b6a93c6c505482f78e21ecc170c56c2641b3 SHA512 8444811e63be007e075b716c70c7df989408b8a323068fb763a07b27a2c52557e5625f311ac7672d5367df9dd3d071354cf3dd1102a0aa057e5cbbdc09ed24df
|
||||
DIST calibre-7.7.0.tar.xz.sig 566 BLAKE2B 6e21d5e8517abd2cf9e278cf40308709422b97cf2c953e1f1b8487aeb6561c57902d233fb397abfe50b8a42ce28071426477171a9d5b0b055af5cf41fdb78ef4 SHA512 17d91e46aa0dc3e12f1d65c5956f3c0f6b9fb07705042efd73508cc0040d0df2bae939544fd4bc123064393174057b5107cb38167b2db2f9477988ce369e10ac
|
||||
DIST calibre-7.8.0.tar.xz 44167208 BLAKE2B 676f5519b2809ca91c972ce0b4227aeac977945248063be58f8ed387c2dc1285f01e0d59c52ba9dea3a25842be1f97cdaece7f1eac5c208503240ff9ac3f0093 SHA512 c90d247af3a8ba3b2a94ca3a03bf9ee4d1c8f07d6feaa1ec045d639f448c476c4be9568e66845e7067e32b746e0ab034be65084a60f2b64f961f6678a30910e7
|
||||
|
||||
243
app-text/calibre/calibre-7.11.0.ebuild
Normal file
243
app-text/calibre/calibre-7.11.0.ebuild
Normal file
@@ -0,0 +1,243 @@
|
||||
# Copyright 1999-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
PYTHON_COMPAT=( python3_{10..12} )
|
||||
PYTHON_REQ_USE="sqlite,ssl"
|
||||
|
||||
inherit edo toolchain-funcs python-single-r1 qmake-utils verify-sig xdg
|
||||
|
||||
DESCRIPTION="Ebook management application"
|
||||
HOMEPAGE="https://calibre-ebook.com/"
|
||||
SRC_URI="
|
||||
https://download.calibre-ebook.com/${PV}/${P}.tar.xz
|
||||
verify-sig? ( https://calibre-ebook.com/signatures/${P}.tar.xz.sig )
|
||||
"
|
||||
VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/kovidgoyal.gpg
|
||||
|
||||
LICENSE="
|
||||
GPL-3+
|
||||
GPL-3
|
||||
GPL-2+
|
||||
GPL-2
|
||||
GPL-1+
|
||||
LGPL-3+
|
||||
LGPL-2.1+
|
||||
LGPL-2.1
|
||||
BSD
|
||||
MIT
|
||||
Old-MIT
|
||||
Apache-2.0
|
||||
public-domain
|
||||
|| ( Artistic GPL-1+ )
|
||||
CC-BY-3.0
|
||||
OFL-1.1
|
||||
PSF-2
|
||||
"
|
||||
KEYWORDS="~amd64 ~arm64"
|
||||
SLOT="0"
|
||||
IUSE="+font-subsetting ios speech +system-mathjax test +udisks unrar"
|
||||
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
|
||||
|
||||
# Qt slotted dependencies are used because the libheadless.so plugin links to
|
||||
# QT_*_PRIVATE_ABI. It only uses core/gui/dbus.
|
||||
COMMON_DEPEND="${PYTHON_DEPS}
|
||||
app-i18n/uchardet
|
||||
>=app-text/hunspell-1.7:=
|
||||
>=app-text/podofo-0.10.0:=
|
||||
app-text/poppler[utils]
|
||||
dev-libs/hyphen:=
|
||||
>=dev-libs/icu-57.1:=
|
||||
dev-libs/openssl:=
|
||||
dev-libs/snowball-stemmer:=
|
||||
$(python_gen_cond_dep '
|
||||
>=dev-python/apsw-3.25.2_p1[${PYTHON_USEDEP}]
|
||||
dev-python/beautifulsoup4[${PYTHON_USEDEP}]
|
||||
>=dev-python/css-parser-1.0.4[${PYTHON_USEDEP}]
|
||||
dev-python/dnspython[${PYTHON_USEDEP}]
|
||||
>=dev-python/feedparser-5.2.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/html2text-2019.8.11[${PYTHON_USEDEP}]
|
||||
>=dev-python/html5-parser-0.4.9[${PYTHON_USEDEP}]
|
||||
dev-python/jeepney[${PYTHON_USEDEP}]
|
||||
>=dev-python/lxml-3.8.0[${PYTHON_USEDEP}]
|
||||
dev-python/lxml-html-clean[${PYTHON_USEDEP}]
|
||||
>=dev-python/markdown-3.0.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/mechanize-0.3.5[${PYTHON_USEDEP}]
|
||||
>=dev-python/msgpack-0.6.2[${PYTHON_USEDEP}]
|
||||
>=dev-python/netifaces-0.10.5[${PYTHON_USEDEP}]
|
||||
>=dev-python/pillow-3.2.0[jpeg,truetype,webp,zlib,${PYTHON_USEDEP}]
|
||||
>=dev-python/psutil-4.3.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/pychm-0.8.6[${PYTHON_USEDEP}]
|
||||
>=dev-python/pygments-2.3.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/python-dateutil-2.5.3[${PYTHON_USEDEP}]
|
||||
dev-python/PyQt6[gui,network,opengl,printsupport,quick,svg,widgets,${PYTHON_USEDEP}]
|
||||
dev-python/PyQt6-WebEngine[widgets,${PYTHON_USEDEP}]
|
||||
dev-python/regex[${PYTHON_USEDEP}]
|
||||
dev-python/xxhash[${PYTHON_USEDEP}]
|
||||
>=dev-python/zeroconf-0.75.0[${PYTHON_USEDEP}]
|
||||
')
|
||||
dev-qt/qtbase:6=[gui,widgets]
|
||||
dev-qt/qtimageformats:6
|
||||
dev-util/desktop-file-utils
|
||||
dev-util/gtk-update-icon-cache
|
||||
media-fonts/liberation-fonts
|
||||
media-libs/fontconfig:=
|
||||
>=media-libs/freetype-2:=
|
||||
>=media-libs/libmtp-1.1.11:=
|
||||
>=media-gfx/optipng-0.7.6
|
||||
virtual/libusb:1=
|
||||
x11-misc/shared-mime-info
|
||||
>=x11-misc/xdg-utils-1.0.2-r2
|
||||
font-subsetting? ( $(python_gen_cond_dep 'dev-python/fonttools[${PYTHON_USEDEP}]') )
|
||||
ios? (
|
||||
>=app-pda/usbmuxd-1.0.8
|
||||
>=app-pda/libimobiledevice-1.2.0
|
||||
)
|
||||
speech? ( $(python_gen_cond_dep 'app-accessibility/speech-dispatcher[python,${PYTHON_USEDEP}]') )
|
||||
system-mathjax? ( >=dev-libs/mathjax-3:= )
|
||||
udisks? ( virtual/libudev )
|
||||
unrar? ( dev-python/unrardll )
|
||||
"
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
udisks? ( sys-fs/udisks:2 )"
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
test? ( $(python_gen_cond_dep '>=dev-python/chardet-3.0.3[${PYTHON_USEDEP}]') )
|
||||
"
|
||||
BDEPEND="$(python_gen_cond_dep '
|
||||
>=dev-python/PyQt-builder-1.10.3[${PYTHON_USEDEP}]
|
||||
>=dev-python/sip-5[${PYTHON_USEDEP}]
|
||||
')
|
||||
virtual/pkgconfig
|
||||
system-mathjax? ( dev-lang/rapydscript-ng )
|
||||
verify-sig? ( sec-keys/openpgp-keys-kovidgoyal )
|
||||
"
|
||||
|
||||
PATCHES=(
|
||||
# Skip calling a binary (JxrDecApp) from libjxr which is used for tests
|
||||
# We don't (yet?) package libjxr and it seems to be dead upstream
|
||||
# (last commit in 2017)
|
||||
"${FILESDIR}/${PN}-7.0.0-jxr-test.patch"
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# Warning:
|
||||
#
|
||||
# While it might be rather tempting to add yet another sed here,
|
||||
# please don't. There have been several bugs in Gentoo's packaging
|
||||
# of calibre from seds-which-become-stale. Please consider
|
||||
# creating a patch instead, but in any case, run the test suite
|
||||
# and ensure it passes.
|
||||
#
|
||||
# If in doubt about a problem, checking Fedora's packaging is recommended.
|
||||
|
||||
# Disable unnecessary privilege dropping for bug #287067.
|
||||
sed -e "s:if os.geteuid() == 0:if False and os.geteuid() == 0:" \
|
||||
-i setup/install.py || die "sed failed to patch install.py"
|
||||
|
||||
# This is only ever used at build time. It contains a small embedded copy
|
||||
# of the rapydscript-ng compiler usable inside of qtwebengine, if you don't
|
||||
# have rapydscript-ng (a nodejs package) itself installed. Its only purpose
|
||||
# is to build some resources that come bundled in dist tarballs already...
|
||||
# and which we may also need to regenerate e.g. to use system-mathjax.
|
||||
#
|
||||
# However, running qtwebengine violates the portage sandbox (among other
|
||||
# things, it tries to create directories in /usr! amazing) so this is a
|
||||
# wash anyway. The only real solution here is to package rapydscript-ng.
|
||||
#
|
||||
# We do not need it at build time, and *no one* needs it at install time.
|
||||
# Delete the cruft.
|
||||
rm -r resources/rapydscript/ || die
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
# TODO: get qmake called by setup.py to respect CC and CXX too
|
||||
tc-export CC CXX
|
||||
|
||||
# bug 821871
|
||||
local MY_LIBDIR="${ESYSROOT}/usr/$(get_libdir)"
|
||||
export FT_LIB_DIR="${MY_LIBDIR}" HUNSPELL_LIB_DIR="${MY_LIBDIR}" PODOFO_LIB_DIR="${MY_LIBDIR}"
|
||||
export QMAKE="$(qt6_get_bindir)/qmake"
|
||||
|
||||
edo ${EPYTHON} setup.py build
|
||||
edo ${EPYTHON} setup.py gui
|
||||
|
||||
# A few different resources are bundled in the distfile by default, because
|
||||
# not all systems necessarily have them. We un-vendor them, using the
|
||||
# upstream integrated approach if possible. See setup/revendor.py and
|
||||
# consider migrating other resources to this if they do not use it, in
|
||||
# *preference* over manual rm'ing.
|
||||
edo ${EPYTHON} setup.py liberation_fonts \
|
||||
--path-to-liberation_fonts "${EPREFIX}"/usr/share/fonts/liberation-fonts \
|
||||
--system-liberation_fonts
|
||||
if use system-mathjax; then
|
||||
edo ${EPYTHON} setup.py mathjax --path-to-mathjax "${EPREFIX}"/usr/share/mathjax --system-mathjax
|
||||
edo ${EPYTHON} setup.py rapydscript
|
||||
fi
|
||||
}
|
||||
|
||||
src_test() {
|
||||
# Skipped tests:
|
||||
local _test_excludes=(
|
||||
# unpackaged Python dependency: py7zr
|
||||
7z
|
||||
# unpackaged Python dependency: pyzstd
|
||||
test_zstd
|
||||
# tests if a completely unused module is bundled
|
||||
pycryptodome
|
||||
|
||||
$(usev !speech speech_dispatcher)
|
||||
$(usev !unrar test_unrar)
|
||||
|
||||
# undocumented reasons
|
||||
test_mem_leaks
|
||||
test_searching
|
||||
)
|
||||
|
||||
edo ${PYTHON} setup.py test "${_test_excludes[@]/#/--exclude-test-name=}"
|
||||
}
|
||||
|
||||
src_install() {
|
||||
# Bug #352625 - Some LANGUAGE values can trigger the following ValueError:
|
||||
# File "/usr/lib/python2.6/locale.py", line 486, in getdefaultlocale
|
||||
# return _parse_localename(localename)
|
||||
# File "/usr/lib/python2.6/locale.py", line 418, in _parse_localename
|
||||
# raise ValueError, 'unknown locale: %s' % localename
|
||||
#ValueError: unknown locale: 46
|
||||
export -n LANG LANGUAGE ${!LC_*}
|
||||
export LC_ALL=C.utf8 # bug #709682
|
||||
|
||||
# Bug #295672 - Avoid sandbox violation in ~/.config by forcing
|
||||
# variables to point to our fake temporary $HOME.
|
||||
export HOME="${T}/fake_homedir"
|
||||
export CALIBRE_CONFIG_DIRECTORY="${HOME}/.config/calibre"
|
||||
mkdir -p "${CALIBRE_CONFIG_DIRECTORY}" || die
|
||||
|
||||
addpredict /dev/dri #665310
|
||||
|
||||
# If this directory doesn't exist, zsh completion won't install
|
||||
dodir /usr/share/zsh/site-functions
|
||||
|
||||
edo "${PYTHON}" setup.py install \
|
||||
--staging-root="${ED}/usr" \
|
||||
--prefix="${EPREFIX}/usr" \
|
||||
--libdir="${EPREFIX}/usr/$(get_libdir)" \
|
||||
--staging-libdir="${ED}/usr/$(get_libdir)" \
|
||||
--system-plugins-location="${EPREFIX}/usr/share/calibre/system-plugins"
|
||||
|
||||
cp -r man-pages/ "${ED}"/usr/share/man || die
|
||||
|
||||
find "${ED}"/usr/share -type d -empty -delete || die
|
||||
|
||||
python_fix_shebang "${ED}/usr/bin"
|
||||
|
||||
python_optimize "${ED}"/usr/$(get_libdir)/calibre "${D}/$(python_get_sitedir)"
|
||||
|
||||
newinitd "${FILESDIR}"/calibre-server-3.init calibre-server
|
||||
newconfd "${FILESDIR}"/calibre-server-3.conf calibre-server
|
||||
}
|
||||
Reference in New Issue
Block a user