mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-23 18:38:08 -07:00
5dfbd9a97d
keyword 0-r1 for ~arm64-macos dev-cpp/eigen: keyword 3.4.0-r1 for ~arm64-macos, ~x64-macos dev-python/pyproject-metadata: keyword 0.7.1 for ~arm64-macos, ~x64-macos dev-python/appdirs: keyword 1.4.4-r3 for ~arm64-macos dev-python/fs: keyword 2.4.16 for ~arm64-macos, ~x64-macos dev-python/cppy: keyword 1.2.1-r1 for ~arm64-macos, ~x64-macos dev-python/olefile: keyword 0.46-r2 for ~arm64-macos, ~x64-macos media-libs/libwebp: keyword 1.3.1 for ~arm64-macos media-libs/qhull: keyword 2020.2-r3 for ~arm64-macos media-fonts/stix-fonts: keyword 2.11 for ~arm64-macos media-fonts/dejavu: keyword 2.37 for ~arm64-macos, ~x64-macos dev-python/pytz: keyword 2023.3-r1 for ~arm64-macos dev-python/pillow: keyword 10.0.0 for ~arm64-macos, ~x64-macos dev-python/kiwisolver: keyword 1.4.4-r1 for ~arm64-macos, ~x64-macos dev-python/fonttools: keyword 4.41.0 for ~arm64-macos dev-python/cycler: keyword 0.11.0-r1 for ~arm64-macos dev-python/contourpy: keyword 1.1.0 for ~arm64-macos, ~x64-macos Signed-off-by: Benda Xu <heroxbd@gentoo.org>
52 lines
1.2 KiB
Bash
52 lines
1.2 KiB
Bash
# Copyright 1999-2023 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
PYTHON_COMPAT=( python3_{10..12} pypy3 )
|
|
PYTHON_REQ_USE="threads(+)"
|
|
|
|
inherit distutils-r1 pypi
|
|
|
|
DESCRIPTION="World timezone definitions for Python"
|
|
HOMEPAGE="
|
|
https://pythonhosted.org/pytz/
|
|
https://github.com/stub42/pytz/
|
|
https://pypi.org/project/pytz/
|
|
"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
|
|
IUSE="test"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
|| (
|
|
>=sys-libs/timezone-data-2023b
|
|
sys-libs/glibc[vanilla]
|
|
)
|
|
"
|
|
BDEPEND="
|
|
test? (
|
|
${RDEPEND}
|
|
)
|
|
"
|
|
|
|
src_prepare() {
|
|
distutils-r1_src_prepare
|
|
|
|
# unbundle timezone-data
|
|
rm -r pytz/zoneinfo || die
|
|
# remove hardcoded list of all timezones but leave subjective set
|
|
# of "common timezones"
|
|
sed -i -e '/^_all_timezones_unchecked/,/^all_timezones_set/d' pytz/__init__.py || die
|
|
eapply "${FILESDIR}"/pytz-2023.2-system-tzinfo.patch
|
|
}
|
|
|
|
python_test() {
|
|
"${EPYTHON}" pytz/tests/test_tzinfo.py -v ||
|
|
die "Tests fail with ${EPYTHON}"
|
|
}
|