sci-mathematics/flint: drop 3.1.3_p1-r1

Signed-off-by: Michael Orlitzky <mjo@gentoo.org>

sci-mathematics/flint/Manifest

@@ -1,2 +1 @@
-DIST flint-3.1.3_p1.tar.gz 7588734 BLAKE2B 87acf8778e21e37c01e12b198ff81e62ab113df3e0e9c6155ff7dd505828f79d5c49d85093e261ea96397e906350caa03477e3ecbdd1fc09d6ae5c984397a2be SHA512 1b16ff2fb9cb2ac4b75513278b8c14683e8d83db39985631df14d6ea74bee4d6ea818a200321d5f0de6f1af89898f7a99dc7088f712f4c6db1a2546199aefba7
 DIST flint-3.1.3_p1.tar.xz 5657304 BLAKE2B 7a76cbd7e3ea6ecfb4728545c427eba48ab476b257316792305522770e03b335d558cc104bac50b1faf2e8e25663f6ade20eef99e85999f7209091bf3c6e674a SHA512 430e83be2d94c059066b7201319dbbbe414ccd10a4f359a865e54f3912b8b8e8f10dfd36ee81c96335553ee2736cf2ef9e1ffdf488c9706360b9e0e8a50a4eea

sci-mathematics/flint/flint-3.1.3_p1-r1.ebuild

@@ -1,90 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{10..12} )
-inherit cmake flag-o-matic python-any-r1
-
-DESCRIPTION="Fast Library for Number Theory"
-HOMEPAGE="https://www.flintlib.org/"
-
-MY_PV="${PV/_/-}"
-SRC_URI="https://github.com/flintlib/flint/archive/refs/tags/v${MY_PV}.tar.gz
-	-> ${P}.tar.gz"
-S="${WORKDIR}/${PN}-${MY_PV}"
-LICENSE="LGPL-2.1+"
-
-# Based off the soname, e.g. /usr/lib64/libflint.so -> libflint.so.15
-SLOT="0/19"
-
-KEYWORDS="amd64 ~arm arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
-IUSE="doc ntl test"
-
-RESTRICT="!test? ( test )"
-
-BDEPEND="${PYTHON_DEPS}
-	doc? (
-		app-text/texlive-core
-		dev-python/sphinx
-		dev-tex/latexmk
-		dev-texlive/texlive-latex
-		dev-texlive/texlive-latexextra
-	)
-"
-DEPEND="dev-libs/gmp:=
-	dev-libs/mpfr:=
-	ntl? ( dev-libs/ntl:= )
-	virtual/cblas"
-# flint 3 includes arb and arb cannot use flint 3.
-RDEPEND="${DEPEND}
-	!sci-mathematics/arb"
-
-# The rst files are API docs, but they're very low-effort compared to
-# the PDF and HTML docs, so we ship them unconditionally and hide only
-# the painful parts behind USE=doc.
-DOCS="AUTHORS README.md doc/source/*.rst"
-
-PATCHES=(
-	"${FILESDIR}/flint-3.0.1-find-cblas.patch"
-	"${FILESDIR}/flint-3.1.3_p1-c99-I.patch"
-	"${FILESDIR}/flint-3.1.3_p1-fix-pc-location.patch"
-)
-
-src_configure() {
-	# Test failures:
-	# * https://bugs.gentoo.org/934463
-	# * https://github.com/flintlib/flint/issues/2029
-	filter-flags -floop-nest-optimize \
-				 -ftree-loop-linear \
-				 -floop-strip-mine \
-				 -floop-block \
-				 -fgraphite-identity
-
-	local mycmakeargs=(
-		-DWITH_NTL="$(usex ntl)"
-		-DBUILD_TESTING="$(usex test)"
-		-DBUILD_DOCS="$(usex doc)"
-	)
-
-	cmake_src_configure
-
-	if use doc; then
-		# Avoid the "html/_source" directory that will contain a copy of
-		# the rst sources we've already installed, and also avoid
-		# installing html/objects.inv.
-		HTML_DOCS="${BUILD_DIR}/html/*.html
-			${BUILD_DIR}/html/*.js
-			${BUILD_DIR}/html/_static"
-		DOCS+=" ${BUILD_DIR}/latex/Flint.pdf"
-	fi
-}
-
-src_compile() {
-	cmake_src_compile
-
-	if use doc; then
-		cmake_build html
-		cmake_build pdf
-	fi
-}