app-office/joplin-desktop: bump to 2.14.17

Signed-off-by: Maciej Barć <xgqt@gentoo.org>
2026-09-24 04:59:14 -07:00 · 2024-03-04 01:11:33 +01:00
parent fbf5602b9c
commit 05c4aeeea3
2 changed files with 104 additions and 0 deletions
--- a/app-office/joplin-desktop/Manifest
+++ b/app-office/joplin-desktop/Manifest
@@ -1,2 +1,3 @@
 DIST Joplin-2.13.15.AppImage 210896525 BLAKE2B 3474dc12fa083ff4d56e0c64343def5171dd7b739c845c2a3ade562de7ae63d3d79a434611d00b0763f43e2a97281f989128c1fdf5ca5acb64f3e8bdd9cbc7f8 SHA512 d5fc3eee37f506aabb131b14e61ce459602d9c80da61b63ef07a849987cce5ff59af913000ac27baad8e3af637ca6cb28ad4ecaea523b24b4aac1a8b0df76493
 DIST Joplin-2.14.11.AppImage 247754522 BLAKE2B c39b87ca790b41d30c505b1001b75b442790c314cfd1340e2a6c1df7fa9d83505a9664d9fa57f30f7d2dd4dd23e2e04abad3bced978023203e2d9de773aac1a6 SHA512 1f2ed8d9ca6c83d86e09eb039b7d200c926e6ccd02e3db0f1e276640204bf5d6cc2df511b302fcf8b28edcff8f3534b0d52d051439f4275ce1b8f6a55fa5ad78
+DIST Joplin-2.14.17.AppImage 248140038 BLAKE2B 62fb124745ced06fce45cea01efb8eae39556cb58bec768935e826e070f6eaba0050daf8c42bb6308e74539735a9e955c188a0c00c5b6209a4550733776c6d38 SHA512 ff6db5b353092d87c35c9c39038f93b0b8f7da8f021fa3057dcdf15cbbffd72b81c5a180ec439802b58060b3862d46ed902ab66a315f574713b9d871b4788502
--- a/app-office/joplin-desktop/joplin-desktop-2.14.17.ebuild
+++ b/app-office/joplin-desktop/joplin-desktop-2.14.17.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# NOTICE: This is a Electron app (oh my) and the upstream only provides AppImages.
+
+EAPI=8
+
+APPIMAGE="Joplin-${PV}.AppImage"
+
+inherit desktop xdg
+
+DESCRIPTION="Secure note taking and to-do app with synchronization capabilities"
+HOMEPAGE="https://joplinapp.org/
+	https://github.com/laurent22/joplin/"
+SRC_URI="https://github.com/laurent22/joplin/releases/download/v${PV}/${APPIMAGE}"
+
+LICENSE="AGPL-3+"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+RESTRICT="bindist"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-crypt/libsecret[crypt]
+	app-misc/ca-certificates
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/libcanberra[gtk3]
+	media-libs/libglvnd
+	media-libs/mesa
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/zlib
+	sys-process/lsof
+	x11-libs/cairo
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libnotify
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libxkbcommon
+	x11-libs/libxkbfile
+	x11-libs/libXrandr
+	x11-libs/libXScrnSaver
+	x11-libs/pango
+	x11-misc/xdg-utils
+"
+
+QA_PREBUILT="*"
+
+src_unpack() {
+	mkdir -p "${S}" || die
+	cp "${DISTDIR}/${APPIMAGE}" "${S}" || die
+
+	cd "${S}" || die         # "appimage-extract" unpacks to current directory.
+	chmod +x "${S}/${APPIMAGE}" || die
+	"${S}/${APPIMAGE}" --appimage-extract || die
+}
+
+src_prepare() {
+	# Fix permissions.
+	find "${S}" -type d -exec chmod a+rx {} + || die
+	find "${S}" -type f -exec chmod a+r {} + || die
+
+	default
+}
+
+src_install() {
+	cd "${S}/squashfs-root" || die
+
+	insinto /usr/share
+	doins -r ./usr/share/icons
+
+	local apphome="/opt/${PN}"
+	local toremove=(
+		.DirIcon
+		@joplinapp-desktop.desktop
+		@joplinapp-desktop.png
+		AppRun
+		LICENSE.electron.txt
+		LICENSES.chromium.html
+		resources/app.asar.unpacked/node_modules/7zip-bin-linux/arm
+		resources/app.asar.unpacked/node_modules/7zip-bin-linux/arm64
+		resources/app.asar.unpacked/node_modules/node-notifier
+		usr
+	)
+	rm -f -r "${toremove[@]}" || die
+
+	mkdir -p "${ED}/${apphome}" || die
+	cp -r . "${ED}/${apphome}" || die
+
+	dosym -r "${apphome}/@joplinapp-desktop" "/usr/bin/${PN}"
+	make_desktop_entry "${PN}" Joplin @joplinapp-desktop "Office;" \
+		"StartupWMClass=Joplin\nMimeType=x-scheme-handler/joplin;"
+}