mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-17 04:28:12 -07:00
d1a9bd8c1c
and drop old python compat Closes: https://bugs.gentoo.org/972791 Signed-off-by: Nowa Ammerlaan <nowa@gentoo.org>
52 lines
1.4 KiB
Bash
52 lines
1.4 KiB
Bash
# Copyright 1999-2026 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
PYTHON_COMPAT=( python3_{12..14} )
|
|
|
|
inherit distutils-r1
|
|
|
|
DESCRIPTION="Python scrapper to access ModDB mods, games and more as objects"
|
|
HOMEPAGE="https://github.com/ClementJ18/moddb"
|
|
SRC_URI="https://github.com/ClementJ18/moddb/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~x86"
|
|
|
|
# Connects to moddb.com
|
|
RESTRICT="test"
|
|
PROPERTIES="test? ( test_network )"
|
|
|
|
BDEPEND="dev-python/pkg-resources[${PYTHON_USEDEP}]"
|
|
|
|
RDEPEND="
|
|
dev-python/beautifulsoup4[${PYTHON_USEDEP}]
|
|
dev-python/requests[${PYTHON_USEDEP}]
|
|
"
|
|
|
|
EPYTEST_DESELECT=(
|
|
# These tests require valid moddb.com login information
|
|
"tests/test_base.py::TestLogin::test_login"
|
|
"tests/test_client.py::TestClient::test_get_watched"
|
|
"tests/test_client.py::TestClient::test_get_updates"
|
|
"tests/test_client.py::TestClient::test_posts"
|
|
"tests/test_client.py::TestClient::test_friends"
|
|
"tests/test_client.py::TestClient::test_messages"
|
|
)
|
|
|
|
distutils_enable_sphinx docs/source dev-python/sphinx-autodoc-typehints
|
|
EPYTEST_PLUGINS=( pytest-rerunfailures )
|
|
distutils_enable_tests pytest
|
|
|
|
python_test() {
|
|
# Dummy moddb.com login information
|
|
export USERNAME="portage"
|
|
export SENDER_USERNAME="portage"
|
|
export PASSWORD="testing"
|
|
export SENDER_PASSWORD="testing"
|
|
epytest
|
|
}
|