mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-17 16:38:08 -07:00
00bcf47c44
This isn't done, but fixes most of the issues, and we are left with 2 failing tests which looks like a real issue. But I still prefer to push current changes to minimize future work to enable py3.12 Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
55 lines
1.4 KiB
Bash
55 lines
1.4 KiB
Bash
# Copyright 1999-2023 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
PYTHON_COMPAT=( pypy3 python3_{10..11} )
|
|
inherit distutils-r1 optfeature pypi
|
|
|
|
DESCRIPTION="Filesystem abstraction layer"
|
|
HOMEPAGE="
|
|
https://pypi.org/project/fs/
|
|
https://docs.pyfilesystem.org/
|
|
https://www.willmcgugan.com/tag/fs/
|
|
"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
|
|
|
|
RDEPEND="
|
|
>=dev-python/appdirs-1.4.3[${PYTHON_USEDEP}]
|
|
dev-python/pytz[${PYTHON_USEDEP}]
|
|
dev-python/setuptools[${PYTHON_USEDEP}]
|
|
>=dev-python/six-1.10[${PYTHON_USEDEP}]
|
|
"
|
|
# NB: we skip tests requiring pyftpdlib
|
|
BDEPEND="
|
|
test? (
|
|
dev-python/parameterized[${PYTHON_USEDEP}]
|
|
dev-python/psutil[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
|
|
distutils_enable_sphinx docs/source dev-python/sphinx-rtd-theme dev-python/recommonmark
|
|
distutils_enable_tests pytest
|
|
|
|
EPYTEST_IGNORE=(
|
|
# TODO: fails at teardown due to unfreed resources
|
|
tests/test_ftpfs.py
|
|
)
|
|
|
|
src_prepare() {
|
|
# fix for python 3.12
|
|
sed -e 's/self.assertRaisesRegexp/self.assertRaisesRegex/g' -i fs/test.py || die
|
|
|
|
distutils-r1_src_prepare
|
|
}
|
|
|
|
pkg_postinst() {
|
|
optfeature "S3 support" dev-python/boto
|
|
optfeature "SFTP support" dev-python/paramiko
|
|
optfeature "Browser support" dev-python/wxpython
|
|
}
|