kde-plasma/wacomtablet: 6.7.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-plasma/wacomtablet/Manifest

@@ -1 +1,2 @@
 DIST wacomtablet-6.6.5.tar.xz 842952 BLAKE2B e71cff36b7456755be3bfab25ae2c2e2435053c739cc724b9fde567cc42d632f97104534e05f9ef4b3ba24d0a07dba905ac14cd4e68badfd34f6923a6897817d SHA512 dff5efc461af038000401c479926b6605937ff332d8ae6e121f217ab5d1b74ff9f925b372f43373cf589e3949651b5113de0c0eef13245cd9391b7f84cffe923
+DIST wacomtablet-6.7.0.tar.xz 843212 BLAKE2B 55ec5b8373a986fbcbec3df815c7cbc9b062db22d81fb77d55822516c97e062b6c00ff49989eb21c3f06e731850fb04f05eff15444580cf370c2e5d533a1d936 SHA512 bdd1131529b3d0900952b8a88e689266dfede912d60e8f31dbedd73be510765bad0bf58d1c5f6a5074315d8270d1f20249a2045c9da5fce751d05075b417667d

kde-plasma/wacomtablet/wacomtablet-6.7.0.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=6.26.0
+QTMIN=6.10.1
+inherit ecm plasma.kde.org xdg
+
+DESCRIPTION="Wacom system settings module that supports different button/pen layout profiles"
+HOMEPAGE="https://userbase.kde.org/Wacomtablet"
+
+LICENSE="GPL-2"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE=""
+
+# slot op: Uses Qt6::GuiPrivate for qtx11extras_p.h
+RDEPEND="
+	>=dev-libs/libwacom-0.30:=
+	>=dev-qt/qtbase-${QTMIN}:6=[dbus,gui,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kglobalaccel-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-plasma/libplasma-${KDE_CATV}:6=
+	>=kde-plasma/plasma5support-${KDE_CATV}:6
+	>=x11-drivers/xf86-input-wacom-0.20.0
+	x11-libs/libXi
+	x11-libs/libxcb
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+	x11-libs/libX11
+"
+BDEPEND="sys-devel/gettext"
+
+src_test() {
+	# test needs DBus, bug 675548
+	local myctestargs=(
+		-E "(Test.KDED.DBusTabletService)"
+	)
+
+	ecm_src_test
+}