app-admin/ansible-base: 2.10.4 bump

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

app-admin/ansible-base/Manifest

@@ -1,2 +1,3 @@
 DIST ansible-base-2.10.2.tar.gz 6023200 BLAKE2B 80abfa3fab56d3f997cbe90b557ffd5004b216709d6ba2c6d50ea0fb7a2e5a2ad49ce83bfc7a17054582e786f53ce29814d8b5a3fc2408a1e729b1647619080c SHA512 2ee60303841e88d3451ddbcc4c18473d3a37253873406b0783816b1bbf9d8404599ebed12bac7c7f32693314048668b84f3a1c593621c7b8c37a7b48687c769b
 DIST ansible-base-2.10.3.tar.gz 5836841 BLAKE2B 000ee1e369beb450a9a58680030fc7605f62020a28f0ec4634569be0b12ca54c79d0c36a6022895f93b6f8449b8f8483e07590eeea233383490600bbce600aff SHA512 4da2c79c7d990bbe07e136447643484d947e512693194017623deadd88d6556dac67865069182059ae2daf82a13876600dc5472712d6ab6e0556cb829fce3b5b
+DIST ansible-base-2.10.4.tar.gz 5708083 BLAKE2B dcae17dd84dd1985703bf55bffd4a7907ecf072fcc52c76633fd2fc1d3461901b284002f69ce542ab8447f7aa6a2f65ff4c9abca1a7c1c8df3ad69a4179b1c33 SHA512 50dcccc0b40f47590d3ea56907f987bddbb858952b0d6a999db0b706232a571037dc31e66a773370be57ca14d11a7091c53a480d7f3cecf4a5e7f91895661100

app-admin/ansible-base/ansible-base-2.10.4.ebuild

@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Model-driven deployment, config management, and command execution framework"
+HOMEPAGE="https://ansible.com/"
+SRC_URI="https://releases.ansible.com/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~x64-macos"
+IUSE="test"
+RESTRICT="test"
+# doc removed due to https://github.com/ansible/ansible/issues/71395
+
+RDEPEND="
+	dev-python/paramiko[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/httplib2[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/netaddr[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	net-misc/sshpass
+	virtual/ssh
+	!<app-admin/ansible-2.10
+"
+# ansible-2.10 or above is needed for the collections
+DEPEND="
+	!<app-admin/ansible-2.10
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/packaging-16.6[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+		>=dev-python/mock-1.0.1[${PYTHON_USEDEP}]
+		dev-python/passlib[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/unittest2[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)"
+
+python_compile() {
+	# disable version checks on upgrade
+	export ANSIBLE_SKIP_CONFLICT_CHECK=1
+	distutils-r1_python_compile
+}
+
+python_test() {
+	nosetests -d -w test/units -v --with-coverage --cover-package=ansible --cover-branches || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	dodoc -r examples
+}