gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-06 00:48:18 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/spyder-kernels: Bump to 2.3.1

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2022-05-22 07:28:25 +02:00
parent 9f67c3b548
commit 074f4f92b3
2 changed files with 74 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/spyder-kernels/Manifest
View File

@@ -1 +1,2 @@
DIST spyder-kernels-2.3.0.tar.gz 89425 BLAKE2B 60f9894ef83e1e4df828b35da4a1453721bfe4fe5f9c5655a120835e936a10c90cfc0431553b57e89e1a4cd81b5290709d9b0389bf961f29e5dfdc3caabeb190 SHA512 86b523b8c5a873ded6f222a42a0137143d134f1cdbe54a2d3d7019f4514eea9c117d7e56586092c568eda5eb101a7779b4e9b757d50649bb7ba314b1afaaa836
DIST spyder-kernels-2.3.1.gh.tar.gz 89715 BLAKE2B 567101be14bc759a995b5753ecf129a1e3fb466a16e4d84d55cf19223d8e3bbd439bf519376bd0dfad13b076fcd29aa3f4f7ab66dfa2525f300e7842b7aa2bc7 SHA512 e8831204f242b68a8aff29f3e66c78f38a8b09542d651754c557af7333e7e3d9fa85ac1dd048972cd1f7eadedee3017afd5b2d012b1473b261603e9990ee12af

73
dev-python/spyder-kernels/spyder-kernels-2.3.1.ebuild Normal file
View File

@@ -0,0 +1,73 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..10} )
inherit distutils-r1
DESCRIPTION="Kernels used by spyder on its ipython console"
HOMEPAGE="
https://github.com/spyder-ide/spyder-kernels/
https://pypi.org/project/spyder-kernels/
"
SRC_URI="
https://github.com/spyder-ide/${PN}/archive/v${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
RDEPEND="
dev-python/cloudpickle[${PYTHON_USEDEP}]
<dev-python/ipykernel-7[${PYTHON_USEDEP}]
>=dev-python/ipykernel-6.9.2[${PYTHON_USEDEP}]
>=dev-python/ipython-7.31.1[${PYTHON_USEDEP}]
<dev-python/jupyter_client-8[${PYTHON_USEDEP}]
>=dev-python/jupyter_client-7.3.1[${PYTHON_USEDEP}]
dev-python/matplotlib-inline[${PYTHON_USEDEP}]
>=dev-python/pyzmq-22.1.0[${PYTHON_USEDEP}]
>=dev-python/wurlitzer-1.0.3[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/cython[${PYTHON_USEDEP}]
dev-python/dask[${PYTHON_USEDEP}]
dev-python/flaky[${PYTHON_USEDEP}]
dev-python/matplotlib[${PYTHON_USEDEP}]
dev-python/mock[${PYTHON_USEDEP}]
dev-python/numpy[${PYTHON_USEDEP}]
dev-python/pandas[${PYTHON_USEDEP}]
dev-python/scipy[${PYTHON_USEDEP}]
dev-python/xarray[${PYTHON_USEDEP}]
dev-python/pillow[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
EPYTEST_DESELECT=(
# we no longer package distributed
spyder_kernels/console/tests/test_console_kernel.py::test_dask_multiprocessing
# RuntimeError: There is no current event loop in thread 'MainThread'.
# https://bugs.gentoo.org/834893
spyder_kernels/console/tests/test_console_kernel.py::test_cwd_in_sys_path
spyder_kernels/console/tests/test_console_kernel.py::test_multiprocessing
spyder_kernels/console/tests/test_console_kernel.py::test_multiprocessing_2
spyder_kernels/console/tests/test_console_kernel.py::test_runfile
spyder_kernels/console/tests/test_console_kernel.py::test_np_threshold
spyder_kernels/console/tests/test_console_kernel.py::test_turtle_launch
spyder_kernels/console/tests/test_console_kernel.py::test_matplotlib_inline
)
python_prepare_all() {
# No additional test failures with ipython-8: 843251
sed -i -e "/ipython/s:,<8::" setup.py || die
distutils-r1_python_prepare_all
}