mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-21 09:07:26 -08:00
f42710561c
Update done using: ``` git grep -l sys-libs/zlib sys-* | xargs sed -i -e s@sys-libs/zlib@virtual/zlib@g git grep -l virtual/zlib-ng sys-* | xargs sed -i -e s@virtual/zlib-ng@sys-libs/zlib-ng@g git diff --name-only | xargs copybump git diff --name-only | xargs grep -l PYTHON_COMPAT | xargs gpy-impl -@dead pkgcheck scan --commits -c SourcingCheck,VisibilityCheck --exit error ``` Plus reverts in sys-libs/minizip-ng, sys-libs/zlib-ng and profiles. Signed-off-by: Michał Górny <mgorny@gentoo.org>
91 lines
1.6 KiB
Bash
91 lines
1.6 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit autotools desktop
|
|
|
|
DESCRIPTION="Emulator of Atari 8-bit computer systems and 5200 game console"
|
|
HOMEPAGE="
|
|
https://atari800.github.io/
|
|
https://github.com/atari800/atari800/
|
|
"
|
|
SRC_URI="
|
|
https://github.com/atari800/atari800/releases/download/ATARI800_${PV//./_}/${P}-src.tgz
|
|
https://sourceforge.net/projects/atari800/files/ROM/Original%20XL%20ROM/xf25.zip
|
|
"
|
|
|
|
LICENSE="GPL-2+"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~x86"
|
|
IUSE="encode-mp3 opengl readline +sdl +sound"
|
|
REQUIRED_USE="
|
|
encode-mp3? ( sound )
|
|
opengl? ( sdl )
|
|
"
|
|
|
|
DEPEND="
|
|
encode-mp3? (
|
|
media-sound/lame
|
|
)
|
|
sdl? (
|
|
>=media-libs/libsdl-1.2.0[joystick,opengl?,sound?,video]
|
|
)
|
|
!sdl? (
|
|
sys-libs/ncurses:=
|
|
)
|
|
readline? (
|
|
sys-libs/readline:=
|
|
sys-libs/ncurses:=
|
|
)
|
|
media-libs/libpng:=
|
|
virtual/zlib
|
|
"
|
|
RDEPEND="
|
|
${DEPEND}
|
|
"
|
|
BDEPEND="
|
|
app-arch/unzip
|
|
"
|
|
|
|
src_prepare() {
|
|
local PATCHES=(
|
|
# Bug 544608
|
|
"${FILESDIR}"/atari800-3.1.0-tgetent-detection.patch
|
|
)
|
|
|
|
default
|
|
eautoreconf
|
|
}
|
|
|
|
src_configure() {
|
|
local video=ncurses
|
|
local sound=no
|
|
|
|
if use sdl; then
|
|
video=sdl
|
|
use sound && sound=sdl
|
|
elif use sound; then
|
|
sound=oss
|
|
fi
|
|
|
|
local myconf=(
|
|
$(use_with opengl)
|
|
$(use_with readline)
|
|
$(use_with encode-mp3 mp3)
|
|
--with-video=${video}
|
|
--with-sound=${sound}
|
|
)
|
|
econf "${myconf[@]}"
|
|
}
|
|
|
|
src_install() {
|
|
default
|
|
insinto "/usr/share/${PN}"
|
|
doins "${WORKDIR}/"*.ROM
|
|
insinto /etc
|
|
newins "${FILESDIR}"/atari800-4.2.0.cfg atari800.cfg
|
|
newicon data/atari2.svg ${PN}.svg
|
|
make_desktop_entry ${PN} "Atari 800 emulator"
|
|
}
|