media-libs/openexr: bump to 3.1.3

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Bernd Waibel <waebbl-gentoo@posteo.net>
Closes: https://github.com/gentoo/gentoo/pull/22812
Signed-off-by: Sam James <sam@gentoo.org>

media-libs/openexr/Manifest

@@ -2,3 +2,4 @@ DIST openexr-2.5.6.tar.gz 27540385 BLAKE2B eea64c6ae4500de31673f3127da6ac98272e8
 DIST openexr-2.5.7.tar.gz 27539574 BLAKE2B 58fd81be52e13d2815b6aa8cea6793359379f5ebf866fd45b31ce30cf5f72aa4699625e7cec51189d62fe76f53418c3e0938f9b827d54ad18342e7aa67c8a3d2 SHA512 e44edfa2dcfff2fe372ed2ba07b39a472e549025978de178eff26be641767d22d1a3b543fb7672d9b7b2e9f4c308667f785829ed6d9032a2b42f2ffa0163de40
 DIST openexr-3.1.1.tar.gz 25588029 BLAKE2B c2ce9622ad7b8a328ce556b6120a868cddb86e908917e001f543e70501b6d31ce549fc10d65806dd9d63e63872b273ad3a1d4f6813b5d23ea238c238f5815304 SHA512 430becbb214cedec5a57e9ff2363badd8a2d94e8a00edffbc75fbcf30d26d887a6eb3f4ff96e371cb26f9d44e63bf0fe2dc511493a0951171ddc64bba7aed735
 DIST openexr-3.1.2.tar.gz 20315253 BLAKE2B d11f26d3e2bb098c4c009271b40da1eca97b120e5683137a0b38f64e2862c226aebff7c17e79344da4a1be5a1967fb8ab0493ff919a7fb5bec16b34e494e49e2 SHA512 34fb28f149e49bb23b2dc230dd5277229f2c780de66aff0acc819601e6802a1dbf83110b5df455dffd63be6eaa286d4aedb4b0af559b8b034d98c3208ee9d969
+DIST openexr-3.1.3.tar.gz 20322346 BLAKE2B e65cb00d1d9ae7544f6d1adf9c6f05193986b8de7b657fa22d20466f2b6dfccf244b5aa3dbe7f2abb0c934aec68d2007dd9edb3eeee91b2bbd8aab331eea7e90 SHA512 12a8f3660104e68ccea0856caf334d1fafbf0ee79115aae23cdce5b835299294ab8a23bafed282acfacd159ce9bc7f6ffc620b1e0df0d40f9ca0eb15a288964d

media-libs/openexr/openexr-3.1.3.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+MY_PN=OpenEXR
+MY_PV=$(ver_cut 1)
+MY_P=${MY_PN}-${MY_PV}
+
+DESCRIPTION="ILM's OpenEXR high dynamic-range image file format libraries"
+HOMEPAGE="https://www.openexr.com/"
+SRC_URI="https://github.com/AcademySoftwareFoundation/openexr/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="3/30" # based on SONAME
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-solaris"
+IUSE="cpu_flags_x86_avx doc examples large-stack static-libs utils test threads"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/imath-3.1.0:=
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? ( dev-python/breathe )
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.1.1-0001-changes-needed-for-proper-slotting.patch
+	"${FILESDIR}"/${PN}-3.1.1-0002-add-version-to-binaries-for-slotting.patch
+	"${FILESDIR}"/${PN}-3.1.1-0003-disable-failing-test.patch
+)
+
+DOCS=( CHANGES.md GOVERNANCE.md PATENTS README.md SECURITY.md docs/SymbolVisibility.md )
+
+src_prepare() {
+	# Fix path for testsuite
+	sed -e "s:/var/tmp/:${T}:" \
+		-i "${S}"/src/test/${MY_PN}{,Fuzz,Util}Test/tmpDir.h || die "failed to set temp path for tests"
+
+	cmake_src_prepare
+
+	mv "${S}"/cmake/${MY_PN}.pc.in "${S}"/cmake/${MY_P}.pc.in || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=$(usex !static-libs)
+		-DBUILD_TESTING=$(usex test)
+		-DDOCS=$(usex doc)
+		-DOPENEXR_BUILD_TOOLS=$(usex utils)
+		-DOPENEXR_ENABLE_LARGE_STACK=$(usex large-stack)
+		-DOPENEXR_ENABLE_THREADING=$(usex threads)
+		-DOPENEXR_INSTALL_EXAMPLES=$(usex examples)
+		-DOPENEXR_INSTALL_PKG_CONFIG=ON
+		-DOPENEXR_INSTALL_TOOLS=$(usex utils)
+		-DOPENEXR_OUTPUT_SUBDIR="${MY_P}"
+		-DOPENEXR_USE_CLANG_TIDY=OFF		# don't look for clang-tidy
+	)
+
+	use test && mycmakeargs+=( -DOPENEXR_RUN_FUZZ_TESTS=ON )
+
+	cmake_src_configure
+}
+
+src_install() {
+	use examples && docompress -x /usr/share/doc/${PF}/examples
+	cmake_src_install
+
+	newenvd - 99${PN}3 <<-EOF
+		LDPATH=/usr/$(get_libdir)/${MY_P}
+	EOF
+}