dev-python/notebook: Bump to 6.1.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/notebook/Manifest

@@ -1,2 +1,3 @@
 DIST notebook-5.0.0.tar.gz 11481080 BLAKE2B 3cc483d338ca22c6b4d7199100875e9425f90e1a7059c016cec07500f0558c437db5f7e367a5c4441520deb68fa891be31c07cd93e858c872a1f12d893530479 SHA512 fbee29cc554f36e94b1fe9804187a50581e840cfb5884bcdf2fef82ad9ae3ae0e2082ea0056f815bfa2a1c2f203679169155e61e53253aa2e9004a43ff7fbcae
 DIST notebook-6.0.3.tar.gz 14048151 BLAKE2B ad4e433accc90acc13efc8005146dd8bcf2e645c104473f0e71d8d9fab80d7e128eb4e070b8aa04aee77e0d6115499e61beb841d94cf66b0e098dc50d3916cbd SHA512 fb56d0e10da3f8673e9578cdf04759dc3247547af6be4f479e9b183f3c5bd0a891fbfede187e0f5aca5c6ffdb9cae6ada23fe6dd159aca2d9cdf967f1f150922
+DIST notebook-6.1.0.tar.gz 13794330 BLAKE2B bba5bde7b40cac4bf6a730d7f37005b74e19665e182ea8f81f748ed6a1f3790a019a9f57d1c232403373fbccbf446277e0bc6617556f4fce4487c2c968d8d6aa SHA512 be584c13e2a285076977cc94601e0cfe10f53e3c112a641d97b2128422bfcb48514d8651928ae703237ff7a956965a85066a363079dcd6a636f6dd6467371499

dev-python/notebook/notebook-6.1.0.ebuild

@@ -0,0 +1,93 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6..9} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Jupyter Interactive Notebook"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-libs/mathjax-2.4
+	dev-python/argon2-cffi[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=dev-python/terminado-0.8.3[${PYTHON_USEDEP}]
+	>=www-servers/tornado-5.0[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.2.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_core-4.6.1[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-5.3.4[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-4.2.0[${PYTHON_USEDEP}]
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	dev-python/prometheus_client[${PYTHON_USEDEP}]"
+
+# sphinx 2+ seems to have a problem with its github plugin. temporarily adding
+# a version constraint.
+BDEPEND="
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/nose_warnings_filters[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/requests-unixsocket[${PYTHON_USEDEP}]
+	)
+	"
+
+PATCHES=(
+	"${FILESDIR}/${PN}"-5.7.0-no-mathjax.patch
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# disable bundled mathjax
+	sed -i 's/^.*MathJax.*$//' bower.json || die
+
+	# require geckodriver
+	rm -r notebook/tests/selenium || die
+	# trash doesn't seem to work for us
+	sed -e 's:test_delete:_&:' \
+		-i notebook/services/contents/tests/test_manager.py || die
+	sed -e 's:test_checkpoints_follow_file:_&:' \
+		-e 's:test_delete:_&:' \
+		-i notebook/services/contents/tests/test_contents_api.py || die
+	# network-sandbox?
+	sed -e 's:test_connections:_&:' \
+		-e 's:test_culling:_&:' \
+		-i notebook/services/kernels/tests/test_kernels_api.py || die
+
+	sed -i -e "/'bdist_egg':/d" setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	distutils_install_for_testing
+	local -x PATH=${TEST_DIR}/scripts:${PATH}
+	pytest -vv || die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	ln -sf \
+		"${EPREFIX}/usr/share/mathjax" \
+		"${D}$(python_get_sitedir)/notebook/static/components/MathJax" || die
+}
+
+pkg_preinst() {
+	# remove old mathjax folder if present
+	rm -rf "${EROOT}"/usr/lib*/python*/site-packages/notebook/static/components/MathJax || die
+}