dev-python/pyatspi: add 2.58.1

Signed-off-by: Pacho Ramos <pacho@gentoo.org>

dev-python/pyatspi/Manifest

@@ -1 +1,2 @@
 DIST pyatspi-2.46.1.tar.xz 323392 BLAKE2B ee55f57616d58ead8bbf14193a984e2d268b0dafd67bdb638086fe531d7d031b6060f2c757036f67ad18ba6c1f774c8ef13a4844c5fb96878604f59903b2653a SHA512 69c1c4c31bef430083a1c9af98ba6b2f1b3d9eec0a5f03982b980838bcf86933069a90d7314d2e5501d5988a453d0a803ad239eca5b98f08cc3bf7dc8d4a7c0c
+DIST pyatspi-2.58.1.tar.xz 82620 BLAKE2B 1c96e56ebd274b3760f6b3568f03a98894d95c991356a16095b5a9ef3be73490347166aa0fb74abc5141c644eb20b5b94234fb43fb0fe2228f469e6a6e86c9bd SHA512 b1ad8baac2a3fde60f13399372813404ca3296d5a7036dd9896a3b0fe509353bc2b98b93abf42efa2e7ca703d416ec32a77118baeebbecbe962e99ef2a985dd8

dev-python/pyatspi/pyatspi-2.58.1.ebuild

@@ -0,0 +1,59 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit gnome.org meson python-r1
+
+DESCRIPTION="Python client bindings for D-Bus AT-SPI"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/pyatspi2"
+
+# Note: only some of the tests are GPL-licensed, everything else is LGPL
+LICENSE="LGPL-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	${PYTHON_DEPS}
+	>=sys-apps/dbus-1
+	>=dev-libs/glib-2.36.0:2
+	>=app-accessibility/at-spi2-core-2.46.0[introspection]
+	dev-libs/libxml2:2
+	>=dev-python/pygobject-2.90.1:3[${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		>=dev-libs/atk-2.46.0
+		dev-python/dbus-python
+	)
+"
+
+src_configure() {
+	python_foreach_impl run_in_build_dir \
+		meson_src_configure -Denable_tests=$(usex test true false)
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir meson_src_compile
+}
+
+src_test() {
+	python_foreach_impl run_in_build_dir \
+		dbus-run-session meson test -C "${BUILD_DIR}" || die
+}
+
+src_install() {
+	python_foreach_impl run_in_build_dir meson_src_install
+	python_foreach_impl run_in_build_dir python_optimize
+
+	einstalldocs
+	docinto examples
+	dodoc examples/*.py
+}