dev-perl/Device-SerialPort: -r bump for EAPI7 & Fixes

- EAPI7
- Fix license as best as possible
- Ensure CFLAGS passed to make/compiler
- Indent wiki link slightly for clearer readability

Bug: https://bugs.gentoo.org/734728
Package-Manager: Portage-2.3.103, Repoman-2.3.22
Signed-off-by: Kent Fredric <kentnl@gentoo.org>

dev-perl/Device-SerialPort/Device-SerialPort-1.40.0-r3.ebuild

@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DIST_AUTHOR=COOK
+DIST_VERSION=1.04
+DIST_EXAMPLES=("eg/*")
+inherit perl-module
+
+DESCRIPTION="A Serial port Perl Module"
+# https://bugs.gentoo.org/734728
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~sparc ~x86"
+
+#From the module:
+# If you run 'make test', you must make sure that nothing is plugged
+# into '/dev/ttyS1'!
+# Doesn't sound wise to enable SRC_TEST="do" - mcummings
+
+src_configure() {
+	myconf=()
+	[[ -n "${DEVICE_SERIALPORT_PORT}" ]] && myconf+=( "TESTPORT=${DEVICE_SERIALPORT_PORT}" )
+	perl-module_src_configure
+}
+src_compile() {
+	mymake=(
+		"OPTIMIZE=${CFLAGS}"
+	)
+	perl-module_src_compile
+}
+src_test() {
+	local MODULES=(
+		"Device::SerialPort ${DIST_VERSION}"
+	)
+	local failed=()
+	for dep in "${MODULES[@]}"; do
+		ebegin "Compile testing ${dep}"
+			perl -Mblib="${S}" -M"${dep} ()" -e1
+		eend $? || failed+=( "$dep" )
+	done
+	if [[ ${failed[@]} ]]; then
+		echo
+		eerror "One or more modules failed compile:";
+		for dep in "${failed[@]}"; do
+			eerror "  ${dep}"
+		done
+		die "Failing due to module compilation errors";
+	fi
+	if [[ -n "${DEVICE_SERIALPORT_PORT}" ]]; then
+		DIST_TEST="do"; # Parallel testing a serial port sounds unsmart.
+		perl-module_src_test;
+	else
+		ewarn "Functional tests are disabled without manual intervention."
+		ewarn "For details, read:"
+		ewarn " https://wiki.gentoo.org/wiki/Project:Perl/maint-notes/${CATEGORY}/${PN}#Tests"
+	fi
+}