sci-astronomy/kstars: 3.3.8 version bump

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

sci-astronomy/kstars/Manifest

@@ -1 +1,2 @@
 DIST kstars-3.2.3.tar.xz 70750660 BLAKE2B ea44b1ab2ba5d34a472b513180c148093defeff9fc2b8fb823621149b836a6fb7d6f53e0e50765de7c423fcdcdfc8fac6ae4feb4c4670d475353e091fa14d20c SHA512 29c534c860cb1ab2c52e497061b16c7870e63253a7184f79ed8565d56abbc2909160d7f8c649764e4eb7462630e30e4428a88753e7987e97e530b174076cbd37
+DIST kstars-3.3.8.tar.xz 70991244 BLAKE2B f8f1508d0eb019d5247df8bdd5472dff42113ed24625f581482e2f403da0d1e6311b6c6e9d78a67548b9cec8b2536fbe1e3f886f16bd493d275b7414c8af8033 SHA512 bfc6b6a4e1d9856d290468b44071f02fe3e2c0f0b3bd90f9c3ebe671abee9e18c24898777065a21adbd4794e8e64beb17c6d339b88cabe750bf3b3a9efb327d0

sci-astronomy/kstars/kstars-3.3.8.ebuild

@@ -0,0 +1,95 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+PYTHON_COMPAT=( python2_7 )
+KFMIN=5.60.0
+QTMIN=5.12.3
+inherit ecm kde.org python-single-r1
+
+DESCRIPTION="Desktop Planetarium"
+HOMEPAGE="https://kde.org/applications/education/org.kde.kstars
+https://edu.kde.org/kstars/"
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	SRC_URI="mirror://kde/stable/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2" # TODO CHECK
+SLOT="5"
+IUSE="fits indi +password raw wcs"
+
+REQUIRED_USE="indi? ( fits ) ${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="
+	>=dev-qt/qtdatavis3d-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwebsockets-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kplotting-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	sys-libs/zlib
+	fits? ( sci-libs/cfitsio )
+	indi? (
+		>=sci-libs/indilib-1.7.5
+		sci-libs/libnova
+	)
+	password? ( dev-libs/qtkeychain:= )
+	raw? ( media-libs/libraw:= )
+	wcs? ( sci-astronomy/wcslib )
+"
+# TODO: Add back when re-enabled by upstream
+# 	opengl? (
+# 		>=dev-qt/qtopengl-${QTMIN}:5
+# 		virtual/opengl
+# 	)
+DEPEND="${COMMON_DEPEND}
+	dev-cpp/eigen:3
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	${PYTHON_DEPS}
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DFETCH_TRANSLATIONS=OFF
+		-DBUILD_DOC=$(usex handbook)
+		$(cmake-utils_use_find_package fits CFitsio)
+		$(cmake-utils_use_find_package indi INDI)
+		$(cmake-utils_use_find_package password Qt5Keychain)
+		$(cmake-utils_use_find_package raw LibRaw)
+		$(cmake-utils_use_find_package wcs WCSLIB)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if [[ -z "${REPLACING_VERSIONS}" ]] && ! has_version "x11-misc/xplanet" ; then
+		elog "${PN} has optional runtime support for x11-misc/xplanet"
+	fi
+	# same for AstrometryNet, which is not packaged.
+}