kde-plasma/kwin: 5.21.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2021-02-23 22:18:23 +01:00
parent dcdf628f9a
commit 08cecf7b5d
2 changed files with 137 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST kwin-5.20.5.tar.xz 6329444 BLAKE2B e80890c1a353b3b8a15659ea3f88e08b84f29ee863aa41ed99758e93008def940450abc2ad66bc2f5d4c9cd391a3d6ddb21eb2ab79d3696b7373f8ae0fdb6d89 SHA512 e9186dc71e3e9b913314a83fe9413b956d61d633f0e8418fd47d82178c6f50eb75b03299c00495af351b0951df23057500ef28123123583c291a0c29ea3414f1
DIST kwin-5.21.0.tar.xz 6392544 BLAKE2B 47eb30a7668ae5f9d61ac79f5d6d1eb89f23d87cf5b4869263d4d742654f5eacf42d89d08942691b221cc765352929b112ffb3c6e5ee7f082484459b67c341a7 SHA512 f311861f6ffa364eaa09aeb8d3a1ef384ac955fd630dcd40dc506feae393bc05e3b71c69a5340a70ca1f6d34ac7070ba7af6f9bc7d7bd9bd82d8842ec1e594d9
DIST kwin-5.21.1.tar.xz 6392952 BLAKE2B 2b541be149060c3a00c635cf7bcb7ea4207c04fbc652b7020d3160dbfcb02ee39d99264eec5454c68e41dc0972c9d87f4809a86962fefceb0c47849931d25fc8 SHA512 a61c4233afb94b14b6a3f87ab5b22e950b02a57f72c5b2a2df1722bb25f99d3fd6c49243e4ccb90ef665d39657dec88efc2908bf76aa69c1a5c8f8c4081604bb
+136
View File
@@ -0,0 +1,136 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
ECM_HANDBOOK="optional"
ECM_TEST="optional"
KFMIN=5.78.0
PVCUT=$(ver_cut 1-3)
QTMIN=5.15.2
VIRTUALX_REQUIRED="test"
inherit ecm kde.org optfeature
DESCRIPTION="Flexible, composited Window Manager for windowing systems on Linux"
LICENSE="GPL-2+"
SLOT="5"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
IUSE="accessibility caps gles2-only multimedia plasma screencast"
RESTRICT+=" test"
COMMON_DEPEND="
>=dev-libs/libinput-1.14
>=dev-libs/wayland-1.2
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtdeclarative-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5=[gles2-only=]
>=dev-qt/qtscript-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=dev-qt/qtx11extras-${QTMIN}:5
>=kde-frameworks/kactivities-${KFMIN}:5
>=kde-frameworks/kauth-${KFMIN}:5
>=kde-frameworks/kcmutils-${KFMIN}:5
>=kde-frameworks/kcompletion-${KFMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/kcrash-${KFMIN}:5
>=kde-frameworks/kdeclarative-${KFMIN}:5
>=kde-frameworks/kglobalaccel-${KFMIN}:5=
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kiconthemes-${KFMIN}:5
>=kde-frameworks/kidletime-${KFMIN}:5=
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/knewstuff-${KFMIN}:5
>=kde-frameworks/knotifications-${KFMIN}:5
>=kde-frameworks/kpackage-${KFMIN}:5
>=kde-frameworks/kservice-${KFMIN}:5
>=kde-frameworks/ktextwidgets-${KFMIN}:5
>=kde-frameworks/kwayland-${KFMIN}:5
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
>=kde-frameworks/kwindowsystem-${KFMIN}:5[X]
>=kde-frameworks/kxmlgui-${KFMIN}:5
>=kde-frameworks/plasma-${KFMIN}:5
>=kde-plasma/breeze-${PVCUT}:5
>=kde-plasma/kdecoration-${PVCUT}:5
>=kde-plasma/kscreenlocker-${PVCUT}:5
>=kde-plasma/kwayland-server-${PVCUT}:5
media-libs/fontconfig
media-libs/freetype
media-libs/lcms:2
media-libs/libepoxy
media-libs/mesa[egl,gbm,wayland,X(+)]
virtual/libudev:=
x11-libs/libX11
x11-libs/libXi
x11-libs/libdrm
>=x11-libs/libxcb-1.10
>=x11-libs/libxkbcommon-0.7.0
x11-libs/xcb-util-cursor
x11-libs/xcb-util-image
x11-libs/xcb-util-keysyms
x11-libs/xcb-util-wm
accessibility? ( media-libs/libqaccessibilityclient:5 )
caps? ( sys-libs/libcap )
gles2-only? ( media-libs/mesa[gles2] )
plasma? ( >=kde-frameworks/krunner-${KFMIN}:5 )
screencast? ( >=media-video/pipewire-0.3:= )
"
# TODO: sys-apps/hwdata? not packaged yet; commit 33a1777a, Gentoo-bug 717216
RDEPEND="${COMMON_DEPEND}
>=dev-qt/qtquickcontrols-${QTMIN}:5
>=dev-qt/qtquickcontrols2-${QTMIN}:5
>=dev-qt/qtvirtualkeyboard-${QTMIN}:5
>=kde-frameworks/kirigami-${KFMIN}:5
>=kde-frameworks/kitemmodels-${KFMIN}:5[qml]
multimedia? ( >=dev-qt/qtmultimedia-${QTMIN}:5[gstreamer,qml] )
"
DEPEND="${COMMON_DEPEND}
>=dev-qt/designer-${QTMIN}:5
>=dev-qt/qtconcurrent-${QTMIN}:5
x11-base/xorg-proto
test? (
>=dev-libs/wayland-protocols-1.19
>=dev-qt/qtwayland-${QTMIN}:5
)
"
PDEPEND="
>=kde-plasma/kde-cli-tools-${PVCUT}:5
"
src_prepare() {
ecm_src_prepare
use multimedia || eapply "${FILESDIR}/${PN}-5.16.80-gstreamer-optional.patch"
# TODO: try to get a build switch upstreamed
if ! use screencast; then
sed -e "s/^pkg_check_modules.*PipeWire/#&/" \
-i CMakeLists.txt || die
fi
}
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package accessibility QAccessibilityClient)
$(cmake_use_find_package caps Libcap)
$(cmake_use_find_package plasma KF5Runner)
)
ecm_src_configure
}
pkg_postinst() {
ecm_pkg_postinst
elog "Optional dependency:"
optfeature "color management support" x11-misc/colord
elog
elog "In Plasma 5.20, default behavior of the Task Switcher to move minimised"
elog "windows to the end of the list was changed so that it remains in the"
elog "original order. To revert to the well established behavior:"
elog
elog " - Edit ~/.config/kwinrc"
elog " - Find [TabBox] section"
elog " - Add \"MoveMinimizedWindowsToEndOfTabBoxFocusChain=true\""
}