dev-python/ipykernel: Bump to 6.29.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/ipykernel/Manifest

@@ -1 +1,2 @@
 DIST ipykernel-6.29.3.tar.gz 162794 BLAKE2B 3f0dcd1805d736f3657949cad45d8cacc57b6bdd4d950507eedb12aaae9e5f769174e8be45cd648d13b842b144bab237afa8da187b94f91a699602e795fb2418 SHA512 8726b37341a810318ec9c1585649288b40c3ac6875c82f5752da245ccd74125f5cb1557ca27a8187a8f668943a527345e9311d015b9e4e3095a4e07195a7d5b8
+DIST ipykernel-6.29.4.tar.gz 162958 BLAKE2B 887d33b433f5fba70273e4020a79bb511bd076fe536c04ebc5f7e838637ff120889789783f9a3a41b4669b0b51d44401215ed3feac413382b953edf9d1b6cb48 SHA512 488d43c1c9f416281b23ba0f31311c7327ef97034d6cf1776392c0f7b193f52f1434e81ae0c45759a0b15354ef9d178c3fc835c6be4408880209e41b91e5602b

dev-python/ipykernel/ipykernel-6.29.4.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="
+	https://github.com/ipython/ipykernel/
+	https://pypi.org/project/ipykernel/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+RDEPEND="
+	>=dev-python/comm-0.1.1[${PYTHON_USEDEP}]
+	>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-8[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-core-4.12[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
+	dev-python/nest-asyncio[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-24[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.4.0[${PYTHON_USEDEP}]
+"
+# RDEPEND seems specifically needed in BDEPEND, at least jupyter
+# bug #816486
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		<dev-python/pytest-8[${PYTHON_USEDEP}]
+		>=dev-python/pytest-asyncio-0.23.5[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/ipyparallel[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# debugpy is actually optional
+	sed -i -e '/debugpy/d' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	# Use python3 in kernel.json configuration, bug #784764
+	sed -i -e '/python3.[0-9]\+/s//python3/' \
+		"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
+}
+
+src_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		tests/test_debugger.py::test_attach_debug
+		tests/test_debugger.py::test_breakpoint_in_cell_with_leading_empty_lines
+		tests/test_debugger.py::test_rich_inspect_at_breakpoint
+		tests/test_debugger.py::test_rich_inspect_not_at_breakpoint
+		tests/test_debugger.py::test_set_breakpoints
+		tests/test_debugger.py::test_stop_on_breakpoint
+		tests/test_debugger.py::test_copy_to_globals
+		# hangs?
+		tests/test_eventloop.py::test_tk_loop
+		# doesn't like pyside2?
+		tests/test_eventloop.py::test_qt_enable_gui
+	)
+
+	virtx distutils-r1_src_test
+}