gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/hypothesis: Bump to 6.62.0

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2023-01-09 08:15:13 +01:00
parent 5c27265727
commit 02a551d9d8
2 changed files with 78 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/hypothesis/Manifest
View File

@@ -2,3 +2,4 @@ DIST hypothesis-6.59.0.gh.tar.gz 9337749 BLAKE2B 29673a769702cf80efa05c3f5a60a3d
DIST hypothesis-6.61.0.gh.tar.gz 9340090 BLAKE2B 0d550e50085ad2e9ae848b86b35eaa229de9aa461e235748c308708e92f22388ca1cd5f663f68d8399f89b73fe20298653f947988b6fb2c505ca44650c3997d4 SHA512 3b460c817b46a61e8bcb506316cc56a6e70b7cb16e1f7af925d24372992fcd8c7c6895722d11637402f67eef0fad63318c5c8835e72b585c789e95937cd38465
DIST hypothesis-6.61.1.gh.tar.gz 9340617 BLAKE2B cdef4559eed21211ecfb3942575b3a9f83e8c2335443d5541e1f52e839a41755d18d5174c1041f12723a26100c6188c618acaa7f504f250132e53ca534c36be1 SHA512 1a0093f18ca3ce4507926c82838cbb205b012faa47f5b4c1b8f574cfe9ebfd10d94d673020212922d162ee1238ee2a09d20b596e9c81ba4a106dfb4e2d6692a0
DIST hypothesis-6.61.3.gh.tar.gz 9339977 BLAKE2B 2bd7f2828563694f678eacc3537e920d027229d294f1d48ba23780d8a467ffb2829fd961ba4e002786f5d95e4b57c6d0c115d75df8468465f31f3512c7fcbbc7 SHA512 835a079570a983343f4059c7b6ca5a8e8d568ad945a173bf179f6ea4b1ac6cf7d1f7ab7df8092c18aacc455499a9aadd0803ac3b0fb800c4d880a16256ca12f2
DIST hypothesis-6.62.0.gh.tar.gz 9341805 BLAKE2B 44a7f9a15f93e402405226d40293ea29954b1a85df02c18386aa0eebc72d973005402664df1f0594d30b25e2f4c43ed56c4a79ab0ad6627196ff5661ee6fff0a SHA512 5ccc098ca738f634972c210ba2cbf02f4f4f909ac7f963a0e761fe2868679854d1b51036b09c61f8cabff000b9f14221ead43740a9f17538138f67be9bd04815

77
dev-python/hypothesis/hypothesis-6.62.0.ebuild Normal file
View File

@@ -0,0 +1,77 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
CLI_COMPAT=( python3_{8..10} )
PYTHON_COMPAT=( "${CLI_COMPAT[@]}" python3_11 pypy3 )
PYTHON_REQ_USE="threads(+),sqlite"
inherit distutils-r1 multiprocessing optfeature
TAG=hypothesis-python-${PV}
MY_P=hypothesis-${TAG}
DESCRIPTION="A library for property based testing"
HOMEPAGE="
https://github.com/HypothesisWorks/hypothesis/
https://pypi.org/project/hypothesis/
"
SRC_URI="
https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
-> ${P}.gh.tar.gz
"
S="${WORKDIR}/${MY_P}/hypothesis-python"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
IUSE="cli"
RDEPEND="
>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
' 3.8 3.9 3.10)
cli? (
$(python_gen_cond_dep '
dev-python/black[${PYTHON_USEDEP}]
dev-python/click[${PYTHON_USEDEP}]
' "${CLI_COMPAT[@]}")
)
"
BDEPEND="
test? (
dev-python/mock[${PYTHON_USEDEP}]
dev-python/pexpect[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
!!<dev-python/requests-toolbelt-0.10.1
)
"
distutils_enable_tests pytest
python_test() {
# subtests are broken by warnings from random plugins
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
local -x PYTEST_PLUGINS=xdist.plugin,pytest_forked,_hypothesis_pytestplugin
epytest tests/cover tests/pytest tests/quality -n "$(makeopts_jobs)"
}
python_install() {
distutils-r1_python_install
if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
fi
}
pkg_postinst() {
optfeature "datetime support" dev-python/pytz
optfeature "dateutil support" dev-python/python-dateutil
optfeature "numpy support" dev-python/numpy
optfeature "django support" dev-python/django dev-python/pytz
optfeature "pandas support" dev-python/pandas
optfeature "pytest support" dev-python/pytest
}