app-emulation/q4wine: version bump 1.3.6

Closes: https://bugs.gentoo.org/634884
Package-Manager: Portage-2.3.14, Repoman-2.3.6

app-emulation/q4wine/Manifest

@@ -1 +1,2 @@
-DIST q4wine-1.3.5.tar.bz2 2862445 SHA256 aa48b0ea8ff504e341b3352194380aa256f6ac8a6a301e1bbf30196eec8d310c SHA512 54fb7bce28750cb71589f6a94658f61369c7777cf7865b71d2feea4ac1221714d861a781fbd1325ee3d21f124162fd2eedc2780ab2bd0af93864eefebcde5f4c WHIRLPOOL b52408ade21dab7203b3d8032e196a2e63f5a806f08fcd8fa6a1d839b4f457475b94d0962e29dbd0ac0a5a9bcaf9bd64786b2268af9b6fc446d1328baee3c1fe
+DIST q4wine-1.3.5.tar.bz2 2862445 BLAKE2B 0de9e61f18c8dedccfa3fc1f42eb6f26b0a99534cb3ad3cc5da06ea2f2fdfcb8d164a05a591a1bc6c959cdc183d98696dee50c78eb73e430198dc901137729f4 SHA512 54fb7bce28750cb71589f6a94658f61369c7777cf7865b71d2feea4ac1221714d861a781fbd1325ee3d21f124162fd2eedc2780ab2bd0af93864eefebcde5f4c
+DIST q4wine-1.3.6.tar.bz2 2867547 BLAKE2B b35a638e514108e4ee4be34b446a7d2d5ba00415d8f54cfee293988707b637d41945d3197a2132147e09d5a05153fd47a55701dcba358f3a2b3a2e6037f78aaa SHA512 1ff0ea2a4523fc5582ec67f5e305622653c4e387ac5f2cecde52289117ef879a60261fdbf9ddf421812765539124d4c5b6b37ff401530d3e061723a3c35d57f8

app-emulation/q4wine/q4wine-1.3.6.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils gnome2-utils xdg-utils
+
+# Upstream names the package PV-rX. We change that to
+# PV_pX so we can use portage revisions.
+MY_P=${PN}-${PV/_p/-r}
+
+DESCRIPTION="Qt GUI configuration tool for Wine"
+HOMEPAGE="http://q4wine.brezblock.org.ua/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+dbus debug +ico +iso +wineappdb"
+
+CDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsingleapplication[qt5,X]
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dbus? ( dev-qt/qtdbus:5 )
+	ico? ( >=media-gfx/icoutils-0.26.0 )
+"
+DEPEND="${CDEPEND}
+	dev-qt/linguist-tools:5
+"
+RDEPEND="${CDEPEND}
+	app-admin/sudo
+	>=sys-apps/which-2.19
+	iso? ( sys-fs/fuseiso )
+"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( AUTHORS ChangeLog README )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug ON OFF)
+		-DWITH_ICOUTILS=$(usex ico ON OFF)
+		-DWITH_SYSTEM_SINGLEAPP=ON
+		-DWITH_WINEAPPDB=$(usex wineappdb ON OFF)
+		-DUSE_BZIP2=OFF
+		-DUSE_GZIP=OFF
+		-DWITH_DBUS=$(usex dbus ON OFF)
+	)
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}