kde-frameworks/extra-cmake-modules: 6.19.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-frameworks/extra-cmake-modules/Manifest

@@ -1,2 +1,3 @@
 DIST extra-cmake-modules-6.16.0.tar.xz 329140 BLAKE2B 97e02de8c2fafc1d36704124fa8b4e7cbaa6ce50b63395d03a9a080d88046238d05a322c47f9956efb1bd4174d8aa06cf9c554a1b1bbbaf5d9562beb161fa7f4 SHA512 982a40bf36ea5692172b57aa563be132aa236199cde0993bf169241624a9ef7f9b9d5d79e06890da103f49610aeaa6a951562f7bf98f1535540d12670cec49f6
 DIST extra-cmake-modules-6.18.0.tar.xz 330388 BLAKE2B aaeef9fccfd5116fb90402004984b5073b7d62db80035a6d461374d0ceeb4099439eb6500f0d04faf1f62845fb9bba97544b944bff630c61ac368404e3a507fd SHA512 b657f22a27bb968fa67092c8037698613270feb18b4a87a53e97280d8db3df38558d0eff5c7f350d9b17b4270004139a9a71a5eb0586746bf447b3a44b57b9f0
+DIST extra-cmake-modules-6.19.0.tar.xz 331316 BLAKE2B f99d12a8b7db51ae8d21b612a7f69d800d98fb0dd040ff4e3fb5e6154dca61adb9c1b40e09441110cc61a21ab3cd1f19ace912b3f08c36c7b75d4161c569a853 SHA512 935e11e0ef3b649e479580d091560e2064321f00ecb7981db26ae372a19295b9e33283ffc3f87b7884673561e330f325a664c87f5b1d5d2ac2ba5aad09cbc325

kde-frameworks/extra-cmake-modules/extra-cmake-modules-6.19.0.ebuild

@@ -0,0 +1,82 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+QTMIN=6.7.2
+inherit cmake frameworks.kde.org python-any-r1
+
+DESCRIPTION="Extra modules and scripts for CMake"
+HOMEPAGE="https://invent.kde.org/frameworks/extra-cmake-modules"
+
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="app-arch/libarchive[bzip2]"
+DEPEND="
+	test? (
+		>=dev-qt/qtbase-${QTMIN}:6[dbus,gui]
+		>=dev-qt/qtdeclarative-${QTMIN}:6
+	)
+"
+BDEPEND="
+	doc? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]')
+		>=dev-qt/qttools-${QTMIN}:6[assistant]
+	)
+	test? (
+		>=dev-qt/qtbase-${QTMIN}:6
+		>=dev-qt/qttools-${QTMIN}:6[linguist]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-5.49.0-no-fatal-warnings.patch"
+	"${FILESDIR}/${PN}-5.93.0-skip-ecm_add_test-early.patch"
+	"${FILESDIR}/${PN}-5.245.0-disable-qmlplugindump.patch"
+	"${FILESDIR}/${PN}-6.5.0-disable-appstreamtest.patch"
+	"${FILESDIR}/${PN}-6.5.0-disable-git-commit-hooks.patch"
+	"${FILESDIR}/${PN}-6.18.0-ECMSetupQtPluginMacroNames.patch" # in 6.20
+	"${FILESDIR}/${PN}-6.18.0-fix-CMP0177-warning.patch" # in 6.20
+)
+
+python_check_deps() {
+	python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDOC_INSTALL_DIR=/usr/share/doc/"${PF}"
+		-DBUILD_QTHELP_DOCS=$(usex doc)
+		-DBUILD_HTML_DOCS=$(usex doc)
+		-DBUILD_MAN_DOCS=$(usex doc)
+		-DBUILD_TESTING=$(usex test)
+	)
+	if use test; then
+		mycmakeargs+=( -DQT_MAJOR_VERSION=6 ) # bug 938316
+	fi
+
+	cmake_src_configure
+}
+
+src_test() {
+	local CMAKE_SKIP_TESTS=(
+		# passes, but then breaks src_install
+		ECMToolchainAndroidTest
+		# broken, bug #627806
+		ECMPoQmToolsTest
+		# can not possibly succeed in releases, bug #764953
+		KDEFetchTranslations
+	)
+	# possible race condition with multiple jobs, bug #701854
+	cmake_src_test -j1
+}