dev-python/subunit: Bump to 1.4.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2022-11-07 06:53:40 +01:00
parent ad99ab9b0f
commit 0342397b2c
2 changed files with 97 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST subunit-1.4.0_p20210729.tar.gz 112644 BLAKE2B 56e785c029f3f2896d0ed3d8005c37403e6aa32d05b653db0e3b679d2157820558e578b53133f4f79404a660f37a710aeeec03ff941fd7cd0819020a0d474515 SHA512 90b1ad071fb5246a7446a4c999142566b9d96c39838905e9020b80f2f0aba0b86dd5185bbd25ff7fc65f69ae68e1e53dfde5b2de05755aa97db9248c6faaa9d7
DIST subunit-1.4.1.gh.tar.gz 112188 BLAKE2B dd09882f13b52e8c1f34f91ee49726f75f473a042b0e025704eb95681e4ff3f313fc6b2f9fbcc78f4fb75c88e3b2a828ffee0f7dfaaa8ad2bff9bfb14bd5c0ea SHA512 c21ab0791ccc92e47df5d741deaae56fffe792777958193727f47c2739135fb77880d30b106e525239c0c35841834dd937e2b30fce27fbe73ca9116753147a65
+96
View File
@@ -0,0 +1,96 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..11} pypy3 )
inherit distutils-r1 multilib-minimal autotools
DESCRIPTION="A streaming protocol for test results"
HOMEPAGE="
https://launchpad.net/subunit/
https://pypi.org/project/python-subunit/
"
SRC_URI="
https://github.com/testing-cabal/subunit/archive/${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="Apache-2.0 BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
IUSE="static-libs test"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-python/testtools-0.9.34[${PYTHON_USEDEP}]
dev-python/extras[${PYTHON_USEDEP}]
dev-lang/perl:=
"
DEPEND="
${RDEPEND}
>=dev-libs/check-0.9.11[${MULTILIB_USEDEP}]
>=dev-util/cppunit-1.13.2[${MULTILIB_USEDEP}]
>=virtual/pkgconfig-0-r1
test? (
dev-python/fixtures[${PYTHON_USEDEP}]
dev-python/hypothesis[${PYTHON_USEDEP}]
dev-python/testscenarios[${PYTHON_USEDEP}]
)
"
PATCHES=(
"${FILESDIR}/subunit-1.4.0-werror.patch"
)
src_prepare() {
# Install perl modules in vendor_perl, bug 534654.
export PERL_INSTALLDIRS=vendor
mv all_tests.py python/ || die
distutils-r1_src_prepare
eautoreconf
multilib_copy_sources
}
multilib_src_configure() {
ECONF_SOURCE=${S} \
econf \
--enable-shared \
$(use_enable static-libs static)
}
multilib_src_compile() {
default
multilib_is_native_abi && distutils-r1_src_compile
}
python_test() {
cd python || die
"${EPYTHON}" -m testtools.run -v all_tests.test_suite ||
die "Testing failed with ${EPYTHON}"
}
multilib_src_test() {
multilib_is_native_abi && distutils-r1_src_test
}
multilib_src_install() {
local targets=(
install-include_subunitHEADERS
install-pcdataDATA
install-exec-local
install-libLTLIBRARIES
)
emake DESTDIR="${D}" "${targets[@]}"
multilib_is_native_abi && distutils-r1_src_install
}
multilib_src_install_all() {
einstalldocs
find "${D}" -name '*.la' -delete || die
}