media-sound/qtractor: bump to 0.9.30

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>
2026-09-24 04:59:14 -07:00 · 2022-12-30 10:31:32 +01:00
parent 451b63134c
commit 06de17815e
2 changed files with 109 additions and 0 deletions
--- a/media-sound/qtractor/Manifest
+++ b/media-sound/qtractor/Manifest
@@ -1 +1,2 @@
 DIST qtractor-0.9.29.tar.gz 1988719 BLAKE2B d7f17211e885c8458c7d74d1cd0cde69d316b1765ab79bdfb3ff1abcfb35ad008f017dd12372a2fafb309a7bead0c3d31f8f1cc322da123d39760377c1883e82 SHA512 bd432e3eb2d804aacc45943c36160c938778827a1c832f30045b2456d363843ac2f77e4b2cb897b905aa026b7d9238eb2963ca1ebbd64d127d890857c5426c41
+DIST qtractor-0.9.30.tar.gz 2005653 BLAKE2B 3d1e21a949a90b4986f7fee0394f28520cf23b420fa0705e8971805a7b4681dd33176b4a77f02559849455bda5ce1a9969d09fc44992ba4df00cecb7fd6311c1 SHA512 610ed5a84d14bff9c37205493cfe70636ce59d574eecd8ca1e8827b4867c4240927038cf56e96fa1b862172e2ed10f781befdfaca30da9f4fc774da0ecdba7be
--- a/media-sound/qtractor/qtractor-0.9.30.ebuild
+++ b/media-sound/qtractor/qtractor-0.9.30.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="Audio/MIDI multi-track sequencer written in C++ with the Qt framework"
+HOMEPAGE="https://qtractor.sourceforge.io"
+SRC_URI="mirror://sourceforge/qtractor/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="aubio cpu_flags_x86_sse debug dssi ladspa libsamplerate mad osc rubberband vorbis zlib"
+REQUIRED_USE="dssi? ( ladspa )"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dev-qt/qtx11extras:5
+	media-libs/alsa-lib
+	media-libs/libsndfile
+	media-libs/lilv
+	media-libs/lv2
+	media-libs/suil
+	virtual/jack
+	x11-libs/libxcb:=
+	aubio? ( media-libs/aubio:= )
+	dssi? ( media-libs/dssi )
+	ladspa? ( media-libs/ladspa-sdk )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad )
+	osc? ( media-libs/liblo )
+	rubberband? ( media-libs/rubberband )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	zlib? ( sys-libs/zlib )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCONFIG_DSSI=$(usex dssi 1 0)
+		-DCONFIG_GRADIENT=1
+		-DCONFIG_JACK_LATENCY=1
+		-DCONFIG_JACK_METADATA=1
+		-DCONFIG_JACK_SESSION=1
+		-DCONFIG_LADSPA=$(usex ladspa 1 0)
+		-DCONFIG_LIBAUBIO=$(usex aubio 1 0)
+		-DCONFIG_LIBLILV=1
+		-DCONFIG_LIBLO=$(usex osc 1 0)
+		-DCONFIG_LIBMAD=$(usex mad 1 0)
+		-DCONFIG_LIBRUBBERBAND=$(usex rubberband 1 0)
+		-DCONFIG_LIBSAMPLERATE=$(usex libsamplerate 1 0)
+		-DCONFIG_LIBVORBIS=$(usex vorbis 1 0)
+		-DCONFIG_LIBZ=$(usex zlib 1 0)
+		-DCONFIG_LV2=1
+		-DCONFIG_LV2_UI_GTK2=0
+		-DCONFIG_NSM=0
+		-DCONFIG_SSE=$(usex cpu_flags_x86_sse 1 0)
+		-DCONFIG_STACKTRACE=$(usex debug 1 0)
+		-DCONFIG_VESTIGE=1
+		-DCONFIG_VST=1
+		-DCONFIG_VST3=0
+		-DCONFIG_XUNIQUE=0
+	)
+	# Following options are left to the default
+	# CONFIG_LV2_ATOM
+	# CONFIG_LV2_BUF_SIZE
+	# CONFIG_LV2_CVPORT
+	# CONFIG_LV2_EVENT
+	# CONFIG_LV2_EXTERNAL_UI
+	# CONFIG_LV2_MIDNAM
+	# CONFIG_LV2_OPTIONS
+	# CONFIG_LV2_PARAMETERS
+	# CONFIG_LV2_PATCH
+	# CONFIG_LV2_PORT_EVENT
+	# CONFIG_LV2_PRESETS
+	# CONFIG_LV2_PROGRAMS
+	# CONFIG_LV2_STATE
+	# CONFIG_LV2_STATE_FILES
+	# CONFIG_LV2_STATE_MAKE_PATH
+	# CONFIG_LV2_TIME
+	# CONFIG_LV2_TIME_POSITION
+	# CONFIG_LV2_UI
+	# CONFIG_LV2_UI_IDLE
+	# CONFIG_LV2_UI_REQ_VALUE
+	# CONFIG_LV2_UI_SHOW
+	# CONFIG_LV2_UI_TOUCH
+	# CONFIG_LV2_WORKER
+	# CONFIG_LV2_UI_X11
+	cmake_src_configure
+}