net-libs/glib-networking: bump to 2.54.1

Signed-off-by: Mart Raudsepp <leio@gentoo.org>
Package-Manager: Portage-2.3.52, Repoman-2.3.11

net-libs/glib-networking/Manifest

@@ -1 +1,2 @@
 DIST glib-networking-2.50.0.tar.xz 435380 BLAKE2B 02eea0692cf20c9b1df8efc7e65eb144675fa307851450d461a73df6ccd55cb2ad4e8db5790ca8b0a38a14e30391e583dada30e858154e7c5b7fa0970658410a SHA512 a1e9d28a546f83d461057f088ca2467a32be110f444c8ede1cbfeb20244637d8d5fb5b5b0ee4485feb517beebc3536671442bbfdd3ba01663b52e6da138bd7fe
+DIST glib-networking-2.54.1.tar.xz 441232 BLAKE2B 4697ac5fe248d12839d2a3c1340e2e699fa2ea65a9b5d741c50d069c904e82eb23feb89d648bc127959d9ac15e18d3a4cd2bd8b08202d48d33937affb9df13c9 SHA512 8356d835914e33df43f4f2bb6a915ddcd48dd0565e4d5bc1f1d692e9c3124ee4421b99f87f2586f74e9fed24ef7421159f3242fd1eb7bd74950bd25e860896ec

net-libs/glib-networking/glib-networking-2.54.1.ebuild

@@ -0,0 +1,83 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2 multilib-minimal virtualx
+
+DESCRIPTION="Network-related giomodules for glib"
+HOMEPAGE="https://git.gnome.org/browse/glib-networking/"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+IUSE="+gnome +libproxy smartcard +ssl test"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+
+RDEPEND="
+	>=dev-libs/glib-2.46.0:2[${MULTILIB_USEDEP}]
+	gnome? ( gnome-base/gsettings-desktop-schemas )
+	libproxy? ( >=net-libs/libproxy-0.4.11-r1:=[${MULTILIB_USEDEP}] )
+	smartcard? (
+		>=app-crypt/p11-kit-0.18.4[${MULTILIB_USEDEP}]
+		>=net-libs/gnutls-3:=[pkcs11,${MULTILIB_USEDEP}] )
+	ssl? (
+		app-misc/ca-certificates
+		>=net-libs/gnutls-3:=[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=sys-devel/gettext-0.19.4
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+	test? ( sys-apps/dbus[X] )
+"
+# eautoreconf needs >=sys-devel/autoconf-2.65:2.5
+
+src_prepare() {
+	default
+	# Disable SSLv3 requiring fallback test, which fails with net-libs/gnutls[-sslv3], bug 595952
+	# https://bugzilla.gnome.org/show_bug.cgi?id=782853
+	sed -i -e '/\/tls\/connection\/fallback\/SSL/d' "${S}"/tls/tests/connection.c || die
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	gnome2_src_configure \
+		--disable-static \
+		--with-ca-certificates="${EPREFIX}"/etc/ssl/certs/ca-certificates.crt \
+		$(use_with gnome gnome-proxy) \
+		$(use_with libproxy) \
+		$(use_with smartcard pkcs11) \
+		$(use_with ssl gnutls)
+}
+
+multilib_src_test() {
+	# XXX: non-native tests fail if glib-networking is already installed.
+	# have no idea what's wrong. would appreciate some help.
+	multilib_is_native_abi || return 0
+
+	virtx emake check
+}
+
+multilib_src_install() {
+	gnome2_src_install
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	multilib_pkg_postinst() {
+		gnome2_giomodule_cache_update \
+			|| die "Update GIO modules cache failed (for ${ABI})"
+	}
+	multilib_foreach_abi multilib_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+
+	multilib_pkg_postrm() {
+		gnome2_giomodule_cache_update \
+			|| die "Update GIO modules cache failed (for ${ABI})"
+	}
+	multilib_foreach_abi multilib_pkg_postrm
+}