net-news/rssguard: Bump to 4.5.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2023-11-13 18:40:52 +01:00
parent ebe936d76e
commit 04cd4e6f6f
2 changed files with 67 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST rssguard-4.5.3.gh.tar.gz 23189973 BLAKE2B fd681372680fe5a14bbcd1823c6d830f995377ad0395ede8e7f36e1c1ddc47ffbee66468a65278718aada217fb843f335647579291e882f46c79055d413d7326 SHA512 dca556b659d069a772ea78d9399707cbe03e3fc0cb093ca7fc400661d1275236943ac00870ab1dcd0930850f0aa51c8f9c381e0e65f00cea4ff40bc6b398ff67
DIST rssguard-4.5.4.gh.tar.gz 23200651 BLAKE2B 5818db43b1da799c02449e29d75c1f7faffa2c48bbf28c76d86c4bfa63ef9cbce8a976f6a4b2fdb29dcf5ce61ce8b9049969e0b3df2d7e913cec75c881a1b16b SHA512 f5670138cc00561f3863ec5cf4e165f5146809eb59ce941adf0998483f8ff41a5ed5859abb9d7970fcfeb161f31ddd89fccb53773526b002e3a22ebe73304875
+66
View File
@@ -0,0 +1,66 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake optfeature xdg
DESCRIPTION="Simple (yet powerful) news feed reader"
HOMEPAGE="https://github.com/martinrotter/rssguard/"
SRC_URI="
https://github.com/martinrotter/rssguard/archive/${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="|| ( LGPL-3 GPL-2+ ) AGPL-3+ BSD GPL-3+ MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="mysql qt6 +sqlite webengine"
REQUIRED_USE="|| ( mysql sqlite )"
BDEPEND="
!qt6? ( dev-qt/linguist-tools:5 )
qt6? ( dev-qt/qttools:6[linguist] )
"
DEPEND="
sys-libs/zlib:=
!qt6? (
dev-qt/qtconcurrent:5
dev-qt/qtcore:5
dev-qt/qtdbus:5
dev-qt/qtdeclarative:5
dev-qt/qtgui:5
dev-qt/qtmultimedia:5[gstreamer]
dev-qt/qtnetwork:5[ssl]
dev-qt/qtsql:5[mysql?,sqlite?]
dev-qt/qtwidgets:5
dev-qt/qtxml:5
webengine? ( dev-qt/qtwebengine:5[widgets(+)] )
)
qt6? (
dev-qt/qtbase:6[concurrent,dbus,gui,mysql?,network,sql,sqlite?,ssl,widgets]
dev-qt/qtdeclarative:6
dev-qt/qtmultimedia:6[gstreamer]
dev-qt/qt5compat:6
media-libs/libglvnd
webengine? ( dev-qt/qtwebengine:6[widgets(+)] )
)
"
RDEPEND="${DEPEND}"
src_configure() {
local mycmakeargs=(
-DBUILD_WITH_QT6=$(usex qt6)
-DUSE_WEBENGINE=$(usex webengine)
-DNO_UPDATE_CHECK=ON
-DENABLE_COMPRESSED_SITEMAP=ON
)
cmake_src_configure
}
pkg_postinst() {
xdg_pkg_postinst
optfeature "ad blocking functionality" "net-libs/nodejs[npm]"
}