gnome-base/gnome-keyring: Drop old versions

Signed-off-by: Matt Turner <mattst88@gentoo.org>

gnome-base/gnome-keyring/Manifest

@@ -1,3 +1,2 @@
 DIST gnome-keyring-40.0.tar.xz 1333440 BLAKE2B 4ef74d982d85766e8d7f28b97ddf295ca546f48b980518be7e586bda607344bdb72c124f92b5c34310aeb2f3903cb39092ae7ca6e1b3baf34ab6a9c58d26aeef SHA512 c9cb0dca8c46ee712200c96c20663a8d5cd39f07801a04e1afca26550a04af6cb369b53a1f29638bf4c8a29f418a69f565befcf4d08df5b0d30fb31894ecf95e
-DIST gnome-keyring-42.0.tar.xz 1346024 BLAKE2B 355d2552dda22c65058b338b9683ffa4500431c0d19e086663d80a5c5043ac9b06e7dfa9ceed84964ece9cc4da238469ffa559f885a2c9f9ee17d8e53d6e183b SHA512 edefee5fad69b621a5243e588d32e2d0d15577313001d9949989337a610fc52ff43295a99d7470628a7cf92b6f8a4c31f37bf424183a925e9ee92a202e7721e0
 DIST gnome-keyring-42.1.tar.xz 1346284 BLAKE2B ff6093cc16c649cda1e6cc2848c2198a502d8aa20a56f0a4dca00550e99f18820028427a7ec3979b6871648a7931da19fced3210558d5ca3de47983b7c94452d SHA512 560dc409c21768dcbdf42151986a5bbbfb9a092d2c36295cf76bd603cdf9650fa80670631c7fb8b3e1822bed6a1f55c34b2170a1419ce45fbe8ca08c7eaf3a57

gnome-base/gnome-keyring/gnome-keyring-42.0.ebuild

@@ -1,80 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-PYTHON_COMPAT=( python3_{8..10} )
-
-inherit gnome2 pam python-any-r1 virtualx
-
-DESCRIPTION="Password and keyring managing daemon"
-HOMEPAGE="https://wiki.gnome.org/Projects/GnomeKeyring"
-
-LICENSE="GPL-2+ LGPL-2+"
-SLOT="0"
-IUSE="pam selinux +ssh-agent systemd test"
-RESTRICT="!test? ( test )"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
-
-# Replace gkd gpg-agent with pinentry[gnome-keyring] one, bug #547456
-RDEPEND="
-	>=app-crypt/gcr-3.27.90:=[gtk]
-	>=app-crypt/gnupg-2.0.28:=
-	>=app-eselect/eselect-pinentry-0.5
-	app-misc/ca-certificates
-	>=dev-libs/glib-2.44:2
-	>=dev-libs/libgcrypt-1.2.2:0=
-	pam? ( sys-libs/pam )
-	selinux? ( sec-policy/selinux-gnome )
-	ssh-agent? ( net-misc/openssh )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	>=app-eselect/eselect-pinentry-0.5
-	app-text/docbook-xml-dtd:4.3
-	dev-libs/libxslt
-	>=sys-devel/gettext-0.19.8
-	virtual/pkgconfig
-	test? ( ${PYTHON_DEPS} )
-"
-
-pkg_setup() {
-	use test && python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	# Disable stupid CFLAGS with debug enabled
-	sed -e 's/CFLAGS="$CFLAGS -g"//' \
-		-e 's/CFLAGS="$CFLAGS -O0"//' \
-		-i configure.ac configure || die
-
-	gnome2_src_prepare
-}
-
-src_configure() {
-	gnome2_src_configure \
-		--without-libcap-ng \
-		$(use_enable pam) \
-		$(use_with pam pam-dir $(getpam_mod_dir)) \
-		$(use_enable selinux) \
-		$(use_enable ssh-agent) \
-		$(use_enable systemd) \
-		--enable-doc
-}
-
-src_test() {
-	# Needs dbus-run-session to not get:
-	# ERROR: test-dbus-search process failed: -6
-	"${BROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/schema" || die
-	GSETTINGS_SCHEMA_DIR="${S}/schema" virtx dbus-run-session emake check
-}
-
-pkg_postinst() {
-	# cap_ipc_lock only needed if building --with-libcap-ng, but that breaks with glib-2.70
-	# Never install as suid root, this breaks dbus activation, see bug #513870
-	gnome2_pkg_postinst
-
-	if ! [[ $(eselect pinentry show | grep "pinentry-gnome3") ]] ; then
-		ewarn "Please select pinentry-gnome3 as default pinentry provider:"
-		ewarn " # eselect pinentry set pinentry-gnome3"
-	fi
-}