gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-23 16:49:10 -07:00
Code Issues Projects Releases Wiki Activity

gui-libs/libpanel: add 1.10.4

Browse Source 
Signed-off-by: Lukas Schmelting <lschmelting@posteo.com>
Part-of: https://github.com/gentoo/gentoo/pull/46017
Closes: https://github.com/gentoo/gentoo/pull/46017
Signed-off-by: Pacho Ramos <pacho@gentoo.org>
This commit is contained in:
Lukas Schmelting
2026-03-27 19:22:01 +01:00
committed by Pacho Ramos
parent 62bdf7ac9e
commit 04c844f2c8
2 changed files with 56 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
gui-libs/libpanel/Manifest
View File

@@ -1,2 +1,3 @@
DIST libpanel-1.10.2.tar.xz 166924 BLAKE2B 73b527f10643bfc6d7a8bc7d6f98c9ca3fde29d013300d21493903a4623515cea277dc23896498b13ca11465bcc375382429c405d72b324fc8cfcfdb0fdf2eb4 SHA512 b45284e0bccf0cae84027886b8c36bb9058e2db315bb3fa9490056e865227e1c3d772f671ba02f5b27588dd13c06a6ef88bfe9ff1e2de4c32c20ca0c2b28078c
DIST libpanel-1.10.3.tar.xz 167568 BLAKE2B 89e8732705ba635ddde6a5b79e620d3b8b66c23be3bdb645911039e112186d71fe3b4b5ee407abca908c0c207119cfe717266e7d1a2406d106ed077da158c74f SHA512 bc370c0441309a909e84fc52aeaac013ed08341eb0e8f8a3d81420b8e31a0a1734768bd76e8e93f934437abd90f44c222f019a566aa7c8d9f1b96e8263da3c1b
DIST libpanel-1.10.4.tar.xz 169424 BLAKE2B 729cc82e382155a46b3862a2d570cfb37493f4bb9b2d0a554cb1f9f7187a2149d28a4db2e40a291a4c3b13eca73717967cde96a7a69a61d6dd27490029b86a02 SHA512 27c428f306deb6e662b912b5fa1e195de115b511685ef51e068fe18174b92959cb5353f2500298d271d21f99fa96e879c39e3c839a6b5934e12d380e9c73cd73

55
gui-libs/libpanel/libpanel-1.10.4.ebuild Normal file
View File

@@ -0,0 +1,55 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit gnome.org meson vala xdg
DESCRIPTION="A dock/panel library for GTK 4"
HOMEPAGE="https://gitlab.gnome.org/GNOME/libpanel"
LICENSE="LGPL-3+"
SLOT="1"
KEYWORDS="~amd64 ~arm64 ~loong ~x86"
IUSE="examples gtk-doc +introspection +vala"
REQUIRED_USE="
gtk-doc? ( introspection )
vala? ( introspection )
"
RDEPEND="
>=dev-libs/glib-2.80:2
>=gui-libs/gtk-4.15:4[introspection?]
>=gui-libs/libadwaita-1.6:1
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
"
DEPEND="${RDEPEND}"
BDEPEND="
gtk-doc? ( >=dev-util/gi-docgen-2021.1 )
vala? ( $(vala_depend) )
"
src_prepare() {
default
use vala && vala_setup
xdg_environment_reset
}
src_configure() {
local emesonargs=(
$(meson_use examples install-examples)
$(meson_feature introspection)
$(meson_feature gtk-doc docs)
$(meson_use vala vapi)
)
meson_src_configure
}
src_install() {
meson_src_install
if use gtk-doc; then
mkdir "${ED}"/usr/share/gtk-doc || die
mv "${ED}"/usr/share/doc/panel-1.0 "${ED}"/usr/share/gtk-doc/ || die
fi
}