gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

sys-auth/pambase: Version bump (v20200617)

Browse Source 
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Mikle Kolyada <zlogene@gentoo.org>
This commit is contained in:
Mikle Kolyada
2020-06-17 21:35:01 +03:00
parent 5407fd9870
commit 04498f86fd
2 changed files with 82 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
sys-auth/pambase/Manifest
View File

@@ -2,3 +2,4 @@ DIST pambase-20190402.tar.gz 3679 BLAKE2B 992d7bf6b6f74ef22a8808b57dd6faffb6c351
DIST pambase-20191128.tar.gz 3472 BLAKE2B 1028239c14eed3d06239f98667ffe136dc3c9cdb9c74d8f49e0c819d9ea308285cdd234538418357030dd39693040592b00f193cac4e37e15b9f277386096860 SHA512 09100457cacbe309eac8545818de3e4bff4f0c4a29b4c1758217dd80206c664f497570ef67207866aaf70be60ec963677b385adaf2c4a0cd931a50404098051b
DIST pambase-20200304.tar.gz 3466 BLAKE2B e4d406460d435403ed7a46d517f9006cacc54a94f5019a573c81b331731c88679ed6d388354b5946894bdfada556b4c73735c3f4de88fc7678cd831c68ab46c3 SHA512 c2a7f3fd143637fbdf5c0a3c58ba5a3c23c5e8adb1f057d02b4b9d64660435fc529031a0f710a9e5fc7091710f78dcb2f3e1ff48f033fb491ddd0399ef05b189
DIST pambase-20200616.tar.gz 3427 BLAKE2B 462586e70d928f7333d2b92d007039ae18a6553a988b4d007167f65321293d7885306305cbfe83e5d5ced856d900faa5bb7b4d28458869c4eca90cfc2f71d824 SHA512 739bf8eafcdc3a295ef37c90a0466c6bf70901d22371d7501e640b512713eae804b01e4885c43a3bd5bb6eea182b9f8b1d85fb9a6b79cf646ebc349b47c6a07b
DIST pambase-20200617.tar.gz 3425 BLAKE2B 6ca1a7079557b98b903ccefc2c76dad35fb2947e692c7025d74ec671c377bbedc8b5f17baab326848201c89ae78252d65b351ab6900aafdc2d475b7169feab1f SHA512 854858a8ba33a76b72334c8cf61e5672df0fef4bc7fce142ac065f4246a132460c7f890620e777158d61d1fd537d785d0856d88f02905a4c6c5ab806f4e8bf13

81
sys-auth/pambase/pambase-20200617.ebuild Normal file
View File

@@ -0,0 +1,81 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DESCRIPTION="PAM base configuration files"
HOMEPAGE="https://github.com/gentoo/pambase"
SRC_URI="https://github.com/gentoo/pambase/archive/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="caps consolekit debug elogind minimal mktemp +nullok pam_krb5 pam_ssh +passwdqc securetty selinux +sha512 systemd"
RESTRICT="binchecks"
REQUIRED_USE="?? ( consolekit elogind systemd )"
MIN_PAM_REQ=1.4.0
RDEPEND="
>=sys-libs/pam-${MIN_PAM_REQ}
consolekit? ( sys-auth/consolekit[pam] )
elogind? ( sys-auth/elogind[pam] )
mktemp? ( sys-auth/pam_mktemp )
pam_krb5? (
>=sys-libs/pam-${MIN_PAM_REQ}
sys-auth/pam_krb5
)
caps? ( sys-libs/libcap[pam] )
pam_ssh? ( sys-auth/pam_ssh )
passwdqc? ( sys-auth/passwdqc )
selinux? ( sys-libs/pam[selinux] )
sha512? ( >=sys-libs/pam-${MIN_PAM_REQ} )
systemd? ( sys-apps/systemd[pam] )
"
DEPEND="
app-arch/xz-utils
app-portage/portage-utils
"
S="${WORKDIR}/${PN}-${P}"
src_compile() {
local linux_pam_version
if has_version sys-libs/pam; then
local ver_str=$(qatom $(best_version sys-libs/pam) | cut -d ' ' -f 3)
linux_pam_version=$(printf "0x%02x%02x%02x" ${ver_str//\./ })
fi
use_var() {
local varname=$(echo "$1" | tr '[:lower:]' '[:upper:]')
local usename=${2-$(echo "$1" | tr '[:upper:]' '[:lower:]')}
local varvalue=$(usex ${usename})
echo "${varname}=${varvalue}"
}
emake \
GIT=true \
$(use_var debug) \
$(use_var LIBCAP caps) \
$(use_var passwdqc) \
$(use_var consolekit) \
$(use_var elogind) \
$(use_var systemd) \
$(use_var selinux) \
$(use_var nullok) \
$(use_var mktemp) \
$(use_var pam_ssh) \
$(use_var securetty) \
$(use_var sha512) \
$(use_var KRB5 pam_krb5) \
$(use_var minimal) \
LINUX_PAM_VERSION=${linux_pam_version}
}
src_test() { :; }
src_install() {
emake GIT=true DESTDIR="${ED}" install
}