dev-go/delve: add 1.25.1

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-go/delve/Manifest

@@ -1,2 +1,3 @@
 DIST delve-1.24.1.tar.gz 9680270 BLAKE2B 51d9e7ddf6127adc65c9fbc29029d8ac0219f3dfbddb02e552bd89d6060f0f8b81f5ad717b1c724eae244fddca073e10e175c6d36c7033a8a2630c55366ebe69 SHA512 7308339af2ef0da14b3d1860d99a602f6fdf3861afd12fd25930c2587bec3099905d3c74ae3d93a193d9aebc77bea4eb4fe3878e3a84c45616ea9926d6b6ba27
 DIST delve-1.24.2.tar.gz 9685412 BLAKE2B 948c91c86ddd11a3d5df3a519e97172a1aac58126519508268f0bb872f45148fcd3a98728821ad6a7ac4bff547190618c2592056f811848f18e61bcbf1eedf54 SHA512 0a81eea4a941d36c310dc540c5604dcd6fc9b48bbb8c32dba27a0ea9ddf6677862c79e3eebc8bdcbc690922869bd1d2e4fbece2556a07f994eb0cf7d11f8b18c
+DIST delve-1.25.1.tar.gz 9793261 BLAKE2B 7a90a3c39c34fb2f9ee86d8a33e106aec426505d764a4d5b42d9eb5843474a603925eb130c6e8b54042b3d21c4c07c9be0f90b21b2db3c8ea97018eb7a6aab2f SHA512 a2d380d9430d99844ae27ca4985b7077c53effe5940cb5cb9fdbc36ed39c3338a455f43484bd3c95381e6ecd37d7fe1b4345e6630dcc22a5c76b3777126e1c71

dev-go/delve/delve-1.25.1.ebuild

@@ -0,0 +1,46 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit go-module
+
+DESCRIPTION="A source-level debugger for the Go programming language"
+HOMEPAGE="https://github.com/go-delve/delve"
+SRC_URI="https://github.com/go-delve/delve/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT BSD BSD-2 Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+src_prepare() {
+	default
+
+	# disable failing tests, require network
+	rm cmd/dlv/dlv_test.go || die
+	sed -e 's/TestGuessSubstitutePath/_&/' -i service/test/integration2_test.go || die
+}
+
+src_compile() {
+	ego build -mod=vendor -ldflags="-X main.Build=${PV}" -o "${S}/dlv" ./cmd/dlv
+}
+
+src_test() {
+	ego test -count 1 -p 1 -ldflags="-X main.Build=${PV}" ./...
+}
+
+src_install() {
+	dobin dlv
+	dodoc README.md CHANGELOG.md
+}
+
+pkg_postinst() {
+	elog "Telemetry notice:"
+	elog "Starting with version 1.24.0, Delve will begin collecting opt-in telemetry"
+	elog "data using the same mechanism used by the Go toolchain."
+	elog
+	elog "For more information, please see:"
+	elog "  * https://github.com/golang/go/issues/68384"
+	elog "  * https://go.dev/doc/telemetry#background"
+	elog "  * https://github.com/go-delve/delve/issues/3815"
+}