gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

xfce-base/xfce4-panel: Bump to 4.20.4

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2025-03-23 14:44:23 +01:00
parent 732f6f5778
commit 0273c3b52b
2 changed files with 87 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
xfce-base/xfce4-panel/Manifest
View File

@@ -2,4 +2,5 @@ DIST xfce4-panel-4.18.6.tar.bz2 1595352 BLAKE2B e4f4eb2f3838cde69a2614021be184ba
DIST xfce4-panel-4.20.0.tar.bz2 2260815 BLAKE2B ab3d66465bf24757a9831ff71aebd4609a4a4b9e456899a34fa900836398a0c0727993b84769decb8c371c94344ad9f940eb15431824152e8acd9434125e58c8 SHA512 431ff1736a62bdee4a7a9a5e7b8aa9f0cf779ce5454503c33fc0ffb82b6cd4bbcbc5e1fc99c092e31f0f702f459cf31336eff914a41b618043f83d2a40c9b049
DIST xfce4-panel-4.20.2.tar.bz2 2262583 BLAKE2B 73bb276bc14720c311855823bf18f32244a5e563296daf900760ed0513a67f4c8a96c469bbf6e7f5be1e236e264e0efb20fe25b47efe6c84b25ff337653da6a9 SHA512 a5dfa5576b638ad15dc9a8b24ab28786526e9785178bbbecd1d2ea1c21f70bb84c5bca1313e21a02bc7347b964d934de2fe406e1b2bc743bd7ea7ef20fcb9b5c
DIST xfce4-panel-4.20.3.tar.bz2 2263062 BLAKE2B 6d36820961c4689f74448732921db8394521a44c30f2e55e9e35feb040b1d9dd954da62c21962a5a2ea39fd245b72acf0ce89f894c6a0982638d276c050c1b8f SHA512 ea4db869e025822119ee01bf9ffaedb254bf1e9362919e6c8fc28617b3eb3be85b486175b02e694198272c25295b9c6b80873f5bcfaa0596df4107356428d1a3
DIST xfce4-panel-4.20.4.tar.bz2 2287183 BLAKE2B 368b1fbdabbbf41c1b7fffb321738c6f5a32e1973c7c47bf9f47e709107ef971f7d59e94c3addc72582df13e32194d4475bee59e94ca5f90d0c74a4c12bd7a35 SHA512 89d835617cab0afce1344495fa29f9cba49fdd1472fb079474c4511befebd1771eb5f4d6f968b98c43517f61e2e284760597a437e39a4956a56abb6d73e43265
DIST xfce4-panel-4.21.0.tar.xz 834780 BLAKE2B cf06cd31589e3f2ce854df7677e6ae54e59432f69cb552a1bd4069798d61a287b0e476e355a3f65c5862134b8a1b1b231fe5660fa7a1e306ca912da5796b4d5e SHA512 64e848af99eb6d11676819ee96b97bf49db7054d12d688177e0f21d9af74cecf3d14a102c01198a2e901568e848149d2c8e9bdb5489a5ddddb8150a78c6f53a6

86
xfce-base/xfce4-panel/xfce4-panel-4.20.4.ebuild Normal file
View File

@@ -0,0 +1,86 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit vala xdg-utils
DESCRIPTION="Panel for the Xfce desktop environment"
HOMEPAGE="
https://docs.xfce.org/xfce/xfce4-panel/start
https://gitlab.xfce.org/xfce/xfce4-panel/
"
SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
LICENSE="GPL-2+ LGPL-2.1+"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE="+dbusmenu introspection vala wayland X"
REQUIRED_USE="
|| ( wayland X )
vala? ( introspection )
"
DEPEND="
>=dev-libs/glib-2.72.0
>=x11-libs/cairo-1.16.0
>=x11-libs/gtk+-3.24.0:3[X?,introspection?,wayland?]
>=xfce-base/exo-4.18.0:=
>=xfce-base/garcon-4.18.0:=
>=xfce-base/libxfce4ui-4.18.0:=
>=xfce-base/libxfce4util-4.18.0:=[introspection?,vala?]
>=xfce-base/libxfce4windowing-4.20.1:=[X?]
>=xfce-base/xfconf-4.18.0:=
dbusmenu? ( >=dev-libs/libdbusmenu-16.04.0[gtk3] )
introspection? ( >=dev-libs/gobject-introspection-1.66:= )
wayland? (
>=dev-libs/wayland-1.20
>=gui-libs/gtk-layer-shell-0.7.0
)
X? (
>=x11-libs/libX11-1.6.7
>=x11-libs/libXext-1.0.0
x11-libs/libwnck:3
)
"
RDEPEND="
${DEPEND}
"
BDEPEND="
vala? ( $(vala_depend) )
dev-build/xfce4-dev-tools
dev-lang/perl
dev-util/gdbus-codegen
dev-util/intltool
sys-devel/gettext
virtual/pkgconfig
"
src_configure() {
local myconf=(
$(use_enable introspection)
$(use_enable dbusmenu dbusmenu-gtk3)
$(use_enable vala)
$(use_enable wayland)
$(use_enable wayland gtk-layer-shell)
$(use_enable X x11)
)
use vala && vala_setup
econf "${myconf[@]}"
}
src_install() {
default
find "${D}" -name '*.la' -delete || die
}
pkg_postinst() {
xdg_icon_cache_update
xdg_desktop_database_update
}
pkg_postrm() {
xdg_icon_cache_update
xdg_desktop_database_update
}