mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 17:09:10 -07:00
ef28997cd5
Closes: https://github.com/gentoo/gentoo/pull/11706 Signed-off-by: Michał Górny <mgorny@gentoo.org>
71 lines
1.6 KiB
Bash
71 lines
1.6 KiB
Bash
# Copyright 1999-2019 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=6
|
|
|
|
PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
|
|
inherit cmake-utils python-any-r1
|
|
|
|
if [[ ${PV} == "9999" ]] ; then
|
|
EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
|
|
inherit git-r3
|
|
else
|
|
SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
|
|
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86 ~ppc-macos"
|
|
fi
|
|
|
|
DESCRIPTION="A linkable library for Git"
|
|
HOMEPAGE="https://libgit2.github.com/"
|
|
|
|
LICENSE="GPL-2-with-linking-exception"
|
|
SLOT="0/28"
|
|
IUSE="examples gssapi libressl +ssh test +threads trace"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
!libressl? ( dev-libs/openssl:0= )
|
|
libressl? ( dev-libs/libressl:0= )
|
|
sys-libs/zlib
|
|
net-libs/http-parser:=
|
|
gssapi? ( virtual/krb5 )
|
|
ssh? ( net-libs/libssh2 )
|
|
"
|
|
DEPEND="${RDEPEND}
|
|
${PYTHON_DEPS}
|
|
virtual/pkgconfig
|
|
"
|
|
|
|
src_configure() {
|
|
local mycmakeargs=(
|
|
-DLIB_INSTALL_DIR="${EPREFIX}/usr/$(get_libdir)"
|
|
-DBUILD_CLAR=$(usex test)
|
|
-DENABLE_TRACE=$(usex trace)
|
|
-DUSE_GSSAPI=$(usex gssapi)
|
|
-DUSE_SSH=$(usex ssh)
|
|
-DTHREADSAFE=$(usex threads)
|
|
)
|
|
cmake-utils_src_configure
|
|
}
|
|
|
|
src_test() {
|
|
if [[ ${EUID} -eq 0 ]] ; then
|
|
# repo::iterator::fs_preserves_error fails if run as root
|
|
# since root can still access dirs with 0000 perms
|
|
ewarn "Skipping tests: non-root privileges are required for all tests to pass"
|
|
else
|
|
local TEST_VERBOSE=1
|
|
cmake-utils_src_test -R offline
|
|
fi
|
|
}
|
|
|
|
src_install() {
|
|
cmake-utils_src_install
|
|
dodoc docs/*.{md,txt}
|
|
|
|
if use examples ; then
|
|
find examples -name '.gitignore' -delete || die
|
|
dodoc -r examples
|
|
docompress -x /usr/share/doc/${PF}/examples
|
|
fi
|
|
}
|