www-client/opera-developer: Version 52.0.2850.0.

Package-Manager: Portage-2.3.20, Repoman-2.3.6

www-client/opera-developer/Manifest

@@ -1,2 +1,3 @@
 DIST opera-developer_52.0.2838.0_amd64.deb 53030918 BLAKE2B 31e26e1babed3cf06168f9485a4d24e981e0e6a6805fc227655e9d63e043e61a8c65340dbc517936aa2f9161e938941ba9e27e0e9b2c9c12880cd58a2708dcc8 SHA512 ef854dc59fe38ab40299f5d2e071340784c0c51e3044b6c640e3e62219ff909889ce021bbdf1a9bad95d81e04d7684163130784ba1366f641bb691dfaef37a33
 DIST opera-developer_52.0.2845.0_amd64.deb 53013254 BLAKE2B 98c719dfd99f0b956d68eaa31b213bdf3b1e0c62b6e2535aba08ff9211a75a34dc6349868af5a649f4215aab900a7f898079e7819fe819933bd5c62c0ba74074 SHA512 c104193de7386717f84d9284cb792992db118c5652118e201c27b2acaa3a99d12e51a5326c61de2a875ed87a38dfc3e3eb888fd2f9d0bb58b61f5719f92aa0cc
+DIST opera-developer_52.0.2850.0_amd64.deb 53492848 BLAKE2B 656ed619806b33d757b3fd4f2bb398c44b5b2f675ef3e0c319f647facbe29290681f95c83f26437dd77b8afee049da1a205d54c365ccea1111e2ee22944edc87 SHA512 fd29a6b0501a52547eac1fc078c20396a5d1e495d5e5a0f3a48ba5199ee9f9a3b2a873aa5b0337d6136202e1671ceffb60b707280461f5a8a89a7dc73ed27d28

www-client/opera-developer/opera-developer-52.0.2850.0.ebuild

@@ -0,0 +1,114 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB es es-419 fi fil fr fr-CA hi hr hu id it
+	ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+inherit chromium-2 gnome2-utils multilib unpacker xdg-utils
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="http://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="
+	http://download1.operacdn.com/pub/
+	http://download2.operacdn.com/pub/
+	http://download3.operacdn.com/pub/
+	http://download4.operacdn.com/pub/
+"
+SRC_URI="amd64? ("
+for uri in ${SRC_URI_BASE}; do
+SRC_URI+="
+	"${uri}${PN}/${PV}/linux/${PN}_${PV}_amd64.deb"
+"
+done
+SRC_URI+=")"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gconf:2
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libnotify
+	x11-libs/pango[X]
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="usr/$(get_libdir)/${PN}"
+
+src_unpack() {
+	unpack_deb ${A}
+}
+
+src_prepare() {
+	case ${ARCH} in
+		amd64)
+			mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+			rm -r usr/lib || die
+			;;
+		x86)
+			mv usr/lib/i386-linux-gnu/${PN} usr/$(get_libdir)/ || die
+			;;
+	esac
+
+	rm usr/bin/${PN} || die
+
+	rm usr/share/doc/${PN}/copyright || die
+	mv usr/share/doc/${PN} usr/share/doc/${PF} || die
+
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+	mv * "${D}" || die
+	dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+	fperms 4711 /usr/$(get_libdir)/${PN}/opera_sandbox
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}