dev-python/jupyter_server: Bump to 1.19.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/jupyter_server/Manifest

@@ -1,2 +1,3 @@
 DIST jupyter_server-1.18.1.tar.gz 451117 BLAKE2B ac9088f8f5c5afa6455f41b4006c0d49286006574101b42dd8e28501c97dcf10d7ee534d54b8cf26a8f34c7d2ba446485ce273ce04e22c39a22e5346d55ea4f5 SHA512 7acf101f337af903318de263dcf78cf3b45b799bb6095bc79568fde7f3f56ca508d39a1d40ffe2a4ab0bdc0173f0ee2f4a7426f41e0855c1b7f9dfd86f7e6d73
 DIST jupyter_server-1.19.0.tar.gz 453227 BLAKE2B c411ea965bd1948cfff488be278e9d6d4374482f0017e8e6f0b557628f1b571735008db3217035344ee1d38bed45e9c74c16fb365899408e0565d31740ee1a78 SHA512 ba1316418662bf465f5252de97efa58ecea237b51dfd83b17643176f95382d47759b88a2a79945e6bbf688dcdb3f99d091a035ab0a8a04706c6e6ba0c8a7fcc8
+DIST jupyter_server-1.19.1.tar.gz 453411 BLAKE2B 800231e7e7ddfcf2a2c2f2725971983d754c76940623ce000e6b86ad503bc6ca68a27e55ca3766193e58184a7148471464dfa9c27076e53ac84b176b8ff65897 SHA512 f4228c73950e49fe26add11c61f3de425b963726908a2df7dae21bb38b986c2ebb6abfc3319ef9e3acbc2fef9579a1a70ac594920985977adf580a082d272368

dev-python/jupyter_server/jupyter_server-1.19.1.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=jupyter
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Core services, APIs, and REST endpoints to Jupyter web applications"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/anyio-3.1.0[${PYTHON_USEDEP}]
+	<dev-python/anyio-4[${PYTHON_USEDEP}]
+	dev-python/argon2-cffi[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-6.1.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_core-4.7.0[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-6.4.4[${PYTHON_USEDEP}]
+	>=dev-python/nbformat-5.2.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/prometheus_client[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	>=dev-python/terminado-0.8.3[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.1[${PYTHON_USEDEP}]
+	dev-python/websocket-client[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	dev-python/pydata-sphinx-theme \
+	dev-python/myst_parser \
+	dev-python/ipython \
+	dev-python/sphinxemoji \
+	dev-python/sphinxcontrib-github-alt \
+	dev-python/sphinxcontrib-openapi
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# This fails if your terminal is zsh (and maybe other non-bash as well?)
+	tests/test_terminal.py::test_culling
+	tests/test_terminal.py::test_terminal_create_with_cwd
+	tests/test_terminal.py::test_terminal_create_with_relative_cwd
+)
+
+src_prepare() {
+	# disable npm use
+	sed -i -e '/\[tool\.jupyter-packaging\.builder\]/,+1d' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest \
+		-p pytest_tornasync.plugin \
+		-p jupyter_server.pytest_plugin \
+		-p pytest_console_scripts \
+		-p pytest_timeout
+}