dev-python/stripe: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/stripe/Manifest

@@ -1,2 +1 @@
-DIST stripe-4.0.2.tar.gz 252436 BLAKE2B d05153e4ddc58b5cbb9f42202a5b8dbcaeff39fab51b5415c59bbbfd615003b4d76881a408fd067a0e17d275a663e7ac8d574af6ead90f9c51e677617ef6117b SHA512 b13ace2419555e21a93f37a328bd59d9ac8af69787dc89ed4851ce5a5a616a34e63d5667b9981f43c486dafee18186a9dc32524c047c9db204dc8ba831198c91
 DIST stripe-4.1.0.tar.gz 266799 BLAKE2B ce801bd6d4536163d7fc56b46b23a76d0ed2c392be65b8891750d0c413e3d8195004b09603fc3f360ea97e32e6472f887aa41ca502cf8a0460b9bac3ece610b3 SHA512 6a243526d56bc83caced776850bc3d2582c19f28779684bbf7b0a81f477d8c02c21151052b05b31160f2f81a83f5d7260bd82c171681a059b12012e794c6e5cf

dev-python/stripe/stripe-4.0.2.ebuild

@@ -1,71 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{8..11} pypy3 )
-
-inherit distutils-r1
-
-DESCRIPTION="Stripe python bindings"
-HOMEPAGE="
-	https://github.com/stripe/stripe-python/
-	https://pypi.org/project/stripe/
-"
-SRC_URI="mirror://pypi/s/${PN}/${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="amd64 x86"
-
-RDEPEND="
-	>=dev-python/requests-2.20[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		>=dev-util/stripe-mock-0.141.0
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-		net-misc/curl
-	)
-"
-
-distutils_enable_tests pytest
-
-DOCS=( LONG_DESCRIPTION.rst CHANGELOG.md README.md )
-
-python_test() {
-	epytest tests
-}
-
-src_test() {
-	local stripe_mock_port=12111
-	local stripe_mock_max_port=12121
-	local stripe_mock_logfile="${T}/stripe_mock_${EPYTHON}.log"
-	# Try to start stripe-mock until we find a free port
-	while [[ "${stripe_mock_port}" -le "${stripe_mock_max_port}" ]]; do
-		ebegin "Trying to start stripe-mock on port ${stripe_mock_port}"
-		stripe-mock --http-port ${stripe_mock_port} &> "${stripe_mock_logfile}" &
-		local stripe_mock_pid=$!
-		sleep 2
-		# Did stripe-mock start?
-		curl --fail -u "sk_test_123:" \
-			http://127.0.0.1:${stripe_mock_port}/v1/customers &> /dev/null
-		eend $? "Port ${stripe_mock_port} unavailable"
-		if [[ $? -eq 0 ]]; then
-			einfo "stripe-mock running on port ${stripe_mock_port}"
-			break
-		fi
-		(( stripe_mock_port++ ))
-	done
-	if [[ "${stripe_mock_port}" -gt "${stripe_mock_max_port}" ]]; then
-		eerror "Unable to start stripe-mock for tests"
-		die "Please see the logfile located at: ${stripe_mock_logfile}"
-	fi
-
-	local -x STRIPE_MOCK_PORT=${stripe_mock_port}
-	distutils-r1_src_test
-
-	# Tear down stripe-mock
-	kill "${stripe_mock_pid}" || die "Unable to stop stripe-mock"
-}