app-i18n/ibus-typing-booster: new upstream release

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Akinori Hattori <hattya@gentoo.org>

app-i18n/ibus-typing-booster/Manifest

@@ -1 +1,2 @@
 DIST ibus-typing-booster-2.15.22.tar.gz 10779889 BLAKE2B c35306fd3556178257047573f58658ea44d1ceee341964bee5719f5e4509f385e6b1ca520324c66bc417a74d89e5b3eebc7a7413ce2e60398bc83f992eb8a07e SHA512 ae7683434111c7c267c1eb05e88609e0895308443a0510e9eba67000681bb3dfddcf5a652f33bd4b63c7aed10fe2109eafcaae19a4052ae008e92ab9314ae907
+DIST ibus-typing-booster-2.15.25.tar.gz 10785373 BLAKE2B 555105c9da7a813491e3ab8cbea0a8b52239c7ffb39dc7a6ea47e461d81515ba3cdf1adfe8d8cebd74bb2b00775eac3b19956aa9e4c4b696e6083418e2b73e91 SHA512 927f118eac1a641f658b82ef72ec8cd728727910f6c2bd77a14d9195a8203fd40b771e68a04d7ea7c5f5c1f2cd4ff37b7e041282e63f301348b60af462e041ea

app-i18n/ibus-typing-booster/ibus-typing-booster-2.15.25.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="sqlite(+)"
+
+inherit gnome2-utils python-single-r1 xdg
+
+DESCRIPTION="Completion input method for IBus"
+HOMEPAGE="https://mike-fabian.github.io/ibus-typing-booster"
+SRC_URI="https://github.com/mike-fabian/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+RESTRICT="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	dev-libs/m17n-lib
+	$(python_gen_cond_dep '
+		app-i18n/ibus[python(+),${PYTHON_USEDEP}]
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/pyenchant[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/pyxdg[${PYTHON_USEDEP}]
+	')"
+RDEPEND="${DEPEND}
+	>=dev-db/m17n-db-1.7"
+BDEPEND="sys-devel/gettext
+	virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	sed -i "s|/usr\(/bin/sh\)|\1|" {engine,setup}/*.in
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}