mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-08 18:27:07 -08:00
net-analyzer/greenbone-feed-sync: add 25.2.0
Signed-off-by: Giuseppe Foti <foti.giuseppe@gmail.com> Part-of: https://github.com/gentoo/gentoo/pull/45609 Closes: https://github.com/gentoo/gentoo/pull/45609 Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST greenbone-feed-sync-25.1.0.tar.gz 65345 BLAKE2B cf0c8ce7b7387b70ea00a87ecc48b12f1529b80e92f13dadfc31c15c81bd549261aa4ec83124c16be4833fc202c0b5000ca0ef92ca2d5fa5f8686ba4c01b63e8 SHA512 970aa6b0b75fabc45629dca3f036a3fca925fa03e52f704033a1d4497e77afaedcbfe9afea94400ab1b136bb19d8829cdab45d6c3c9de6088e9a48da0871128f
|
||||
DIST greenbone-feed-sync-25.2.0.tar.gz 75235 BLAKE2B af655cb9e76e97773ef19288b032d9516c18bd8e848ab622f699508b25a8a68d50040da2f86a8eea0c988a875a53166759f170ffb5e1c6956529fa55761b7772 SHA512 33b61109ea0f7b728c980e8a14f780b25ca5c06bc37e280e60bd25a69e9119594e6a40b1a795f9aa4e439e2c78a68e298822d879c93235228941ec005f55bd0c
|
||||
|
||||
@@ -0,0 +1,102 @@
|
||||
# Copyright 1999-2026 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
|
||||
DISTUTILS_USE_PEP517=poetry
|
||||
inherit distutils-r1 systemd
|
||||
|
||||
DESCRIPTION="New script for syncing the Greenbone Community Feed"
|
||||
HOMEPAGE="https://github.com/greenbone/greenbone-feed-sync"
|
||||
SRC_URI="https://github.com/greenbone/greenbone-feed-sync/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
|
||||
|
||||
LICENSE="GPL-3+"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64"
|
||||
IUSE="cron"
|
||||
|
||||
COMMON_DEPEND="
|
||||
acct-user/gvm
|
||||
net-misc/rsync
|
||||
>=net-analyzer/gvmd-22.5.0
|
||||
>=dev-python/rich-13.2.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/shtab-1.7.0[${PYTHON_USEDEP}]
|
||||
"
|
||||
DEPEND="
|
||||
${COMMON_DEPEND}
|
||||
test? ( >=net-analyzer/pontos-22.12.2[${PYTHON_USEDEP}] )
|
||||
"
|
||||
RDEPEND="
|
||||
${COMMON_DEPEND}
|
||||
cron? ( virtual/cron )
|
||||
"
|
||||
|
||||
distutils_enable_tests unittest
|
||||
|
||||
src_test() {
|
||||
# Make a copy of the original config
|
||||
cp greenbone/feed/sync/config.py "${T}"/config.py.orig || die
|
||||
|
||||
# Patch the config.py to not use files from /etc/gvm, as this may
|
||||
# cause a PermissionError. See https://bugs.gentoo.org/932836#c10
|
||||
sed -i \
|
||||
-e 's:DEFAULT_CONFIG_FILE = "/etc/gvm/greenbone-feed-sync.toml":DEFAULT_CONFIG_FILE = "'"${WORKDIR}/${P}-${TARGET}"'/install/etc/gvm/greenbone-feed-sync.toml":' \
|
||||
-e 's:DEFAULT_ENTERPRISE_KEY_PATH = "/etc/gvm/greenbone-enterprise-feed-key":DEFAULT_ENTERPRISE_KEY_PATH = "'"${WORKDIR}/${P}-${TARGET}"'/install/etc/gvm/greenbone-enterprise-feed-key":' \
|
||||
greenbone/feed/sync/config.py || die
|
||||
|
||||
# Disable tests that require network access.
|
||||
sed -i \
|
||||
-e 's:test_do_not_run_as_root:_&:' \
|
||||
-e 's:test_sync_nvts:_&:' \
|
||||
-e 's:test_sync_nvts_quiet:_&:' \
|
||||
-e 's:test_sync_nvts_rsync_error:_&:' \
|
||||
-e 's:test_sync_nvts_verbose:_&:' \
|
||||
-e 's:test_sync_nvts:_&:' \
|
||||
-e 's:test_sync_nvts_error:_&:' \
|
||||
tests/test_main.py || die
|
||||
|
||||
distutils-r1_src_test
|
||||
|
||||
# Restore config.py after test.
|
||||
mv "${T}"/config.py.orig greenbone/feed/sync/config.py || die
|
||||
}
|
||||
|
||||
python_install() {
|
||||
distutils-r1_python_install
|
||||
|
||||
# greenbone-feed-sync should not be run as root to avoid changing file permissions
|
||||
insinto /etc/sudoers.d
|
||||
newins - greenbone-feed-sync <<-EOF
|
||||
gvm ALL = NOPASSWD: /usr/bin/greenbone-feed-sync
|
||||
EOF
|
||||
|
||||
fperms 0750 /etc/sudoers.d
|
||||
fperms 0440 /etc/sudoers.d/greenbone-feed-sync
|
||||
|
||||
if use cron; then
|
||||
exeinto /etc/cron.daily
|
||||
newexe "${FILESDIR}"/${PN}.cron ${PN}
|
||||
fi
|
||||
|
||||
systemd_dounit "${FILESDIR}/${PN}.timer" "${FILESDIR}/${PN}.service"
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
if [[ -n ${REPLACING_VERSIONS} ]]; then
|
||||
return
|
||||
fi
|
||||
|
||||
if use cron; then
|
||||
elog
|
||||
elog "Edit ${EROOT}/etc/cron.weekly/greenbone-feed-sync to activate daily feed update!"
|
||||
elog
|
||||
fi
|
||||
|
||||
if systemd_is_booted; then
|
||||
elog
|
||||
elog "To enable the systemd timer, run the following command:"
|
||||
elog " systemctl enable --now greenbone-feed-sync.timer"
|
||||
elog
|
||||
fi
|
||||
}
|
||||
Reference in New Issue
Block a user