xfce-base/libxfce4ui: Bump to 4.15.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/libxfce4ui/Manifest

@@ -1,2 +1,3 @@
 DIST libxfce4ui-4.14.1.tar.bz2 756175 BLAKE2B d487cc0a04b6053ead6670eeb83cafe1c4098818d5ad6a94a81176720d78cfd65160156961cbb526baa1640ae66a5c6958f707b7078c412d81fcd24cc8cf4013 SHA512 f42f41da3a683a0c56c3b1e7ba420c4f50909d2613e681d053b09b50bc0eb7f750f44c892e94b0ee8b9207983a87c0cadbda1ad93d0df74ae351dc8812025407
 DIST libxfce4ui-4.15.3.tar.bz2 756530 BLAKE2B ca2a9d5aae80d22a97b2fe932248756c9f34f71a13342670cdc0ad1c5393eb62d4f5bed8b21a45a60c762a83ebf1458deb7ef629c4dd3c894468ecf16a821dcf SHA512 a0e5a60c54df811fa2815238f9fe506700f6df8a6baa8172a6f8c68f005b54ba94ee31aba87d635fb506700da9c77e25f8c57268018fc8cfa5577f29aab58a6b
+DIST libxfce4ui-4.15.4.tar.bz2 825895 BLAKE2B 46687dea72d17a3693c31f69bd4d1961397bf00d9395935778c8c5b90e6e56585fa2e64fe4be817ad44994841218d7cce98ade033914c56ea82a04ae7e1b70e7 SHA512 af2545f6d72df1a13d926a52b5124c52f34fbee0b2db6664292f74bcc3d93cb42263eab57beb9f882be42b6530649b2c7e42d496817f1b34b7d2b67b29e6deb1

xfce-base/libxfce4ui/libxfce4ui-4.15.4.ebuild

@@ -0,0 +1,67 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg-utils vala
+
+DESCRIPTION="Unified widget and session management libs for Xfce"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="LGPL-2+ GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug glade introspection libgtop startup-notification vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND=">=dev-libs/glib-2.42:2
+	>=x11-libs/gtk+-3.22:3[introspection?]
+	x11-libs/libX11
+	x11-libs/libICE
+	x11-libs/libSM
+	>=xfce-base/libxfce4util-4.12:=[introspection?]
+	>=xfce-base/xfconf-4.12:=
+	glade? ( dev-util/glade:3.10 )
+	introspection? ( dev-libs/gobject-introspection:= )
+	libgtop? ( gnome-base/libgtop )
+	startup-notification? ( x11-libs/startup-notification )"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-lang/perl
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )"
+
+src_prepare() {
+	# stupid vala.eclass...
+	default
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable libgtop glibtop)
+		$(use_enable startup-notification)
+		$(use_enable vala)
+		$(use_enable glade gladeui2)
+		--with-vendor-info=Gentoo
+	)
+
+	use vala && vala_src_prepare
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}