net-im/dino: add 0.4.5

Signed-off-by: 1vybridge <openrc@posteo.de>
Closes: https://github.com/gentoo/gentoo/pull/40941
Signed-off-by: Sam James <sam@gentoo.org>

net-im/dino/Manifest

@@ -1 +1,2 @@
 DIST dino-0.4.4.tar.gz 884259 BLAKE2B 5290543aeaf89f2adf5acf648b6ff4fb7daafc7d4e0b9e948f34a4af81ea49073664aa37d2541753e2f75dbfe492ac82ebdda5fe9ab5749e7b251d6788a36f3a SHA512 d2d5553c60d20e163930c0d8468727109871651f7305bf86940b7efd70a42d11ca85572f4dbea01e67ec8ce48fb0a244acb29b491d5d43bf188653ddc6ecface
+DIST dino-0.4.5.tar.gz 886933 BLAKE2B 19afec6cedf770017ef459ab87dac38f24a4e9c7ca956145e6bd4bc99f35928ae2cc461f98de262beb6e06cd6cbbcd56197835adc8ead57c3f1f29b2c4446771 SHA512 877e218105b4c9b643145d557ebf0e19d9ad989146dcffde047aba46290389babf8814a8bd819788f91e34c11df0c8609c68f9de8fa418c0801c83642ad861c6

net-im/dino/dino-0.4.5.ebuild

@@ -0,0 +1,100 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake vala xdg readme.gentoo-r1
+
+DESCRIPTION="Modern Jabber/XMPP Client using GTK+/Vala"
+HOMEPAGE="https://dino.im"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+gpg +http +omemo +notification-sound +rtp test"
+RESTRICT="!test? ( test )"
+
+MY_REPO_URI="https://github.com/dino/dino"
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="${MY_REPO_URI}.git"
+	inherit git-r3
+else
+	KEYWORDS="~amd64 ~arm64"
+	SRC_URI="${MY_REPO_URI}/releases/download/v${PV}/${P}.tar.gz"
+fi
+
+RDEPEND="
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/icu:=
+	dev-libs/libgee:0.8=
+	gui-libs/gtk:4
+	>=gui-libs/libadwaita-1.2.0:1[vala]
+	media-libs/graphene
+	net-libs/glib-networking
+	net-libs/gnutls:=
+	>=net-libs/libnice-0.1.15
+	net-libs/libsignal-protocol-c
+	net-libs/libsrtp:2=
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango
+	gpg? ( app-crypt/gpgme:= )
+	http? ( net-libs/libsoup:2.4 )
+	notification-sound? ( media-libs/libcanberra:0[sound(+)] )
+	omemo? (
+		dev-libs/libgcrypt:=
+		media-gfx/qrencode:=
+	)
+	rtp? (
+		media-libs/gst-plugins-base:1.0
+		media-libs/gstreamer:1.0
+		media-libs/webrtc-audio-processing:1
+	)
+"
+DEPEND="${RDEPEND}
+	media-libs/gst-plugins-base
+	media-libs/gstreamer
+"
+BDEPEND="
+	sys-devel/gettext
+	$(vala_depend)
+"
+
+src_configure() {
+	vala_setup
+
+	local disabled_plugins=(
+		$(usex gpg "" "openpgp")
+		$(usex omemo "" "omemo")
+		$(usex http  "" "http-files")
+		$(usex rtp "" rtp)
+	)
+	local enabled_plugins=(
+		$(usex notification-sound "notification-sound" "")
+	)
+	local mycmakeargs=(
+		"-DENABLED_PLUGINS=$(local IFS=";"; echo "${enabled_plugins[*]}")"
+		"-DDISABLED_PLUGINS=$(local IFS=";"; echo "${disabled_plugins[*]}")"
+		"-DVALA_EXECUTABLE=${VALAC}"
+		# libsoup-2 for bug #948374
+		# dino -> libnice[upnp] -> gupnp-igd:0 -> gupnp:0 -> libsoup:2.4
+		"-DSOUP_VERSION=2"
+		"-DBUILD_TESTS=$(usex test)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/xmpp-vala-test || die
+}
+
+src_install() {
+	cmake_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	readme.gentoo_print_elog
+}