dev-python/tornado: Bump to 6.5.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/tornado/Manifest

@@ -1 +1,2 @@
 DIST tornado-6.5.1.tar.gz 509934 BLAKE2B d60479a2baabc10ff5e858efc74be6f42d051032477009c6e9922969bd4ae40c5137a946182ad7c859d4ab3fe8ec51c313067c58638b38d0c0a9690746e40f63 SHA512 af95a8cb1c387824ed3c8f4d01ad982706d5bd142002ac4c839de76955b33411a7560973f898ef7953468b716ad585f0ebd7989d3948201ace1f0d95ebf52811
+DIST tornado-6.5.2.tar.gz 510821 BLAKE2B 31e4753a3f8d5474d84b431c41617668e749fed14aeb5a87ce4dd9cf329d0a6972b1c6d2275b2912ac0222fce91fa2421ff1f61b626e42b79ef5613bfbd36f52 SHA512 a0a9a123849571a08a552252f1732418cc46ba51e6f80d2e632c266f971eef26787eb2345cb8ae2f1337dbe06a3af12f99b1ae0d0fa813ede66c1f36700fae4d

dev-python/tornado/tornado-6.5.2.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python web framework and asynchronous networking library"
+HOMEPAGE="
+	https://www.tornadoweb.org/
+	https://github.com/tornadoweb/tornado/
+	https://pypi.org/project/tornado/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		$(python_gen_cond_dep '
+			>=dev-python/pycurl-7.19.3.1[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-6.3.2-ignore-deprecationwarning.patch"
+)
+
+src_prepare() {
+	# network-sandbox? ipv6?
+	sed -i -e 's:test_localhost:_&:' \
+		tornado/test/netutil_test.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x ASYNC_TEST_TIMEOUT=60
+	# Avoid time-sensitive tests
+	# https://github.com/tornadoweb/tornado/blob/10974e6ebee80a26a2a65bb9bd715cf858fafde5/tornado/test/util.py#L19
+	local -x TRAVIS=1
+	local -x NO_NETWORK=1
+
+	cd "${T}" || die
+	"${EPYTHON}" -m tornado.test.runtests --verbose ||
+		die "tests failed under ${EPYTHON}"
+}