net-im/element-desktop-bin: add 1.11.97, add arm64

Closes: https://github.com/gentoo/gentoo/pull/35920
Closes: https://github.com/gentoo/gentoo/pull/40084
Closes: https://github.com/gentoo/gentoo/pull/41547
Signed-off-by: Joe Kappus <joe@wt.gd>
Signed-off-by: Stefan Strogin <steils@gentoo.org>

net-im/element-desktop-bin/Manifest

@@ -1 +1,3 @@
 DIST element-desktop_1.11.94_amd64.deb 99435530 BLAKE2B 2289844e6e45d765b95758033acd7ee7ec421c10552ed9cf0ebdc992a4abee126c34cd90cf9d4468a5b21420554f5ac27531ac5c801dd959e0a37001551ce311 SHA512 d34f01df54b135d400d8f9d1e507b952bc253df0e13db5f4e82fb86c3647d489467aae855b994ccef7d1a4222494d46e12265341f0c1afc2ca0e4bd80de5f61f
+DIST element-desktop_1.11.97_amd64.deb 107145198 BLAKE2B 1e06fd299dd98d50e3093bca6669bff241b9a120eb10f3c2b0794125794974d52da86da68a44aebb887377cfa81a706bd229a9f80c6eb9383b213878639f0811 SHA512 46279ab8025f652da62b7dff353d302525004a535c04a6d0b4d615ebc01fdf2705dc4d0a9feb5c25df880a6855c33eff58dd7bb403e1decdcfa374c277921bf8
+DIST element-desktop_1.11.97_arm64.deb 117456616 BLAKE2B 724ce248b120867395d9b5c4524a8ac7e57536c9bcc2ec3bd0d5786a2dfd400cd25e1ae71f488087a52bcac249b2ec6da0121003bc57b417ed98175c6e8460a0 SHA512 f79904c94d3c6b0238a247dedfa2157240a63a0c1593934aa483961f7bb5dda55979c2c4092dafe72eca5cf640d617b746bc1e46fa87df5babba28cbf4f306ec

net-im/element-desktop-bin/element-desktop-bin-1.11.97.ebuild

@@ -0,0 +1,89 @@
+# Copyright 2020-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit optfeature unpacker xdg
+
+MY_PN="${PN/-bin}"
+MY_URI="https://packages.element.io/debian/pool/main/e/element-desktop"
+
+DESCRIPTION="A glossy Matrix collaboration client for desktop (binary package)"
+HOMEPAGE="https://element.io"
+SRC_URI="
+	amd64? ( ${MY_URI}/${MY_PN}_${PV}_amd64.deb )
+	arm64? ( ${MY_URI}/${MY_PN}_${PV}_arm64.deb )
+"
+
+S="${WORKDIR}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~arm64"
+RESTRICT="splitdebug"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-crypt/libsecret
+	dev-db/sqlcipher
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nettle
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	sys-apps/dbus
+	virtual/udev
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/pango"
+
+QA_PREBUILT="opt/Element/chrome-sandbox
+	opt/Element/chrome_crashpad_handler
+	opt/Element/element-desktop
+	opt/Element/libEGL.so
+	opt/Element/libGLESv2.so
+	opt/Element/libffmpeg.so
+	opt/Element/libvk_swiftshader.so
+	opt/Element/libvulkan.so.1
+	opt/Element/resources/app.asar.unpacked/node_modules/matrix-seshat/index.node
+	opt/Element/resources/app.asar.unpacked/node_modules/keytar-forked/build/Release/keytar.node"
+
+src_prepare() {
+	default
+	rm opt/Element/{LICENSE.electron.txt,LICENSES.chromium.html} || die
+}
+
+src_install() {
+	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+	gunzip usr/share/doc/${PF}/changelog.gz || die
+
+	insinto /
+	doins -r usr
+	doins -r opt
+	local f
+	for f in ${QA_PREBUILT}; do
+		fperms +x "/${f}"
+	done
+	fperms u+s /opt/Element/chrome-sandbox
+
+	dosym ../../opt/Element/${MY_PN} /usr/bin/${MY_PN}
+	dosym ${MY_PN} /usr/bin/riot-desktop
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	optfeature "emojis" media-fonts/noto-emoji
+}