dev-libs/appstream-glib: bump to 0.7.9

Closes: https://bugs.gentoo.org/654596
Package-Manager: Portage-2.3.40, Repoman-2.3.9

dev-libs/appstream-glib/Manifest

@@ -1 +1,2 @@
 DIST appstream-glib-0.6.13.tar.xz 1974864 BLAKE2B e9e0967b7657250659b3597bc2f6b049a20750e6dc66ee3672f3794b8c50f5060e48c7d4cd76d16e9e7d7cbc7d3364b7600e1c20fe24b33538c66d2a80cf0888 SHA512 d7e95a31d3f6fba974af2fab423282c7b0291d1325a634d8040fe2c2c2fcde49981be18900415251b3d71f20bb9e945e16d7c00fa830b27deac2e5547ec4c8b0
+DIST appstream-glib-0.7.9.tar.xz 2245728 BLAKE2B fb6f54329bed91f1acaa6218b111fd4527dff7ed412a89cb44a6e4f6cdfb7e0fe4e6f9fb37b6cdc2efa75164dccef323b6d7428a63b08369b941d36b0b9071f0 SHA512 d78cb6f11cad01d67cb33f16e987485177d20b78a8b21cfbabb64ce7b18b813c0d2d1de2faeea199fdc31d12633e899a5596a6cf133cb831a4377d641f79eb7d

dev-libs/appstream-glib/appstream-glib-0.7.9.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit xdg meson
+
+DESCRIPTION="Provides GObjects and helper methods to read and write AppStream metadata"
+HOMEPAGE="https://people.freedesktop.org/~hughsient/appstream-glib/"
+SRC_URI="https://people.freedesktop.org/~hughsient/${PN}/releases/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/8" # soname version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc +introspection stemmer"
+
+RDEPEND="
+	>=dev-libs/glib-2.45.8:2
+	sys-apps/util-linux
+	app-arch/libarchive
+	>=net-libs/libsoup-2.51.92:2.4
+	>=dev-libs/json-glib-1.1.2
+	>=x11-libs/gdk-pixbuf-2.31.5:2[introspection?]
+	app-arch/gcab
+
+	x11-libs/gtk+:3
+	>=media-libs/freetype-2.4:2
+	>=media-libs/fontconfig-2.11:1.0
+	dev-libs/libyaml
+	stemmer? ( dev-libs/snowball-stemmer )
+	x11-libs/pango
+	introspection? ( >=dev-libs/gobject-introspection-0.9.8:= )
+"
+# libxml2 required for glib-compile-resources
+DEPEND="${RDEPEND}
+	dev-util/gperf
+
+	dev-libs/libxml2:2
+	app-text/docbook-xml-dtd:4.2
+	dev-libs/libxslt
+	doc? (
+		>=dev-util/gtk-doc-1.9
+		app-text/docbook-xml-dtd:4.3
+	)
+	>=sys-devel/gettext-0.19.7
+"
+# ${PN} superseeds appdata-tools
+RDEPEND="${RDEPEND}
+	!<dev-util/appdata-tools-0.1.8-r1
+"
+
+src_configure() {
+	local emesonargs=(
+		-Ddep11=true
+		-Dbuilder=true
+		-Drpm=false
+		-Dalpm=false
+		-Dfonts=true
+		$(meson_use stemmer)
+		-Dman=true
+		$(meson_use doc gtk-doc)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}