mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-24 18:58:08 -07:00
d83e25b6a5
sed -E '/dev-libs\/gobject-introspection(:=|\s|$|-[0-9]|\[)/ { s/(>=)?dev-libs\/gobject-introspection(-[0-9.r-]*)?/>=dev-libs\/gobject-introspection-1.82.0-r2/ }' */*/*.ebuild -i
+ manually going over to undo the false positives or if the version
requirement was higher.
Bug: https://bugs.gentoo.org/947058
See-Also: ae37e3f389
Signed-off-by: Alfred Wingate <parona@protonmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/44336
Closes: https://github.com/gentoo/gentoo/pull/44336
Signed-off-by: Sam James <sam@gentoo.org>
62 lines
1.3 KiB
Bash
62 lines
1.3 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit gnome.org meson xdg vala virtualx
|
|
|
|
DESCRIPTION="Building blocks for modern adaptive GNOME apps"
|
|
HOMEPAGE="https://gitlab.gnome.org/GNOME/libhandy/"
|
|
|
|
LICENSE="LGPL-2.1+"
|
|
SLOT="1"
|
|
KEYWORDS="~alpha amd64 ~arm arm64 ~loong ppc ppc64 ~riscv ~sparc x86"
|
|
|
|
IUSE="examples glade gtk-doc +introspection test +vala"
|
|
REQUIRED_USE="
|
|
gtk-doc? ( introspection )
|
|
vala? ( introspection )
|
|
"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
>=dev-libs/glib-2.44:2
|
|
>=x11-libs/gtk+-3.24.1:3[introspection?]
|
|
glade? ( dev-util/glade:3.10= )
|
|
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
|
|
"
|
|
DEPEND="${RDEPEND}
|
|
x11-base/xorg-proto"
|
|
BDEPEND="
|
|
dev-libs/libxml2:2
|
|
dev-util/glib-utils
|
|
>=sys-devel/gettext-0.19.8
|
|
virtual/pkgconfig
|
|
gtk-doc? ( >=dev-util/gi-docgen-2021.1
|
|
app-text/docbook-xml-dtd:4.3 )
|
|
vala? ( $(vala_depend) )
|
|
"
|
|
|
|
src_prepare() {
|
|
default
|
|
use vala && vala_setup
|
|
xdg_environment_reset
|
|
}
|
|
|
|
src_configure() {
|
|
local emesonargs=(
|
|
-Dprofiling=false # -pg passing
|
|
$(meson_feature introspection)
|
|
$(meson_use vala vapi)
|
|
$(meson_use gtk-doc gtk_doc)
|
|
$(meson_use test tests)
|
|
$(meson_use examples)
|
|
$(meson_feature glade glade_catalog)
|
|
)
|
|
meson_src_configure
|
|
}
|
|
|
|
src_test() {
|
|
virtx meson_src_test
|
|
}
|