app-misc/workrave: Version bump (#564254 by Perfect Gentleman)

Package-Manager: portage-2.2.23
This commit is contained in:
Pacho Ramos
2015-11-07 11:12:38 +01:00
parent 1963597908
commit 07cd3babae
2 changed files with 106 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST v1_10_6.tar.gz 6444740 SHA256 f8699fbbfef7f3de2226f5f7dc4c74d98de3b59bfed4c6dac70bb231ec405760 SHA512 5c2a7dac1614751edf925eefa945e08e0b2fb318903b12fc8d4acde0b6027ecb534c90933da14796edc958f0d9a2f892815fddea9ab41ac921756fc5577acd8e WHIRLPOOL 91c47a66f0ab60f2560b103ef7ac6591088296b470d3403d6d9f511d44e361fc6841d9fda85d9c24d6c60595ea66b2a18ebb34c806d3ab4b465895a427a6d819
DIST workrave-1.10.6.tar.gz 6444740 SHA256 f8699fbbfef7f3de2226f5f7dc4c74d98de3b59bfed4c6dac70bb231ec405760 SHA512 5c2a7dac1614751edf925eefa945e08e0b2fb318903b12fc8d4acde0b6027ecb534c90933da14796edc958f0d9a2f892815fddea9ab41ac921756fc5577acd8e WHIRLPOOL 91c47a66f0ab60f2560b103ef7ac6591088296b470d3403d6d9f511d44e361fc6841d9fda85d9c24d6c60595ea66b2a18ebb34c806d3ab4b465895a427a6d819
DIST workrave-1.10.8.tar.gz 6370506 SHA256 15e0c87c2172dc249031d97d4020ee4a47ea9073aa26dc06a4b15e91abf88479 SHA512 67c3725627b42c5b32a61eb4e62e45b4a802806217ddb311ee2b610d281f9c521f69cc4da0db5ded63c99691d9f5c272493a911ba504f335508ac64945cd7403 WHIRLPOOL 9fe2c6dbd2abacc76190dac94ed334bb8ecad1dfb714afa6fee69cbbeae3981f960113dce52b54fb6935bacb29d7ad3939b4aba6ef6323b93d05b56b166edb7e
+105
View File
@@ -0,0 +1,105 @@
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
GCONF_DEBUG="no" # --enable-debug only messes up with FLAGS
PYTHON_COMPAT=( python2_7 )
inherit autotools eutils gnome2 python-single-r1 versionator vcs-snapshot
DESCRIPTION="Helpful utility to attack Repetitive Strain Injury (RSI)"
HOMEPAGE="http://www.workrave.org/"
MY_PV=$(replace_all_version_separators '_')
SRC_URI="https://github.com/rcaelers/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
# dbus support looks to be used only for trying to use panel applets on gnome3!
IUSE="ayatana doc gnome gstreamer introspection mate nls pulseaudio test xfce"
REQUIRED_USE="ayatana? ( introspection )"
RDEPEND="
>=dev-libs/glib-2.28.0:2
>=x11-libs/gtk+-3.0:3[introspection?]
>=dev-cpp/gtkmm-3.0.0:3.0
>=dev-cpp/glibmm-2.28.0:2
>=dev-libs/libsigc++-2.2.4.2:2
ayatana? (
>=dev-libs/libdbusmenu-0.4[gtk3,introspection]
>=dev-libs/libindicator-0.4:3 )
gnome? ( >=gnome-base/gnome-shell-3.6.2 )
gstreamer? (
media-libs/gstreamer:1.0[introspection?]
media-libs/gst-plugins-base:1.0[introspection?]
media-plugins/gst-plugins-meta:1.0 )
introspection? ( dev-libs/gobject-introspection:= )
mate? ( mate-base/mate-applets )
pulseaudio? ( >=media-sound/pulseaudio-0.9.15 )
xfce? (
>=x11-libs/gtk+-2.6.0:2[introspection?]
>=xfce-base/xfce4-panel-4.4 )
x11-libs/libXScrnSaver
x11-libs/libSM
x11-libs/libX11
x11-libs/libXtst
x11-libs/libXt
x11-libs/libXmu
"
# dbus? (
# >=sys-apps/dbus-1.2
# dev-libs/dbus-glib )
DEPEND="${RDEPEND}
>=dev-util/intltool-0.40.0
x11-proto/xproto
x11-proto/inputproto
x11-proto/recordproto
dev-python/cheetah
virtual/pkgconfig
doc? (
app-text/docbook-sgml-utils
app-text/xmlto )
nls? ( >=sys-devel/gettext-0.17 )
"
pkg_setup() {
python-single-r1_pkg_setup
}
src_unpack() {
vcs-snapshot_src_unpack
}
src_prepare() {
# Fix gstreamer slot automagic dependency, bug #563584
# http://issues.workrave.org/show_bug.cgi?id=1179
epatch "${FILESDIR}"/${PN}-1.10.6-automagic-gstreamer.patch
eautoreconf
gnome2_src_prepare
}
src_configure() {
# gnet ("distribution") is dead for ages and other distributions stopped
# relying on it for such time too.
gnome2_src_configure \
--disable-dbus \
--disable-distribution \
--enable-exercises \
--disable-experimental \
--disable-gnome2 \
--disable-static \
--disable-xml \
$(use_enable ayatana indicator) \
$(use_enable doc manual) \
$(use_enable gnome gnome3) \
$(use_enable gstreamer) \
$(use_enable introspection) \
$(use_enable mate) \
$(use_enable nls) \
$(use_enable pulseaudio pulse) \
$(use_enable test tests) \
$(use_enable xfce)
}