media-fonts/noto-emoji: Version bump

Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

media-fonts/noto-emoji/Manifest

@@ -1,2 +1,3 @@
 DIST noto-emoji-20200317.tar.gz 60841240 BLAKE2B aab99a5cbab6943b9e282b33dc113601489c7d02a3670db8675e6c90be615ceaf0f2900bdbc68ffaca6130f4e724b2ec1001cfccce80a181208ace0638492b7e SHA512 958a589ef7d7a0b9e4fa3eb1caa20284fa7463419a740d0ca05f850618324883c13498f92839476042cfd1daffa7eff925b2f22ec318c0726391f69c04911bfb
 DIST noto-emoji-20200916.tar.gz 60016327 BLAKE2B 980a4e960f200567e34c1314d9269029749e1d9cd29ab1c5da30418d8a016b894223adf8f263222512c513feab4de856a2f48b1695011ced0c49c30e7a487e47 SHA512 d497c4ecaf299ade23b1f6a3bc6e98d7dbbb619e51f067496d4a4dbf71693c96de26263af595c0aae86c63dcea8be190718f5477af645d4338989f25cc3ab848
+DIST noto-emoji-20201214.tar.gz 69885567 BLAKE2B 21d251a25740bf474e4c7e138c33d90f35cfea93ff2c72904e38a8bead0124408c67a731ed142fe96da07bbf8afb7d929293518a366157fd1393dacc560bf12b SHA512 b3ad1f31bbb48bd5de2fbddcac5c3f27891a805ae4ac8d0b69b07c1d7259c6a5317eca9ac7e3b068d24ed5d3acd3523cfb2036f2e9f08179b85fd81dd5c9b570

media-fonts/noto-emoji/noto-emoji-20201214.ebuild

@@ -0,0 +1,109 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6..8} )
+
+inherit font python-any-r1
+
+DESCRIPTION="Google Noto Emoji fonts"
+HOMEPAGE="https://www.google.com/get/noto/ https://github.com/googlefonts/noto-emoji"
+
+COMMIT="e7ac893b3315181f51710de3ba16704ec95e3f51"
+SRC_URI="https://github.com/googlefonts/noto-emoji/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0 OFL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="buildfont"
+
+BDEPEND="
+	buildfont? (
+		${PYTHON_DEPS}
+		app-arch/zopfli
+		$(python_gen_any_dep '
+			>=dev-python/fonttools-4.7.0[${PYTHON_USEDEP}]
+			>=dev-python/nototools-0.2.13[${PYTHON_USEDEP}]
+		')
+		media-gfx/pngquant
+		x11-libs/cairo
+		|| ( media-gfx/imagemagick[png] media-gfx/graphicsmagick[png] )
+	)
+"
+
+RESTRICT="binchecks strip"
+
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+python_check_deps() {
+	has_version -b "dev-python/fonttools[${PYTHON_USEDEP}]" &&
+	has_version -b "dev-python/nototools[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	font_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# Drop font for Windows 10
+	rm fonts/NotoColorEmoji_WindowsCompatible.ttf || die
+
+	if use buildfont; then
+		# From Fedora
+		eapply "${FILESDIR}/${PN}-build-all-flags.patch"
+
+		# https://github.com/googlei18n/noto-emoji/issues/240
+		eapply "${FILESDIR}/${PN}-20180823-build-path.patch"
+
+		# Be more verbose, bug #717654
+		eapply "${FILESDIR}"/${PN}-pngquant-verbose.patch
+		sed -i -e 's:@$(ZOPFLIPNG) -y "$<" "$@" 1> /dev/null 2>&1:@$(ZOPFLIPNG) -y "$<" "$@":g' Makefile || die
+
+		# Based on Fedora patch to allow graphicsmagick usage
+		if has_version -b media-gfx/graphicsmagick; then
+			eapply "${FILESDIR}/${PN}-20190328-use-gm.patch"
+		fi
+	fi
+}
+
+src_compile() {
+	if ! use buildfont; then
+		einfo "Installing pre-built fonts provided by upstream."
+		einfo "They could be not fully updated or miss some items."
+		einfo "To build fonts based on latest images enable 'buildfont'"
+		einfo "USE (that will require more time and resources too)."
+	else
+		python_setup
+		einfo "Building fonts..."
+
+		# From Debian:
+		# The build requires a VIRTUAL_ENV variable and sequence check isn't working
+		VIRTUAL_ENV=true \
+		BYPASS_SEQUENCE_CHECK=true \
+		default
+	fi
+}
+
+src_install() {
+	if ! use buildfont; then
+		FONT_S="${S}/fonts"
+	else
+		mv -i fonts/NotoEmoji-Regular.ttf "${S}" || die
+		# Built font and Regular font
+		FONT_S="${S}"
+
+		# Don't lose fancy emoji icons
+		insinto /usr/share/icons/"${PN}"/128x128/emotes/
+		doins png/128/*.png
+
+		insinto /usr/share/icons/"${PN}"/scalable/emotes/
+		doins svg/*.svg
+	fi
+
+	FONT_SUFFIX="ttf"
+	font_src_install
+
+	dodoc README.md
+}